1 These notes may change in the next few days (today is 30 Nov 2010).
2 The material here benefited from many discussions with Ken Shan.
4 [[!toc]]
6 ##List Zippers##
8 Say you've got some moderately-complex function for searching through a list, for example:
10         let find_nth (test : 'a -> bool) (n : int) (lst : 'a list) : (int * 'a) ->
11                 let rec helper (position : int) n lst =
12                         match lst with
13                         | [] -> failwith "not found"
14                         | x :: xs when test x -> (if n = 1
15                                 then (position, x)
16                                 else helper (position + 1) (n - 1) xs
17                         )
18                         | x :: xs -> helper (position + 1) n xs
19                 in helper 0 n lst;;
21 This searches for the `n`th element of a list that satisfies the predicate `test`, and returns a pair containing the position of that element, and the element itself. Good. But now what if you wanted to retrieve a different kind of information, such as the `n`th element matching `test`, together with its preceding and succeeding elements? In a real situation, you'd want to develop some good strategy for reporting when the target element doesn't have a predecessor and successor; but we'll just simplify here and report them as having some default value:
23         let find_nth' (test : 'a -> bool) (n : int) (lst : 'a list) (default : 'a) : ('a * 'a * 'a) ->
24                 let rec helper (predecessor : 'a) n lst =
25                         match lst with
26                         | [] -> failwith "not found"
27                         | x :: xs when test x -> (if n = 1
28                                 then (predecessor, x, match xs with [] -> default | y::ys -> y)
29                                 else helper x (n - 1) xs
30                         )
31                         | x :: xs -> helper x n xs
32                 in helper default n lst;;
34 This duplicates a lot of the structure of `find_nth`; it just has enough different code to retrieve different information when the matching element is found. But now what if you wanted to retrieve yet a different kind of information...?
36 Ideally, there should be some way to factor out the code to find the target element---the `n`th element of the list satisfying the predicate `test`---from the code that retrieves the information you want once the target is found. We might build upon the initial `find_nth` function, since that returns the *position* of the matching element. We could hand that result off to some other function that's designed to retrieve information of a specific sort surrounding that position. But suppose our list has millions of elements, and the target element is at position 600512. The search function will already have traversed 600512 elements of the list looking for the target, then the retrieval function would have to *start again from the beginning* and traverse those same 600512 elements again. It could go a bit faster, since it doesn't have to check each element against `test` as it traverses. It already knows how far it has to travel. But still, this should seem a bit wasteful.
38 Here's an idea. What if we had some way of representing a list as "broken" at a specific point. For example, if our base list is:
40         [10; 20; 30; 40; 50; 60; 70; 80; 90]
42 we might imagine the list "broken" at position 3 like this (positions are numbered starting from 0):
44                     40;
45                 30;     50;
46             20;             60;
47         [10;                    70;
48                                     80;
49                                         90]
51 Then if we move one step forward in the list, it would be "broken" at position 4:
53                         50;
54                     40;     60;
55                 30;             70;
56             20;                     80;
57         [10;                            90]
59 If we had some convenient representation of these "broken" lists, then our search function could hand *that* off to the retrieval function, and the retrieval function could start right at the position where the list was broken, without having to start at the beginning and traverse many elements to get there. The retrieval function would also be able to inspect elements both forwards and backwards from the position where the list was "broken".
61 The kind of data structure we're looking for here is called a **list zipper**. To represent our first broken list, we'd use two lists: (1) containing the elements in the left branch, preceding the target element, *in the order reverse to their appearance in the base list*. (2) containing the target element and the rest of the list, in normal order. So:
63                     40;
64                 30;     50;
65             20;             60;
66         [10;                    70;
67                                     80;
68                                         90]
70 would be represented as `([30; 20; 10], [40; 50; 60; 70; 80; 90])`. To move forward in the base list, we pop the head element `40` off of the head element of the second list in the zipper, and push it onto the first list, getting `([40; 30; 20; 10], [50; 60; 70; 80; 90])`. To move backwards again, we pop off of the first list, and push it onto the second. To reconstruct the base list, we just "move backwards" until the first list is empty. (This is supposed to evoke the image of zipping up a zipper; hence the data structure's name.)
72 We had some discussio in seminar of the right way to understand the "zipper" metaphor. I think it's best to think of the tab of the zipper being here:
74                  t
75                   a
76                    b
77                     40;
78                 30;     50;
79             20;             60;
80         [10;                    70;
81                                     80;
82                                         90]
84 And imagine that you're just seeing the left half of a real-zipper, rotated 60 degrees counter-clockwise. When the list is all "zipped up", we've "move backwards" to the state where the first element is targetted:
86         ([], [10; 20; 30; 40; 50; 60; 70; 80; 90])
88 However you understand the "zipper" metaphor, this is a very handy datastructure, and it will become even more handy when we translate it over to more complicated base structures, like trees. To help get a good conceptual grip on how to do that, it's useful to introduce a kind of symbolism for talking about zippers. This is just a metalanguage notation, for us theorists; we don't need our programs to interpret the notation. We'll use a specification like this:
90         [10; 20; 30; *; 50; 60; 70; 80; 90], * filled by 40
92 to represent a list zipper where the break is at position 3, and the element occupying that position is 40. For a list zipper, this is implemented using the pairs-of-lists structure described above.
95 ##Tree Zippers##
97 Now how could we translate a zipper-like structure over to trees? What we're aiming for is a way to keep track of where we are in a tree, in the same way that the "broken" lists let us keep track of where we are in the base list.
99 It's important to set some ground rules for what will follow. If you don't understand these ground rules you will get confused. First off, for many uses of trees one wants some of the nodes or leafs in the tree to be *labeled* with additional information. It's important not to conflate the label with the node itself. Numerically one and the same piece of information---for example, the same `int`---could label two nodes of the tree without those nodes thereby being identical, as here:
101                 root
102                 / \
103               /     \
104             /  \    label 1
105           /      \
106         label 1  label 2
108 The leftmost leaf and the rightmost leaf have the same label; but they are different leafs. The leftmost leaf has a sibling leaf with the label 2; the rightmost leaf has no siblings that are leafs. Sometimes when one is diagramming trees, one will annotate the nodes with the labels, as above. Other times, when one is diagramming trees, one will instead want to annotate the nodes with tags to make it easier to refer to particular parts of the tree. So for instance, I could diagram the same tree as above as:
110                  1
111                 / \
112               2     \
113             /  \     5
114           /      \
115          3        4
117 Here I haven't drawn what the labels are. The leftmost leaf, the node tagged "3" in this diagram, doesn't have the label `3`. It has the label 1, as we said before. I just haven't put that into the diagram. The node tagged "2" doesn't have the label `2`. It doesn't have any label. The tree in this example only has information labeling its leafs, not any of its inner nodes. The identity of its inner nodes is exhausted by their position in the tree.
119 That is a second thing to note. In what follows, we'll only be working with *leaf-labeled* trees. In some uses of trees, one also wants labels on inner nodes. But we won't be discussing any such trees now. Our trees only have labels on their leafs. The diagrams below will tag all of the nodes, as in the second diagram above, and won't display what the leafs' labels are.
121 Final introductory comment: in particular applications, you may only need to work with binary trees---trees where internal nodes always have exactly two subtrees. That is what we'll work with in the homework, for example. But to get the guiding idea of how tree zippers work, it's helpful first to think about trees that permit nodes to have many subtrees. So that's how we'll start.
123 Suppose we have the following tree:
125                                  9200
126                             /      |  \
127                          /         |    \
128                       /            |      \
129                    /               |        \
130                 /                  |          \
131                500                920          950
132             /   |    \          /  |  \      /  |  \
133          20     50     80      91  92  93   94  95  96
134         1 2 3  4 5 6  7 8 9
136 This is a leaf-labeled tree whose labels aren't displayed. The `9200` and so on are tags to make it easier for us to refer to particular parts of the tree.
138 Suppose we want to represent that we're *at* the node marked `50`. We might use the following metalanguage notation to specify this:
140         {parent = ...; siblings = [subtree 20; *; subtree 80]}, * filled by subtree 50
142 This is modeled on the notation suggested above for list zippers. Here `subtree 20` refers to the whole subtree rooted at node `20`:
144           20
145          / | \
146         1  2  3
148 Similarly for `subtree 50` and `subtree 80`. We haven't said yet what goes in the `parent = ...` slot. Well, the parent of a subtree targetted on `node 50` should intuitively be a tree targetted on `node 500`:
150         {parent = ...; siblings = [*; subtree 920; subtree 950]}, * filled by subtree 500
152 And the parent of that targetted subtree should intuitively be a tree targetted on `node 9200`:
154         {parent = None; siblings = [*]}, * filled by tree 9200
156 This tree has no parents because it's the root of the base tree. Fully spelled out, then, our tree targetted on `node 50` would be:
158         {
159            parent = {
160               parent = {
161                  parent = None;
162                  siblings = [*]
163               }, * filled by tree 9200;
164               siblings = [*; subtree 920; subtree 950]
165            }, * filled by subtree 500;
166            siblings = [subtree 20; *; subtree 80]
167         }, * filled by subtree 50
169 In fact, there's some redundancy in this structure, at the points where we have `* filled by tree 9200` and `* filled by subtree 500`. Since node 9200 doesn't have any label attached to it, the subtree rooted in it is determined by the rest of this structure; and so too with `subtree 500`. So we could really work with:
171         {
172            parent = {
173               parent = {
174                  parent = None;
175                  siblings = [*]
176               },
177               siblings = [*; subtree 920; subtree 950]
178            },
179            siblings = [subtree 20; *; subtree 80]
180         }, * filled by subtree 50
183 We still do need to keep track of what fills the outermost targetted position---`* filled by subtree 50`---because that contain a subtree of arbitrary complexity, that is not determined by the rest of this data structure.
185 For simplicity, I'll continue to use the abbreviated form:
187         {parent = ...; siblings = [subtree 20; *; subtree 80]}, * filled by subtree 50
189 But that should be understood as standing for the more fully-spelled-out structure. Structures of this sort are called **tree zippers**. They should already seem intuitively similar to list zippers, at least in what we're using them to represent. I think it may also be helpful to call them **targetted trees**, though, and so will be switching back and forth between these different terms.
191 Moving left in our targetted tree that's targetted on `node 50` would be a matter of shifting the `*` leftwards:
193         {parent = ...; siblings = [*; subtree 50; subtree 80]}, * filled by subtree 20
195 and similarly for moving right. If the sibling list is implemented as a list zipper, you should already know how to do that. If one were designing a tree zipper for a more restricted kind of tree, however, such as a binary tree, one would probably not represent siblings with a list zipper, but with something more special-purpose and economical.
197 Moving downward in the tree would be a matter of constructing a tree targetted on some child of `node 20`, with the first part of the targetted tree above as its parent:
199         {
200            parent = {parent = ...; siblings = [*; subtree 50; subtree 80]};
201            siblings = [*; leaf 2; leaf 3]
202         }, * filled by leaf 1
204 How would we move upward in a tree? Well, we'd build a regular, untargetted tree with a root node---let's call it `20'`---and whose children are given by the outermost sibling list in the targetted tree above, after inserting the targetted subtree into the `*` position:
206                node 20'
207             /     |    \
208          /        |      \
209         leaf 1  leaf 2  leaf 3
211 We'll call this new untargetted tree `subtree 20'`. The result of moving upward from our previous targetted tree, targetted on `leaf 1`, would be the outermost `parent` element of that targetted tree, with `subtree 20'` being the subtree that fills that parent's target position `*`:
213         {
214            parent = ...;
215            siblings = [*; subtree 50; subtree 80]
216         }, * filled by subtree 20'
218 Or, spelling that structure out fully:
220         {
221            parent = {
222               parent = {
223                  parent = None;
224                  siblings = [*]
225               },
226               siblings = [*; subtree 920; subtree 950]
227            },
228            siblings = [*; subtree 50; subtree 80]
229         }, * filled by subtree 20'
231 Moving upwards yet again would get us:
233         {
234            parent = {
235               parent = None;
236               siblings = [*]
237            },
238            siblings = [*; subtree 920; subtree 950]
239         }, * filled by subtree 500'
241 where `subtree 500'` refers to a tree built from a root node whose children are given by the list `[*; subtree 50; subtree 80]`, with `subtree 20'` inserted into the `*` position. Moving upwards yet again would get us:
243         {
244            parent = None;
245            siblings = [*]
246         }, * filled by tree 9200'
248 where the targetted element is the root of our base tree. Like the "moving backward" operation for the list zipper, this "moving upward" operation is supposed to be reminiscent of closing a zipper, and that's why these data structures are called zippers.
250 We haven't given you a real implementation of the tree zipper, but only a suggestive notation. We have however told you enough that you should be able to implement it yourself. Or if you're lazy, you can read:
252 *       [[!wikipedia Zipper (data structure)]]
253 *       Huet, Gerard. ["Functional Pearl: The Zipper"](http://www.st.cs.uni-sb.de/edu/seminare/2005/advanced-fp/docs/huet-zipper.pdf) Journal of Functional Programming 7 (5): 549-554, September 1997.
254 *       As always, [Oleg](http://okmij.org/ftp/continuations/Continuations.html#zipper) takes this a few steps deeper.
257 ##Same-fringe using a zipper-based coroutine##
259 Recall back in [[Assignment4]], we asked you to enumerate the "fringe" of a leaf-labeled tree. Both of these trees (here I *am* drawing the labels in the diagram):
261             .                .
262            / \              / \
263           .   3            1   .
264          / \                  / \
265         1   2                2   3
267 have the same fringe: `[1;2;3]`. We also asked you to write a function that determined when two trees have the same fringe. The way you approached that back then was to enumerate each tree's fringe, and then compare the two lists for equality. Today, and then again in a later class, we'll encounter new ways to approach the problem of determining when two trees have the same fringe.
270 Supposing you did work out an implementation of the tree zipper, then one way to determine whether two trees have the same fringe would be: go downwards (and leftwards) in each tree as far as possible. Compare the targetted leaves. If they're different, stop because the trees have different fringes. If they're the same, then for each tree, move rightward if possible; if it's not (because you're at the rightmost position in a sibling list), more upwards then try again to move rightwards. Repeat until you are able to move rightwards. Once you do move rightwards, go downwards (and leftwards) as far as possible. Then you'll be targetted on the next leaf in the tree's fringe. The operations it takes to get to "the next leaf" may be different for the two trees. For example, in these trees:
272             .                .
273            / \              / \
274           .   3            1   .
275          / \                  / \
276         1   2                2   3
278 you won't move upwards at the same steps. Keep comparing "the next leafs" until they are different, or you exhaust the leafs of only one of the trees (then again the trees have different fringes), or you exhaust the leafs of both trees at the same time, without having found leafs with different labels. In this last case, the trees have the same fringe.
280 If your trees are very big---say, millions of leaves---you can imagine how this would be quicker and more memory-efficient than traversing each tree to construct a list of its fringe, and then comparing the two lists so built to see if they're equal. For one thing, the zipper method can abort early if the fringes diverge early, without needing to traverse or build a list containing the rest of each tree's fringe.
282 Let's sketch the implementation of this. We won't provide all the details for an implementation of the tree zipper, but we will sketch an interface for it.
284 First, we define a type for leaf-labeled, binary trees:
286         type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)
288 Next, the interface for our tree zippers. We'll help ourselves to OCaml's **record types**. These are nothing more than tuples with a pretty interface. Instead of saying:
290         # type blah = Blah of (int * int * (char -> bool));;
292 and then having to remember which element in the triple was which:
294         # let b1 = Blah (1, (fun c -> c = 'M'), 2);;
295         Error: This expression has type int * (char -> bool) * int
296        but an expression was expected of type int * int * (char -> bool)
297         # (* damnit *)
298         # let b1 = Blah (1, 2, (fun c -> c = 'M'));;
299         val b1 : blah = Blah (1, 2, <fun>)
301 records let you attach descriptive labels to the components of the tuple:
303         # type blah_record = { height : int; weight : int; char_tester : char -> bool };;
304         # let b2 = { height = 1; weight = 2; char_tester = fun c -> c = 'M' };;
305         val b2 : blah_record = {height = 1; weight = 2; char_tester = <fun>}
306         # let b3 = { height = 1; char_tester = (fun c -> c = 'K'); weight = 3 };; (* also works *)
307         val b3 : blah_record = {height = 1; weight = 3; char_tester = <fun>}
309 These were the strategies to extract the components of an unlabeled tuple:
311         let h = fst some_pair;; (* accessor functions fst and snd are only predefined for pairs *)
313         let (h, w, test) = b1;; (* works for arbitrary tuples *)
315         match b1 with
316         | (h, w, test) -> ...;; (* same as preceding *)
318 Here is how you can extract the components of a labeled record:
320         let h = b2.height;; (* handy! *)
322         let {height = h; weight = w; char_tester = test} = b2
323         in (* go on to use h, w, and test ... *)
325         match test with
326         | {height = h; weight = w; char_tester = test} ->
327                 (* go on to use h, w, and test ... *)
329 Anyway, using record types, we might define the tree zipper interface like so:
331         type 'a starred_level = Root | Starring_Left of 'a starred_nonroot | Starring_Right of 'a starred_nonroot
332         and 'a starred_nonroot = { parent : 'a starred_level; sibling: 'a tree };;
334         type 'a zipper = { level : 'a starred_level; filler: 'a tree };;
336         let rec move_botleft (z : 'a zipper) : 'a zipper =
337             (* returns z if the targetted node in z has no children *)
338             (* else returns move_botleft (zipper which results from moving down and left in z) *)
340 <!--
341             let {level; filler} = z
342             in match filler with
343             | Leaf _ -> z
344             | Node(left, right) ->
345                 let zdown = {level = Starring_Left {parent = level; sibling = right}; filler = left}
346                 in move_botleft zdown
347             ;;
348 -->
350         let rec move_right_or_up (z : 'a zipper) : 'a zipper option =
351             (* if it's possible to move right in z, returns Some (the result of doing so) *)
352             (* else if it's not possible to move any further up in z, returns None *)
353             (* else returns move_right_or_up (result of moving up in z) *)
355 <!--
356             let {level; filler} = z
357             in match level with
358             | Starring_Left {parent; sibling = right} -> Some {level = Starring_Right {parent; sibling = filler}; filler = right}
359             | Root -> None
360             | Starring_Right {parent; sibling = left} ->
361                 let z' = {level = parent; filler = Node(left, filler)}
362                 in move_right_or_up z'
363             ;;
364 -->
366 The following function takes an 'a tree and returns an 'a zipper focused on its root:
368         let new_zipper (t : 'a tree) : 'a zipper =
369             {level = Root; filler = t}
370             ;;
372 Finally, we can use a mutable reference cell to define a function that enumerates a tree's fringe until it's exhausted:
374         let make_fringe_enumerator (t: 'a tree) =
375             (* create a zipper targetting the botleft of t *)
376             let zbotleft = move_botleft (new_zipper t)
377             (* create a refcell initially pointing to zbotleft *)
378             in let zcell = ref (Some zbotleft)
379             (* construct the next_leaf function *)
380             in let next_leaf () : 'a option =
381                 match !zcell with
382                 | Some z -> (
383                     (* extract label of currently-targetted leaf *)
384                     let Leaf current = z.filler
385                     (* update zcell to point to next leaf, if there is one *)
386                     in let () = zcell := match move_right_or_up z with
387                         | None -> None
388                         | Some z' -> Some (move_botleft z')
389                     (* return saved label *)
390                     in Some current
391                 | None -> (* we've finished enumerating the fringe *)
392                     None
393                 )
394             (* return the next_leaf function *)
395             in next_leaf
396             ;;
398 Here's an example of `make_fringe_enumerator` in action:
400         # let tree1 = Leaf 1;;
401         val tree1 : int tree = Leaf 1
402         # let next1 = make_fringe_enumerator tree1;;
403         val next1 : unit -> int option = <fun>
404         # next1 ();;
405         - : int option = Some 1
406         # next1 ();;
407         - : int option = None
408         # next1 ();;
409         - : int option = None
410         # let tree2 = Node (Node (Leaf 1, Leaf 2), Leaf 3);;
411         val tree2 : int tree = Node (Node (Leaf 1, Leaf 2), Leaf 3)
412         # let next2 = make_fringe_enumerator tree2;;
413         val next2 : unit -> int option = <fun>
414         # next2 ();;
415         - : int option = Some 1
416         # next2 ();;
417         - : int option = Some 2
418         # next2 ();;
419         - : int option = Some 3
420         # next2 ();;
421         - : int option = None
422         # next2 ();;
423         - : int option = None
425 You might think of it like this: `make_fringe_enumerator` returns a little subprogram that will keep returning the next leaf in a tree's fringe, in the form `Some ...`, until it gets to the end of the fringe. After that, it will keep returning `None`.
427 Using these fringe enumerators, we can write our `same_fringe` function like this:
429         let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
430                 let next1 = make_fringe_enumerator t1
431                 in let next2 = make_fringe_enumerator t2
432                 in let rec loop () : bool =
433                         match next1 (), next2 () with
434                         | Some a, Some b when a = b -> loop ()
435                         | None, None -> true
436                         | _ -> false
437                 in loop ()
438                 ;;
440 The auxiliary `loop` function will keep calling itself recursively until a difference in the fringes has manifested itself---either because one fringe is exhausted before the other, or because the next leaves in the two fringes have different labels. If we get to the end of both fringes at the same time (`next1 (), next2 ()` matches the pattern `None, None`) then we've established that the trees do have the same fringe.
442 The technique illustrated here with our fringe enumerators is a powerful and important one. It's an example of what's sometimes called **cooperative threading**. A "thread" is a subprogram that the main computation spawns off. Threads are called "cooperative" when the code of the main computation and the thread fixes when control passes back and forth between them. (When the code doesn't control this---for example, it's determined by the operating system or the hardware in ways that the programmer can't predict---that's called "preemptive threading.") Cooperative threads are also sometimes called *coroutines* or *generators*.
444 With cooperative threads, one typically yields control to the thread, and then back again to the main program, multiple times. Here's the pattern in which that happens in our `same_fringe` function:
446         main program            next1 thread            next2 thread
447         ------------            ------------            ------------
448         start next1
449         (paused)                        starting
450         (paused)                        calculate first leaf
451         (paused)                        <--- return it
452         start next2                     (paused)                        starting
453         (paused)                        (paused)                        calculate first leaf
454         (paused)                        (paused)                        <-- return it
455         compare leaves          (paused)                        (paused)
456         call loop again         (paused)                        (paused)
457         call next1 again        (paused)                        (paused)
458         (paused)                        calculate next leaf     (paused)
459         (paused)                        <-- return it           (paused)
460         ... and so on ...
462 If you want to read more about these kinds of threads, here are some links:
464 <!-- *  [[!wikipedia Computer_multitasking]]
465 *       [[!wikipedia Thread_(computer_science)]] -->
467 *       [[!wikipedia Coroutine]]
468 *       [[!wikipedia Iterator]]
469 *       [[!wikipedia Generator_(computer_science)]]
470 *       [[!wikipedia Fiber_(computer_science)]]
471 <!-- *  [[!wikipedia Green_threads]]
472 *       [[!wikipedia Protothreads]] -->
474 The way we built cooperative threads here crucially relied on two heavyweight tools. First, it relied on our having a data structure (the tree zipper) capable of being a static snapshot of where we left off in the tree whose fringe we're enumerating. Second, it relied on our using mutable reference cells so that we could update what the current snapshot (that is, tree zipper) was, so that the next invocation of the `next_leaf` function could start up again where the previous invocation left off.
476 It's possible to build cooperative threads without using those tools, however. Some languages have a native syntax for them. Here's how we'd write the same-fringe solution above using native coroutines in the language Lua:
478         > function fringe_enumerator (tree)
479             if tree.leaf then
480                 coroutine.yield (tree.leaf)
481             else
482                 fringe_enumerator (tree.left)
483                 fringe_enumerator (tree.right)
484             end
485         end
487         > function same_fringe (tree1, tree2)
488             local next1 = coroutine.wrap (fringe_enumerator)
489             local next2 = coroutine.wrap (fringe_enumerator)
490             local function loop (leaf1, leaf2)
491                 if leaf1 or leaf2 then
492                     return leaf1 == leaf2 and loop( next1(), next2() )
493                 elseif not leaf1 and not leaf2 then
494                     return true
495                 else
496                     return false
497                 end
498             end
499             return loop (next1(tree1), next2(tree2))
500         end
502         > return same_fringe ( {leaf=1}, {leaf=2})
503         false
505         > return same_fringe ( {leaf=1}, {leaf=1})
506         true
508         > return same_fringe ( {left = {leaf=1}, right = {left = {leaf=2}, right = {leaf=3}}},
509             {left = {left = {leaf=1}, right = {leaf=2}}, right = {leaf=3}} )
510         true
512 We're going to think about the underlying principles to this execution pattern, and instead learn how to implement it from scratch---without necessarily having zippers to rely on.
515 ##Exceptions and Aborts##
517 To get a better understanding of how that execution patter works, we'll add yet a second execution pattern to our plate, and then think about what they have in common.
519 While writing OCaml code, you've probably come across errors. In fact, you've probably come across errors of two sorts. One sort of error comes about when you've got syntax errors or type errors and the OCaml interpreter isn't even able to understand your code:
521         # let lst = [1; 2] in
522           "a" :: lst;;
523         Error: This expression has type int list
524                    but an expression was expected of type string list
526 But you may also have encountered other kinds of error, that arise while your program is running. For example:
528         # 1/0;;
529         Exception: Division_by_zero.
530         # List.nth [1;2] 10;;
531         Exception: Failure "nth".
533 These "Exceptions" are **run-time errors**. OCaml will automatically detect some of them, like when you attempt to divide by zero. Other exceptions are *raised* by code. For instance, here is the implementation of `List.nth`:
535         let nth l n =
536           if n < 0 then invalid_arg "List.nth" else
537           let rec nth_aux l n =
538                 match l with
539                 | [] -> failwith "nth"
540                 | a::l -> if n = 0 then a else nth_aux l (n-1)
541           in nth_aux l n
543 Notice the two clauses `invalid_arg "List.nth"` and `failwith "nth"`. These are two helper functions which are shorthand for:
545         raise (Invalid_argument "List.nth");;
546         raise (Failure "nth");;
548 where `Invalid_argument "List.nth"` is a value of type `exn`, and so too `Failure "nth"`. When you have some value `ex` of type `exn` and evaluate the expression:
550         raise ex
552 the effect is for the program to immediately stop without evaluating any further code:
554         # let xcell = ref 0;;
555         val xcell : int ref = {contents = 0}
556         # let ex = Failure "test"
557           in let _ = raise ex
558           in xcell := 1;;
559         Exception: Failure "test".
560         # !xcell;;
561         - : int = 0
563 Notice that the line `xcell := 1` was never evaluated, so the contents of `xcell` are still `0`.
565 I said when you evaluate the expression:
567         raise ex
569 the effect is for the program to immediately stop. That's not exactly true. You can also programmatically arrange to *catch* errors, without the program necessarily stopping. In OCaml we do that with a `try ... with PATTERN -> ...` construct, analogous to the `match ... with PATTERN -> ...` construct:
571         # let foo x =
572             try
573                 if x = 1 then 10
574                 else if x = 2 then raise (Failure "two")
575                 else raise (Failure "three")
576             with Failure "two" -> 20
577             ;;
578         val foo : int -> int = <fun>
579         # foo 1;;
580         - : int = 10
581         # foo 2;;
582         - : int = 20
583         # foo 3;;
584         Exception: Failure "three".
586 Notice what happens here. If we call `foo 1`, then the code between `try` and `with` evaluates to `10`, with no exceptions being raised. That then is what the entire `try ... with ...` block evaluates to; and so too what `foo 1` evaluates to. If we call `foo 2`, then the code between `try` and `with` raises an exception `Failure "two"`. The pattern in the `with` clause matches that exception, so we get instead `20`. If we call `foo 3`, we again raise an exception. This exception isn't matched by the `with` block, so it percolates up to the top of the program, and then the program immediately stops.
588 So what I should have said is that when you evaluate the expression:
590         raise ex
592 *and that exception is never caught*, then the effect is for the program to immediately stop.
594 Of course, it's possible to handle errors in other ways too. There's no reason why the implementation of `List.nth` *had* to do things this way. They might instead have returned `Some a` when the list had an nth member `a`, and `None` when it does not. But it's pedagogically useful for us to think about this pattern now.
596 When an exception is raised, it percolates up through the code that called it, until it finds a surrounding `try ... with ...` that matches it. That might not be the first `try ... with ...` that it encounters. For example:
598         # try
599             try
600                 raise (Failure "blah")
601             with Failure "fooey" -> 10
602           with Failure "blah" -> 20;;
603         - : int = 20
605 The matching `try ... with ...` block need not *lexically surround* the site where the error was raised:
607         # let foo b x =
608             try
609                 b x
610             with Failure "blah" -> 20
611         in let bar x =
612             raise (Failure "blah")
613         in foo bar 0;;
614         - : int = 20
616 Here we call `foo bar 0`, and `foo` in turn calls `bar 0`, and `bar` raises the exception. Since there's no matching `try ... with ...` block in `bar`, we percolate back up the history of *who called this function?* and find a matching `try ... with ...` block in `foo`. This catches the error and so then the `try ... with ...` block in `foo` that called `bar` in the first place will evaluate to `20`.
618 OK, now this exception-handling apparatus does exemplify the second execution pattern we want to focus on. But it may bring it into clearer focus if we simplify the pattern even more. Imagine we could write code like this instead:
620         # let foo x =
621             try
622                 (if x = 1 then 10
623                 else abort 20) + 1
624             end
625             ;;
627 then if we called `foo 1`, we'd get the result `11`. If we called `foo 2`, on the other hand, we'd get `20` (note, not `21`). This exemplifies the same interesting "jump out of this part of the code" behavior that the `try ... raise ... with ...` code does, but without the details of matching which exception was raised, and handling the exception to produce a new result.
629 Many programming languages have this simplified exceution pattern, either instead of or alongside a `try ... with ...`-like pattern. In Lua and many other languages, `abort` is instead called `return`. The preceding example would be written:
631         > function foo(x)
632             local value
633             if (x == 1) then
634                 value = 10
635             else
636                 return 20
637             end
638             return value + 1
639         end
641         > return foo(1)
642         11
644         > return foo(2)
645         20
647 Okay, so that's our second execution pattern.
649 ##What do these have in common?##
651 In both of these patterns, we need to have some way to take a snapshot of where we are in the evaluation of a complex piece of code, so that we might later resume execution at that point. In the coroutine example, the two threads need to have a snapshot of where they were in the enumeration of their tree's leaves. In the abort example, we need to have a snapshot of where to pick up again if some embedded piece of code aborts. Sometimes we might distill that snapshot into a datastructure like a zipper. But we might not always know how to do so; and learning how to think about these snapshots without the help of zippers will help us see patterns and similarities we might otherwise miss.
653 A more general way to think about these snapshots is to think of the code we're taking a snapshot of as a *function.* For example, in this code:
655         let foo x =
656             try
657                 (if x = 1 then 10
658                 else abort 20) + 1
659             end
660         in (foo 2) + 1;;
662 we can imagine a box:
664         let foo x =
665         +---------------------------+
666         |   try                     |
667         |       (if x = 1 then 10   |
668         |       else abort 20) + 1  |
669         |   end                     |
670         +---------------------------+
671         in (foo 2) + 1;;
673 and as we're about to enter the box, we want to take a snapshot of the code *outside* the box. If we decide to abort, we'd be aborting to that snapshotted code.
675 <!--
676 # #require "delimcc";;
677 # open Delimcc;;
678 # let reset body = let p = new_prompt () in push_prompt p (body p);;
679 val reset : ('a Delimcc.prompt -> unit -> 'a) -> 'a = <fun>
680 # let foo x = reset(fun p () -> (shift p (fun k -> if x = 1 then k 10 else 20)) + 1) in (foo 1) + 100;;
681 - : int = 111
682 # let foo x = reset(fun p () -> (shift p (fun k -> if x = 1 then k 10 else 20)) + 1) in (foo 2) + 100;;
683 - : int = 120
684 -->
689 --------------------------------------
691 In coming weeks, we'll learn about a different way to create threads, that relies on **continuations** rather than on those two tools. All of these tools are inter-related. As Oleg says, "Zipper can be viewed as a delimited continuation reified as a data structure." These different tools are also inter-related with monads. Many of these tools can be used to define the others. We'll explore some of the connections between them in the remaining weeks, but we encourage you to explore more.
694 ##Introducing Continuations##
696 A continuation is "the rest of the program." Or better: an **delimited continuation** is "the rest of the program, up to a certain boundary." An **undelimited continuation** is "the rest of the program, period."
698 Even if you haven't read specifically about this notion (for example, even if you haven't read Chris and Ken's work on using continuations in natural language semantics), you'll have brushed shoulders with it already several times in this course.
700 A naive semantics for atomic sentences will say the subject term is of type `e`, and the predicate of type `e -> t`, and that the subject provides an argument to the function expressed by the predicate.
702 Monatague proposed we instead take subject terms to be of type `(e -> t) -> t`, and that now it'd be the predicate (still of type `e -> t`) that provides an argument to the function expressed by the subject.
704 If all the subject did then was supply an `e` to the `e -> t` it receives as an argument, we wouldn't have gained anything we weren't already able to do. But of course, there are other things the subject can do with the `e -> t` it receives as an argument. For instance, it can check whether anything in the domain satisfies that `e -> t`; or whether most things do; and so on.
706 This inversion of who is the argument and who is the function receiving the argument is paradigmatic of working with continuations. We did the same thing ourselves back in the early days of the seminar, for example in our implementation of pairs. In the untyped lambda calculus, we identified the pair `(x, y)` with a function:
708         \handler. handler x y
710 A pair-handling function would accept the two elements of a pair as arguments, and then do something with one or both of them. The important point here is that the handler was supplied as an argument to the pair. Eventually, the handler would itself be supplied with arguments. But only after it was supplied as an argument to the pair. This inverts the order you'd expect about what is the data or argument, and what is the function that operates on it.
712 Consider a complex computation, such as:
714         1 + 2 * (1 - g (3 + 4))
716 Part of this computation---`3 + 4`---leads up to supplying `g` with an argument. The rest of the computation---`1 + 2 * (1 - ___)`---waits for the result of applying `g` to that argument and will go on to do something with it (inserting the result into the `___` slot). That "rest of the computation" can be regarded as a function:
718         \result. 1 + 2 * (1 - result)
720 This function will be applied to whatever is the result of `g (3 + 4)`. So this function can be called the *continuation* of that application of `g`. For some purposes, it's useful to be able to invert the function/argument order here, and rather than supplying the result of applying `g` to the continuation, we instead supply the continuation to `g`. Well, not to `g` itself, since `g` only wants a single `int` argument. But we might build some `g`-like function which accepts not just an `int` argument like `g` does, but also a continuation argument.
722 Go back and read the material on "Aborting a Search Through a List" in [[Week4]] for an example of doing this.
724 In very general terms, the strategy is to work with functions like this:
726         let g' k (i : int) =
727                 ... do stuff ...
728                 ... if you want to abort early, supply an argument to k ...
729                 ... do more stuff ...
730                 ... normal result
731         in let gcon = fun result -> 1 + 2 * (1 - result)
732         in gcon (g' gcon (3 + 4))
734 It's a convention to use variables like `k` for continuation arguments. If the function `g'` never supplies an argument to its contination argument `k`, but instead just finishes evaluating to a normal result, that normal result will be delivered to `g'`'s continuation `gcon`, just as happens when we don't pass around any explicit continuation variables.
736 The above snippet of OCaml code doesn't really capture what happens when we pass explicit continuation variables. For suppose that inside `g'`, we do supply an argument to `k`. That would go into the `result` parameter in `gcon`. But then what happens once we've finished evaluating the application of `gcon` to that `result`? In the OCaml snippet above, the final value would then bubble up through the context in the body of `g'` where `k` was applied, and eventually out to the final line of the snippet, where it once again supplied an argument to `gcon`. That's not what happens with a real continuation. A real continuation works more like this:
738         let g' k (i : int) =
739                 ... do stuff ...
740                 ... if you want to abort early, supply an argument to k ...
741                 ... do more stuff ...
742                 ... normal result
743         in let gcon = fun result ->
744                 let final_value = 1 + 2 * (1 - result)
745                 in end_program_with final_value
746         in gcon (g' gcon (3 + 4))
748 So once we've finished evaluating the application of `gcon` to a `result`, the program is finished. (This is how undelimited continuations behave. We'll discuss delimited continuations later.)
750 So now, guess what would be the result of doing the following:
752         let g' k (i : int) =
753                 1 + k i
754         in let gcon = fun result ->
755                 let final_value = (1, result)
756                 in end_program_with final_value
757         in gcon (g' gcon (3 + 4))
759 <!-- (1, 7) ... explain why not (1, 8) -->
762 Refunctionalizing zippers: from lists to continuations
763 ------------------------------------------------------
765 If zippers are continuations reified (defuntionalized), then one route
766 to continuations is to re-functionalize a zipper.  Then the
767 concreteness and understandability of the zipper provides a way of
768 understanding and equivalent treatment using continuations.
770 Let's work with lists of chars for a change.  To maximize readability, we'll
771 indulge in an abbreviatory convention that "abSd" abbreviates the
772 list `['a'; 'b'; 'S'; 'd']`.
774 We will set out to compute a deceptively simple-seeming **task: given a
775 string, replace each occurrence of 'S' in that string with a copy of
776 the string up to that point.**
778 We'll define a function `t` (for "task") that maps strings to their
779 updated version.
781 Expected behavior:
783 <pre>
784 t "abSd" ~~> "ababd"
785 </pre>
788 In linguistic terms, this is a kind of anaphora
789 resolution, where `'S'` is functioning like an anaphoric element, and
790 the preceding string portion is the antecedent.
792 This deceptively simple task gives rise to some mind-bending complexity.
793 Note that it matters which 'S' you target first (the position of the *
794 indicates the targeted 'S'):
796 <pre>
797     t "aSbS"
798         *
799 ~~> t "aabS"
800           *
801 ~~> "aabaab"
802 </pre>
804 versus
806 <pre>
807     t "aSbS"
808           *
809 ~~> t "aSbaSb"
810         *
811 ~~> t "aabaSb"
812            *
813 ~~> "aabaaabab"
814 </pre>
816 versus
818 <pre>
819     t "aSbS"
820           *
821 ~~> t "aSbaSb"
822            *
823 ~~> t "aSbaaSbab"
824             *
825 ~~> t "aSbaaaSbaabab"
826              *
827 ~~> ...
828 </pre>
830 Aparently, this task, as simple as it is, is a form of computation,
831 and the order in which the `'S'`s get evaluated can lead to divergent
832 behavior.
834 For now, we'll agree to always evaluate the leftmost `'S'`, which
835 guarantees termination, and a final string without any `'S'` in it.
837 This is a task well-suited to using a zipper.  We'll define a function
838 `tz` (for task with zippers), which accomplishes the task by mapping a
839 char list zipper to a char list.  We'll call the two parts of the
840 zipper `unzipped` and `zipped`; we start with a fully zipped list, and
841 move elements to the zipped part by pulling the zipped down until the
842 entire list has been unzipped (and so the zipped half of the zipper is empty).
844 <pre>
845 type 'a list_zipper = ('a list) * ('a list);;
847 let rec tz (z:char list_zipper) =
848     match z with (unzipped, []) -> List.rev(unzipped) (* Done! *)
849                | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped)
850                | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)
852 # tz ([], ['a'; 'b'; 'S'; 'd']);;
853 - : char list = ['a'; 'b'; 'a'; 'b'; 'd']
855 # tz ([], ['a'; 'S'; 'b'; 'S']);;
856 - : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
857 </pre>
859 Note that this implementation enforces the evaluate-leftmost rule.
862 One way to see exactly what is going on is to watch the zipper in
863 action by tracing the execution of `tz`.  By using the `#trace`
864 directive in the Ocaml interpreter, the system will print out the
865 arguments to `tz` each time it is (recurcively) called.  Note that the
866 lines with left-facing arrows (`<--`) show (recursive) calls to `tz`,
867 giving the value of its argument (a zipper), and the lines with
868 right-facing arrows (`-->`) show the output of each recursive call, a
869 simple list.
871 <pre>
872 # #trace tz;;
873 t1 is now traced.
874 # tz ([], ['a'; 'b'; 'S'; 'd']);;
875 tz <-- ([], ['a'; 'b'; 'S'; 'd'])
876 tz <-- (['a'], ['b'; 'S'; 'd'])         (* Pull zipper *)
877 tz <-- (['b'; 'a'], ['S'; 'd'])         (* Pull zipper *)
878 tz <-- (['b'; 'a'; 'b'; 'a'], ['d'])    (* Special step *)
879 tz <-- (['d'; 'b'; 'a'; 'b'; 'a'], [])  (* Pull zipper *)
880 tz --> ['a'; 'b'; 'a'; 'b'; 'd']        (* Output reversed *)
881 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
882 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
883 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
884 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
885 - : char list = ['a'; 'b'; 'a'; 'b'; 'd']
886 </pre>
888 The nice thing about computations involving lists is that it's so easy
889 to visualize them as a data structure.  Eventually, we want to get to
890 a place where we can talk about more abstract computations.  In order
891 to get there, we'll first do the exact same thing we just did with
892 concrete zipper using procedures.
894 Think of a list as a procedural recipe: `['a'; 'b'; 'S'; 'd']`
895 is the result of the computation `a::(b::(S::(d::[])))` (or, in our old
896 style, `makelist a (makelist b (makelist S (makelist c empty)))`).
897 The recipe for constructing the list goes like this:
899 <pre>
900 (0)  Start with the empty list []
901 (1)  make a new list whose first element is 'd' and whose tail is the list constructed in step (0)
902 (2)  make a new list whose first element is 'S' and whose tail is the list constructed in step (1)
903 -----------------------------------------
904 (3)  make a new list whose first element is 'b' and whose tail is the list constructed in step (2)
905 (4)  make a new list whose first element is 'a' and whose tail is the list constructed in step (3)
906 </pre>
908 What is the type of each of these steps?  Well, it will be a function
909 from the result of the previous step (a list) to a new list: it will
910 be a function of type `char list -> char list`.  We'll call each step
911 a **continuation** of the recipe.  So in this context, a continuation
912 is a function of type `char list -> char list`.  For instance, the
913 continuation corresponding to the portion of the recipe below the
914 horizontal line is the function `fun (tail:char list) -> a::(b::tail)`.
916 This means that we can now represent the unzipped part of our
917 zipper--the part we've already unzipped--as a continuation: a function
918 describing how to finish building the list.  We'll write a new
919 function, `tc` (for task with continuations), that will take an input
920 list (not a zipper!) and a continuation and return a processed list.
921 The structure and the behavior will follow that of `tz` above, with
922 some small but interesting differences:
924 <pre>
925 let rec tc (l: char list) (c: (char list) -> (char list)) =
926   match l with [] -> List.rev (c [])
927              | 'S'::zipped -> tc zipped (fun x -> c (c x))
928              | target::zipped -> tc zipped (fun x -> target::(c x));;
930 # tc ['a'; 'b'; 'S'; 'd'] (fun x -> x);;
931 - : char list = ['a'; 'b'; 'a'; 'b']
933 # tc ['a'; 'S'; 'b'; 'S'] (fun x -> x);;
934 - : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
935 </pre>
937 To emphasize the parallel, I've re-used the names `zipped` and
938 `target`.  The trace of the procedure will show that these variables
939 take on the same values in the same series of steps as they did during
940 the execution of `tz` above.  There will once again be one initial and
941 four recursive calls to `tc`, and `zipped` will take on the values
942 `"bSd"`, `"Sd"`, `"d"`, and `""` (and, once again, on the final call,
943 the first `match` clause will fire, so the the variable `zipper` will
944 not be instantiated).
946 I have not called the functional argument `unzipped`, although that is
947 what the parallel would suggest.  The reason is that `unzipped` is a
948 list, but `c` is a function.  That's the most crucial difference, the
949 point of the excercise, and it should be emphasized.  For instance,
950 you can see this difference in the fact that in `tz`, we have to glue
951 together the two instances of `unzipped` with an explicit `List.append`.
952 In the `tc` version of the task, we simply compose `c` with itself:
953 `c o c = fun x -> c (c x)`.
955 Why use the identity function as the initial continuation?  Well, if
956 you have already constructed the list "abSd", what's the next step in
957 the recipe to produce the desired result (which is the same list,
958 "abSd")?  Clearly, the identity continuation.
960 A good way to test your understanding is to figure out what the
961 continuation function `c` must be at the point in the computation when
962 `tc` is called with
964 There are a number of interesting directions we can go with this task.
965 The task was chosen because the computation can be viewed as a
966 simplified picture of a computation using continuations, where `'S'`
967 plays the role of a control operator with some similarities to what is
968 often called `shift`.  &sset; &integral; In the analogy, the list
969 portrays a string of functional applications, where `[f1; f2; f3; x]`
970 represents `f1(f2(f3 x))`.  The limitation of the analogy is that it
971 is only possible to represent computations in which the applications
972 are always right-branching, i.e., the computation `((f1 f2) f3) x`
973 cannot be directly represented.
975 One possibile development is that we could add a special symbol `'#'`,
976 and then the task would be to copy from the target `'S'` only back to
977 the closest `'#'`.  This would allow the task to simulate delimited
978 continuations (for right-branching computations).
980 The task is well-suited to the list zipper because the list monad has
981 an intimate connection with continuations.  The following section
982 makes this connection.  We'll return to the list task after talking
983 about generalized quantifiers below.
986 Rethinking the list monad
987 -------------------------
989 To construct a monad, the key element is to settle on a type
990 constructor, and the monad naturally follows from that.  We'll remind
991 you of some examples of how monads follow from the type constructor in
992 a moment.  This will involve some review of familair material, but
993 it's worth doing for two reasons: it will set up a pattern for the new
994 discussion further below, and it will tie together some previously
995 unconnected elements of the course (more specifically, version 3 lists
998 For instance, take the **Reader Monad**.  Once we decide that the type
999 constructor is
1001     type 'a reader = env -> 'a
1003 then the choice of unit and bind is natural:
1005     let r_unit (a : 'a) : 'a reader = fun (e : env) -> a
1007 Since the type of an `'a reader` is `env -> 'a` (by definition),
1008 the type of the `r_unit` function is `'a -> env -> 'a`, which is a
1009 specific case of the type of the *K* combinator.  So it makes sense
1010 that *K* is the unit for the reader monad.
1012 Since the type of the `bind` operator is required to be
1014     r_bind : ('a reader) -> ('a -> 'b reader) -> ('b reader)
1016 We can reason our way to the correct `bind` function as follows. We
1017 start by declaring the types determined by the definition of a bind operation:
1019     let r_bind (u : 'a reader) (f : 'a -> 'b reader) : ('b reader) = ...
1021 Now we have to open up the `u` box and get out the `'a` object in order to
1022 feed it to `f`.  Since `u` is a function from environments to
1023 objects of type `'a`, the way we open a box in this monad is
1024 by applying it to an environment:
1026         ... f (u e) ...
1028 This subexpression types to `'b reader`, which is good.  The only
1029 problem is that we invented an environment `e` that we didn't already have ,
1030 so we have to abstract over that variable to balance the books:
1032         fun e -> f (u e) ...
1034 This types to `env -> 'b reader`, but we want to end up with `env ->
1035 'b`.  Once again, the easiest way to turn a `'b reader` into a `'b` is to apply it to an environment.  So we end up as follows:
1037     r_bind (u : 'a reader) (f : 'a -> 'b reader) : ('b reader) =
1038                 f (u e) e
1040 And we're done. This gives us a bind function of the right type. We can then check whether, in combination with the unit function we chose, it satisfies the monad laws, and behaves in the way we intend. And it does.
1042 [The bind we cite here is a condensed version of the careful `let a = u e in ...`
1043 constructions we provided in earlier lectures.  We use the condensed
1044 version here in order to emphasize similarities of structure across
1047 The **State Monad** is similar.  Once we've decided to use the following type constructor:
1049     type 'a state = store -> ('a, store)
1051 Then our unit is naturally:
1053     let s_unit (a : 'a) : ('a state) = fun (s : store) -> (a, s)
1055 And we can reason our way to the bind function in a way similar to the reasoning given above. First, we need to apply `f` to the contents of the `u` box:
1057     let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
1058                 ... f (...) ...
1060 But unlocking the `u` box is a little more complicated.  As before, we
1061 need to posit a state `s` that we can apply `u` to.  Once we do so,
1062 however, we won't have an `'a`, we'll have a pair whose first element
1063 is an `'a`.  So we have to unpack the pair:
1065         ... let (a, s') = u s in ... (f a) ...
1067 Abstracting over the `s` and adjusting the types gives the result:
1069         let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
1070                 fun (s : store) -> let (a, s') = u s in f a s'
1072 The **Option/Maybe Monad** doesn't follow the same pattern so closely, so we
1073 won't pause to explore it here, though conceptually its unit and bind
1074 follow just as naturally from its type constructor.
1076 Our other familiar monad is the **List Monad**, which we were told
1077 looks like this:
1079     type 'a list = ['a];;
1080     l_unit (a : 'a) = [a];;
1081     l_bind u f = List.concat (List.map f u);;
1083 Thinking through the list monad will take a little time, but doing so
1084 will provide a connection with continuations.
1086 Recall that `List.map` takes a function and a list and returns the
1087 result to applying the function to the elements of the list:
1089     List.map (fun i -> [i;i+1]) [1;2] ~~> [[1; 2]; [2; 3]]
1091 and List.concat takes a list of lists and erases the embdded list
1092 boundaries:
1094     List.concat [[1; 2]; [2; 3]] ~~> [1; 2; 2; 3]
1096 And sure enough,
1098     l_bind [1;2] (fun i -> [i, i+1]) ~~> [1; 2; 2; 3]
1100 Now, why this unit, and why this bind?  Well, ideally a unit should
1101 not throw away information, so we can rule out `fun x -> []` as an
1102 ideal unit.  And units should not add more information than required,
1103 so there's no obvious reason to prefer `fun x -> [x,x]`.  In other
1104 words, `fun x -> [x]` is a reasonable choice for a unit.
1106 As for bind, an `'a list` monadic object contains a lot of objects of
1107 type `'a`, and we want to make some use of each of them (rather than
1108 arbitrarily throwing some of them away).  The only
1109 thing we know for sure we can do with an object of type `'a` is apply
1110 the function of type `'a -> 'a list` to them.  Once we've done so, we
1111 have a collection of lists, one for each of the `'a`'s.  One
1112 possibility is that we could gather them all up in a list, so that
1113 `bind' [1;2] (fun i -> [i;i]) ~~> [[1;1];[2;2]]`.  But that restricts
1114 the object returned by the second argument of `bind` to always be of
1115 type `'b list list`.  We can elimiate that restriction by flattening
1116 the list of lists into a single list: this is
1117 just List.concat applied to the output of List.map.  So there is some logic to the
1118 choice of unit and bind for the list monad.
1120 Yet we can still desire to go deeper, and see if the appropriate bind
1121 behavior emerges from the types, as it did for the previously
1122 considered monads.  But we can't do that if we leave the list type
1123 as a primitive Ocaml type.  However, we know several ways of implementing
1124 lists using just functions.  In what follows, we're going to use type
1125 3 lists (the right fold implementation), though it's important to
1126 wonder how things would change if we used some other strategy for
1127 implementating lists.  These were the lists that made lists look like
1128 Church numerals with extra bits embdded in them:
1130     empty list:                fun f z -> z
1131     list with one element:     fun f z -> f 1 z
1132     list with two elements:    fun f z -> f 2 (f 1 z)
1133     list with three elements:  fun f z -> f 3 (f 2 (f 1 z))
1135 and so on.  To save time, we'll let the OCaml interpreter infer the
1136 principle types of these functions (rather than inferring what the
1137 types should be ourselves):
1139         # fun f z -> z;;
1140         - : 'a -> 'b -> 'b = <fun>
1141         # fun f z -> f 1 z;;
1142         - : (int -> 'a -> 'b) -> 'a -> 'b = <fun>
1143         # fun f z -> f 2 (f 1 z);;
1144         - : (int -> 'a -> 'a) -> 'a -> 'a = <fun>
1145         # fun f z -> f 3 (f 2 (f 1 z))
1146         - : (int -> 'a -> 'a) -> 'a -> 'a = <fun>
1148 We can see what the consistent, general principle types are at the end, so we
1149 can stop. These types should remind you of the simply-typed lambda calculus
1150 types for Church numerals (`(o -> o) -> o -> o`) with one extra type
1151 thrown in, the type of the element a the head of the list
1152 (in this case, an int).
1154 So here's our type constructor for our hand-rolled lists:
1156     type 'b list' = (int -> 'b -> 'b) -> 'b -> 'b
1158 Generalizing to lists that contain any kind of element (not just
1159 ints), we have
1161     type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b
1163 So an `('a, 'b) list'` is a list containing elements of type `'a`,
1164 where `'b` is the type of some part of the plumbing.  This is more
1165 general than an ordinary OCaml list, but we'll see how to map them
1166 into OCaml lists soon.  We don't need to fully grasp the role of the `'b`'s
1167 in order to proceed to build a monad:
1169     l'_unit (a : 'a) : ('a, 'b) list = fun a -> fun f z -> f a z
1171 No problem.  Arriving at bind is a little more complicated, but
1172 exactly the same principles apply, you just have to be careful and
1173 systematic about it.
1175     l'_bind (u : ('a,'b) list') (f : 'a -> ('c, 'd) list') : ('c, 'd) list'  = ...
1177 Unpacking the types gives:
1179     l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
1180             (f : 'a -> ('c -> 'd -> 'd) -> 'd -> 'd)
1181             : ('c -> 'd -> 'd) -> 'd -> 'd = ...
1183 Perhaps a bit intimiating.
1184 But it's a rookie mistake to quail before complicated types. You should
1185 be no more intimiated by complex types than by a linguistic tree with
1186 deeply embedded branches: complex structure created by repeated
1187 application of simple rules.
1189 [This would be a good time to try to build your own term for the types
1190 just given.  Doing so (or attempting to do so) will make the next
1191 paragraph much easier to follow.]
1193 As usual, we need to unpack the `u` box.  Examine the type of `u`.
1194 This time, `u` will only deliver up its contents if we give `u` an
1195 argument that is a function expecting an `'a` and a `'b`. `u` will
1196 fold that function over its type `'a` members, and that's how we'll get the `'a`s we need. Thus:
1198         ... u (fun (a : 'a) (b : 'b) -> ... f a ... ) ...
1200 In order for `u` to have the kind of argument it needs, the `... (f a) ...` has to evaluate to a result of type `'b`. The easiest way to do this is to collapse (or "unify") the types `'b` and `'d`, with the result that `f a` will have type `('c -> 'b -> 'b) -> 'b -> 'b`. Let's postulate an argument `k` of type `('c -> 'b -> 'b)` and supply it to `(f a)`:
1202         ... u (fun (a : 'a) (b : 'b) -> ... f a k ... ) ...
1204 Now we have an argument `b` of type `'b`, so we can supply that to `(f a) k`, getting a result of type `'b`, as we need:
1206         ... u (fun (a : 'a) (b : 'b) -> f a k b) ...
1208 Now, we've used a `k` that we pulled out of nowhere, so we need to abstract over it:
1210         fun (k : 'c -> 'b -> 'b) -> u (fun (a : 'a) (b : 'b) -> f a k b)
1212 This whole expression has type `('c -> 'b -> 'b) -> 'b -> 'b`, which is exactly the type of a `('c, 'b) list'`. So we can hypothesize that we our bind is:
1214     l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
1215             (f : 'a -> ('c -> 'b -> 'b) -> 'b -> 'b)
1216             : ('c -> 'b -> 'b) -> 'b -> 'b =
1217       fun k -> u (fun a b -> f a k b)
1219 That is a function of the right type for our bind, but to check whether it works, we have to verify it (with the unit we chose) against the monad laws, and reason whether it will have the right behavior.
1221 Here's a way to persuade yourself that it will have the right behavior. First, it will be handy to eta-expand our `fun k -> u (fun a b -> f a k b)` to:
1223       fun k z -> u (fun a b -> f a k b) z
1225 Now let's think about what this does. It's a wrapper around `u`. In order to behave as the list which is the result of mapping `f` over each element of `u`, and then joining (`concat`ing) the results, this wrapper would have to accept arguments `k` and `z` and fold them in just the same way that the list which is the result of mapping `f` and then joining the results would fold them. Will it?
1227 Suppose we have a list' whose contents are `[1; 2; 4; 8]`---that is, our list' will be `fun f z -> f 1 (f 2 (f 4 (f 8 z)))`. We call that list' `u`. Suppose we also have a function `f` that for each `int` we give it, gives back a list of the divisors of that `int` that are greater than 1. Intuitively, then, binding `u` to `f` should give us:
1229         concat (map f u) =
1230         concat [[]; ; [2; 4]; [2; 4; 8]] =
1231         [2; 2; 4; 2; 4; 8]
1233 Or rather, it should give us a list' version of that, which takes a function `k` and value `z` as arguments, and returns the right fold of `k` and `z` over those elements. What does our formula
1235       fun k z -> u (fun a b -> f a k b) z
1237 do? Well, for each element `a` in `u`, it applies `f` to that `a`, getting one of the lists:
1239         []
1240         
1241         [2; 4]
1242         [2; 4; 8]
1244 (or rather, their list' versions). Then it takes the accumulated result `b` of previous steps in the fold, and it folds `k` and `b` over the list generated by `f a`. The result of doing so is passed on to the next step as the accumulated result so far.
1246 So if, for example, we let `k` be `+` and `z` be `0`, then the computation would proceed:
1248         0 ==>
1249         right-fold + and 0 over [2; 4; 8] = 2+4+8+0 ==>
1250         right-fold + and 2+4+8+0 over [2; 4] = 2+4+2+4+8+0 ==>
1251         right-fold + and 2+4+2+4+8+0 over  = 2+2+4+2+4+8+0 ==>
1252         right-fold + and 2+2+4+2+4+8+0 over [] = 2+2+4+2+4+8+0
1254 which indeed is the result of right-folding + and 0 over `[2; 2; 4; 2; 4; 8]`. If you trace through how this works, you should be able to persuade yourself that our formula:
1256       fun k z -> u (fun a b -> f a k b) z
1258 will deliver just the same folds, for arbitrary choices of `k` and `z` (with the right types), and arbitrary list's `u` and appropriately-typed `f`s, as
1260         fun k z -> List.fold_right k (concat (map f u)) z
1262 would.
1264 For future reference, we might make two eta-reductions to our formula, so that we have instead:
1266       let l'_bind = fun k -> u (fun a -> f a k);;
1268 Let's make some more tests:
1271     l_bind [1;2] (fun i -> [i, i+1]) ~~> [1; 2; 2; 3]
1273     l'_bind (fun f z -> f 1 (f 2 z))
1274             (fun i -> fun f z -> f i (f (i+1) z)) ~~> <fun>
1276 Sigh.  OCaml won't show us our own list.  So we have to choose an `f`
1277 and a `z` that will turn our hand-crafted lists into standard OCaml
1278 lists, so that they will print out.
1280         # let cons h t = h :: t;;  (* OCaml is stupid about :: *)
1281         # l'_bind (fun f z -> f 1 (f 2 z))
1282                           (fun i -> fun f z -> f i (f (i+1) z)) cons [];;
1283         - : int list = [1; 2; 2; 3]
1285 Ta da!
1288 Montague's PTQ treatment of DPs as generalized quantifiers
1289 ----------------------------------------------------------
1291 We've hinted that Montague's treatment of DPs as generalized
1292 quantifiers embodies the spirit of continuations (see de Groote 2001,
1293 Barker 2002 for lengthy discussion).  Let's see why.
1295 First, we'll need a type constructor.  As you probably know,
1296 Montague replaced individual-denoting determiner phrases (with type `e`)
1297 with generalized quantifiers (with [extensional] type `(e -> t) -> t`.
1298 In particular, the denotation of a proper name like *John*, which
1299 might originally denote a object `j` of type `e`, came to denote a
1300 generalized quantifier `fun pred -> pred j` of type `(e -> t) -> t`.
1301 Let's write a general function that will map individuals into their
1302 corresponding generalized quantifier:
1304    gqize (a : e) = fun (p : e -> t) -> p a
1306 This function is what Partee 1987 calls LIFT, and it would be
1307 reasonable to use it here, but we will avoid that name, given that we
1308 use that word to refer to other functions.
1310 This function wraps up an individual in a box.  That is to say,
1311 we are in the presence of a monad.  The type constructor, the unit and
1312 the bind follow naturally.  We've done this enough times that we won't
1313 belabor the construction of the bind function, the derivation is
1314 highly similar to the List monad just given:
1316         type 'a continuation = ('a -> 'b) -> 'b
1317         c_unit (a : 'a) = fun (p : 'a -> 'b) -> p a
1318         c_bind (u : ('a -> 'b) -> 'b) (f : 'a -> ('c -> 'd) -> 'd) : ('c -> 'd) -> 'd =
1319           fun (k : 'a -> 'b) -> u (fun (a : 'a) -> f a k)
1321 Note that `c_bind` is exactly the `gqize` function that Montague used
1322 to lift individuals into the continuation monad.
1324 That last bit in `c_bind` looks familiar---we just saw something like
1325 it in the List monad.  How similar is it to the List monad?  Let's
1326 examine the type constructor and the terms from the list monad derived
1327 above:
1329     type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b
1330     l'_unit a = fun f -> f a
1331     l'_bind u f = fun k -> u (fun a -> f a k)
1333 (We performed a sneaky but valid eta reduction in the unit term.)
1335 The unit and the bind for the Montague continuation monad and the
1336 homemade List monad are the same terms!  In other words, the behavior
1337 of the List monad and the behavior of the continuations monad are
1338 parallel in a deep sense.
1340 Have we really discovered that lists are secretly continuations?  Or
1341 have we merely found a way of simulating lists using list
1342 continuations?  Well, strictly speaking, what we have done is shown
1343 that one particular implementation of lists---the right fold
1344 implementation---gives rise to a continuation monad fairly naturally,
1345 and that this monad can reproduce the behavior of the standard list
1346 monad.  But what about other list implementations?  Do they give rise
1347 to monads that can be understood in terms of continuations?
1349 Manipulating trees with monads
1350 ------------------------------
1352 This thread develops an idea based on a detailed suggestion of Ken
1353 Shan's.  We'll build a series of functions that operate on trees,
1354 doing various things, including replacing leaves, counting nodes, and
1355 converting a tree to a list of leaves.  The end result will be an
1356 application for continuations.
1358 From an engineering standpoint, we'll build a tree transformer that
1359 deals in monads.  We can modify the behavior of the system by swapping
1361 a layer of funtionality without disturbing the underlying system, for
1362 instance, in the way that the reader monad allowed us to add a layer
1363 of intensionality to an extensional grammar, but we have not yet seen
1364 the utility of replacing one monad with other.)
1366 First, we'll be needing a lot of trees during the remainder of the
1367 course.  Here's a type constructor for binary trees:
1369     type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)
1371 These are trees in which the internal nodes do not have labels.  [How
1372 would you adjust the type constructor to allow for labels on the
1373 internal nodes?]
1375 We'll be using trees where the nodes are integers, e.g.,
1378 <pre>
1379 let t1 = Node ((Node ((Leaf 2), (Leaf 3))),
1380                (Node ((Leaf 5),(Node ((Leaf 7),
1381                                       (Leaf 11))))))
1383     .
1384  ___|___
1385  |     |
1386  .     .
1387 _|__  _|__
1388 |  |  |  |
1389 2  3  5  .
1390         _|__
1391         |  |
1392         7  11
1393 </pre>
1395 Our first task will be to replace each leaf with its double:
1397 <pre>
1398 let rec treemap (newleaf:'a -> 'b) (t:'a tree):('b tree) =
1399   match t with Leaf x -> Leaf (newleaf x)
1400              | Node (l, r) -> Node ((treemap newleaf l),
1401                                     (treemap newleaf r));;
1402 </pre>
1403 `treemap` takes a function that transforms old leaves into new leaves,
1404 and maps that function over all the leaves in the tree, leaving the
1405 structure of the tree unchanged.  For instance:
1407 <pre>
1408 let double i = i + i;;
1409 treemap double t1;;
1410 - : int tree =
1411 Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
1413     .
1414  ___|____
1415  |      |
1416  .      .
1417 _|__  __|__
1418 |  |  |   |
1419 4  6  10  .
1420         __|___
1421         |    |
1422         14   22
1423 </pre>
1425 We could have built the doubling operation right into the `treemap`
1426 code.  However, because what to do to each leaf is a parameter, we can
1427 decide to do something else to the leaves without needing to rewrite
1428 `treemap`.  For instance, we can easily square each leaf instead by
1429 supplying the appropriate `int -> int` operation in place of `double`:
1431 <pre>
1432 let square x = x * x;;
1433 treemap square t1;;
1434 - : int tree =ppp
1435 Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
1436 </pre>
1438 Note that what `treemap` does is take some global, contextual
1439 information---what to do to each leaf---and supplies that information
1440 to each subpart of the computation.  In other words, `treemap` has the
1441 behavior of a reader monad.  Let's make that explicit.
1443 In general, we're on a journey of making our treemap function more and
1444 more flexible.  So the next step---combining the tree transducer with
1445 a reader monad---is to have the treemap function return a (monadized)
1446 tree that is ready to accept any `int->int` function and produce the
1447 updated tree.
1449 \tree (. (. (f2) (f3))(. (f5) (.(f7)(f11))))
1450 <pre>
1451 \f    .
1452   ____|____
1453   |       |
1454   .       .
1455 __|__   __|__
1456 |   |   |   |
1457 f2  f3  f5  .
1458           __|___
1459           |    |
1460           f7  f11
1461 </pre>
1463 That is, we want to transform the ordinary tree `t1` (of type `int
1464 tree`) into a reader object of type `(int->int)-> int tree`: something
1465 that, when you apply it to an `int->int` function returns an `int
1466 tree` in which each leaf `x` has been replaced with `(f x)`.
1468 With previous readers, we always knew which kind of environment to
1469 expect: either an assignment function (the original calculator
1470 simulation), a world (the intensionality monad), an integer (the
1471 Jacobson-inspired link monad), etc.  In this situation, it will be
1472 enough for now to expect that our reader will expect a function of
1473 type `int->int`.
1475 <pre>
1476 type 'a reader = (int->int) -> 'a;;  (* mnemonic: e for environment *)
1477 let reader_unit (x:'a): 'a reader = fun _ -> x;;
1478 let reader_bind (u: 'a reader) (f:'a -> 'c reader):'c reader = fun e -> f (u e) e;;
1479 </pre>
1481 It's easy to figure out how to turn an `int` into an `int reader`:
1483 <pre>
1484 let int2int_reader (x:'a): 'b reader = fun (op:'a -> 'b) -> op x;;
1485 int2int_reader 2 (fun i -> i + i);;
1486 - : int = 4
1487 </pre>
1489 But what do we do when the integers are scattered over the leaves of a
1490 tree?  A binary tree is not the kind of thing that we can apply a
1491 function of type `int->int` to.
1493 <pre>
1494 let rec treemonadizer (f:'a -> 'b reader) (t:'a tree):('b tree) reader =
1495   match t with Leaf x -> reader_bind (f x) (fun x' -> reader_unit (Leaf x'))
1496              | Node (l, r) -> reader_bind (treemonadizer f l) (fun x ->
1497                                 reader_bind (treemonadizer f r) (fun y ->
1498                                   reader_unit (Node (x, y))));;
1499 </pre>
1501 This function says: give me a function `f` that knows how to turn
1502 something of type `'a` into an `'b reader`, and I'll show you how to
1503 turn an `'a tree` into an `'a tree reader`.  In more fanciful terms,
1504 the `treemonadizer` function builds plumbing that connects all of the
1505 leaves of a tree into one connected monadic network; it threads the
1506 monad through the leaves.
1508 <pre>
1509 # treemonadizer int2int_reader t1 (fun i -> i + i);;
1510 - : int tree =
1511 Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
1512 </pre>
1514 Here, our environment is the doubling function (`fun i -> i + i`).  If
1515 we apply the very same `int tree reader` (namely, `treemonadizer
1516 int2int_reader t1`) to a different `int->int` function---say, the
1517 squaring function, `fun i -> i * i`---we get an entirely different
1518 result:
1520 <pre>
1521 # treemonadizer int2int_reader t1 (fun i -> i * i);;
1522 - : int tree =
1523 Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
1524 </pre>
1526 Now that we have a tree transducer that accepts a monad as a
1527 parameter, we can see what it would take to swap in a different monad.
1528 For instance, we can use a state monad to count the number of nodes in
1529 the tree.
1531 <pre>
1532 type 'a state = int -> 'a * int;;
1533 let state_unit x i = (x, i+.5);;
1534 let state_bind u f i = let (a, i') = u i in f a (i'+.5);;
1535 </pre>
1537 Gratifyingly, we can use the `treemonadizer` function without any
1538 modification whatsoever, except for replacing the (parametric) type
1539 `reader` with `state`:
1541 <pre>
1542 let rec treemonadizer (f:'a -> 'b state) (t:'a tree):('b tree) state =
1543   match t with Leaf x -> state_bind (f x) (fun x' -> state_unit (Leaf x'))
1544              | Node (l, r) -> state_bind (treemonadizer f l) (fun x ->
1545                                 state_bind (treemonadizer f r) (fun y ->
1546                                   state_unit (Node (x, y))));;
1547 </pre>
1549 Then we can count the number of nodes in the tree:
1551 <pre>
1552 # treemonadizer state_unit t1 0;;
1553 - : int tree * int =
1554 (Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11))), 13)
1556     .
1557  ___|___
1558  |     |
1559  .     .
1560 _|__  _|__
1561 |  |  |  |
1562 2  3  5  .
1563         _|__
1564         |  |
1565         7  11
1566 </pre>
1568 Notice that we've counted each internal node twice---it's a good
1569 exercise to adjust the code to count each node once.
1571 One more revealing example before getting down to business: replacing
1572 `state` everywhere in `treemonadizer` with `list` gives us
1574 <pre>
1575 # treemonadizer (fun x -> [ [x; square x] ]) t1;;
1576 - : int list tree list =
1577 [Node
1578   (Node (Leaf [2; 4], Leaf [3; 9]),
1579    Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))]
1580 </pre>
1582 Unlike the previous cases, instead of turning a tree into a function
1583 from some input to a result, this transformer replaces each `int` with
1584 a list of `int`'s.
1586 Now for the main point.  What if we wanted to convert a tree to a list
1587 of leaves?
1589 <pre>
1590 type ('a, 'r) continuation = ('a -> 'r) -> 'r;;
1591 let continuation_unit x c = c x;;
1592 let continuation_bind u f c = u (fun a -> f a c);;
1594 let rec treemonadizer (f:'a -> ('b, 'r) continuation) (t:'a tree):(('b tree), 'r) continuation =
1595   match t with Leaf x -> continuation_bind (f x) (fun x' -> continuation_unit (Leaf x'))
1596              | Node (l, r) -> continuation_bind (treemonadizer f l) (fun x ->
1597                                 continuation_bind (treemonadizer f r) (fun y ->
1598                                   continuation_unit (Node (x, y))));;
1599 </pre>
1601 We use the continuation monad described above, and insert the
1602 `continuation` type in the appropriate place in the `treemonadizer` code.
1603 We then compute:
1605 <pre>
1606 # treemonadizer (fun a c -> a :: (c a)) t1 (fun t -> []);;
1607 - : int list = [2; 3; 5; 7; 11]
1608 </pre>
1610 We have found a way of collapsing a tree into a list of its leaves.
1612 The continuation monad is amazingly flexible; we can use it to
1613 simulate some of the computations performed above.  To see how, first
1614 note that an interestingly uninteresting thing happens if we use the
1615 continuation unit as our first argument to `treemonadizer`, and then
1616 apply the result to the identity function:
1618 <pre>
1619 # treemonadizer continuation_unit t1 (fun x -> x);;
1620 - : int tree =
1621 Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))
1622 </pre>
1624 That is, nothing happens.  But we can begin to substitute more
1625 interesting functions for the first argument of `treemonadizer`:
1627 <pre>
1628 (* Simulating the tree reader: distributing a operation over the leaves *)
1629 # treemonadizer (fun a c -> c (square a)) t1 (fun x -> x);;
1630 - : int tree =
1631 Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
1633 (* Simulating the int list tree list *)
1634 # treemonadizer (fun a c -> c [a; square a]) t1 (fun x -> x);;
1635 - : int list tree =
1636 Node
1637  (Node (Leaf [2; 4], Leaf [3; 9]),
1638   Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))
1640 (* Counting leaves *)
1641 # treemonadizer (fun a c -> 1 + c a) t1 (fun x -> 0);;
1642 - : int = 5
1643 </pre>
1645 We could simulate the tree state example too, but it would require
1646 generalizing the type of the continuation monad to
1648     type ('a -> 'b -> 'c) continuation = ('a -> 'b) -> 'c;;
1650 The binary tree monad
1651 ---------------------
1653 Of course, by now you may have realized that we have discovered a new
1656 <pre>
1657 type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
1658 let tree_unit (x:'a) = Leaf x;;
1659 let rec tree_bind (u:'a tree) (f:'a -> 'b tree):'b tree =
1660   match u with Leaf x -> f x
1661              | Node (l, r) -> Node ((tree_bind l f), (tree_bind r f));;
1662 </pre>
1664 For once, let's check the Monad laws.  The left identity law is easy:
1666     Left identity: bind (unit a) f = bind (Leaf a) f = fa
1668 To check the other two laws, we need to make the following
1669 observation: it is easy to prove based on `tree_bind` by a simple
1670 induction on the structure of the first argument that the tree
1671 resulting from `bind u f` is a tree with the same strucure as `u`,
1672 except that each leaf `a` has been replaced with `fa`:
1674 \tree (. (fa1) (. (. (. (fa2)(fa3)) (fa4)) (fa5)))
1675 <pre>
1676                 .                         .
1677               __|__                     __|__
1678               |   |                     |   |
1679               a1  .                    fa1  .
1680                  _|__                     __|__
1681                  |  |                     |   |
1682                  .  a5                    .  fa5
1683    bind         _|__       f   =        __|__
1684                 |  |                    |   |
1685                 .  a4                   .  fa4
1686               __|__                   __|___
1687               |   |                   |    |
1688               a2  a3                 fa2  fa3
1689 </pre>
1691 Given this equivalence, the right identity law
1693     Right identity: bind u unit = u
1695 falls out once we realize that
1697     bind (Leaf a) unit = unit a = Leaf a
1699 As for the associative law,
1701     Associativity: bind (bind u f) g = bind u (\a. bind (fa) g)
1703 we'll give an example that will show how an inductive proof would
1704 proceed.  Let `f a = Node (Leaf a, Leaf a)`.  Then
1706 \tree (. (. (. (. (a1)(a2)))))
1707 \tree (. (. (. (. (a1) (a1)) (. (a1) (a1)))  ))
1708 <pre>
1709                                            .
1710                                        ____|____
1711           .               .            |       |
1712 bind    __|__   f  =    __|_    =      .       .
1713         |   |           |   |        __|__   __|__
1714         a1  a2         fa1 fa2       |   |   |   |
1715                                      a1  a1  a1  a1
1716 </pre>
1718 Now when we bind this tree to `g`, we get
1720 <pre>
1721            .
1722        ____|____
1723        |       |
1724        .       .
1725      __|__   __|__
1726      |   |   |   |
1727     ga1 ga1 ga1 ga1
1728 </pre>
1730 At this point, it should be easy to convince yourself that
1731 using the recipe on the right hand side of the associative law will
1732 built the exact same final tree.
1734 So binary trees are a monad.