1 [[!toc]]
3 ##Same-fringe using a zipper-based coroutine##
5 Recall back in [[Assignment4]], we asked you to enumerate the "fringe" of a leaf-labeled tree. Both of these trees (here I *am* drawing the labels in the diagram):
7             .                .
8            / \              / \
9           .   3            1   .
10          / \                  / \
11         1   2                2   3
13 have the same fringe: `[1;2;3]`. We also asked you to write a function that determined when two trees have the same fringe. The way you approached that back then was to enumerate each tree's fringe, and then compare the two lists for equality. Today, and then again in a later class, we'll encounter new ways to approach the problem of determining when two trees have the same fringe.
16 Supposing you did work out an implementation of the tree zipper, then one way to determine whether two trees have the same fringe would be: go downwards (and leftwards) in each tree as far as possible. Compare the targetted leaves. If they're different, stop because the trees have different fringes. If they're the same, then for each tree, move rightward if possible; if it's not (because you're at the rightmost position in a sibling list), more upwards then try again to move rightwards. Repeat until you are able to move rightwards. Once you do move rightwards, go downwards (and leftwards) as far as possible. Then you'll be targetted on the next leaf in the tree's fringe. The operations it takes to get to "the next leaf" may be different for the two trees. For example, in these trees:
18             .                .
19            / \              / \
20           .   3            1   .
21          / \                  / \
22         1   2                2   3
24 you won't move upwards at the same steps. Keep comparing "the next leafs" until they are different, or you exhaust the leafs of only one of the trees (then again the trees have different fringes), or you exhaust the leafs of both trees at the same time, without having found leafs with different labels. In this last case, the trees have the same fringe.
26 If your trees are very big---say, millions of leaves---you can imagine how this would be quicker and more memory-efficient than traversing each tree to construct a list of its fringe, and then comparing the two lists so built to see if they're equal. For one thing, the zipper method can abort early if the fringes diverge early, without needing to traverse or build a list containing the rest of each tree's fringe.
28 Let's sketch the implementation of this. We won't provide all the details for an implementation of the tree zipper, but we will sketch an interface for it.
30 First, we define a type for leaf-labeled, binary trees:
32         type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)
34 Next, the interface for our tree zippers. We'll help ourselves to OCaml's **record types**. These are nothing more than tuples with a pretty interface. Instead of saying:
36         # type blah = Blah of (int * int * (char -> bool));;
38 and then having to remember which element in the triple was which:
40         # let b1 = Blah (1, (fun c -> c = 'M'), 2);;
41         Error: This expression has type int * (char -> bool) * int
42        but an expression was expected of type int * int * (char -> bool)
43         # (* damnit *)
44         # let b1 = Blah (1, 2, (fun c -> c = 'M'));;
45         val b1 : blah = Blah (1, 2, <fun>)
47 records let you attach descriptive labels to the components of the tuple:
49         # type blah_record = { height : int; weight : int; char_tester : char -> bool };;
50         # let b2 = { height = 1; weight = 2; char_tester = fun c -> c = 'M' };;
51         val b2 : blah_record = {height = 1; weight = 2; char_tester = <fun>}
52         # let b3 = { height = 1; char_tester = (fun c -> c = 'K'); weight = 3 };; (* also works *)
53         val b3 : blah_record = {height = 1; weight = 3; char_tester = <fun>}
55 These were the strategies to extract the components of an unlabeled tuple:
57         let h = fst some_pair;; (* accessor functions fst and snd are only predefined for pairs *)
59         let (h, w, test) = b1;; (* works for arbitrary tuples *)
61         match b1 with
62         | (h, w, test) -> ...;; (* same as preceding *)
64 Here is how you can extract the components of a labeled record:
66         let h = b2.height;; (* handy! *)
68         let {height = h; weight = w; char_tester = test} = b2
69         in (* go on to use h, w, and test ... *)
71         match test with
72         | {height = h; weight = w; char_tester = test} ->
73                 (* go on to use h, w, and test ... *)
75 Anyway, using record types, we might define the tree zipper interface like so:
77         type 'a starred_level = Root | Starring_Left of 'a starred_nonroot | Starring_Right of 'a starred_nonroot
78         and 'a starred_nonroot = { parent : 'a starred_level; sibling: 'a tree };;
80         type 'a zipper = { level : 'a starred_level; filler: 'a tree };;
82         let rec move_botleft (z : 'a zipper) : 'a zipper =
83             (* returns z if the targetted node in z has no children *)
84             (* else returns move_botleft (zipper which results from moving down and left in z) *)
86 <!--
87             let {level; filler} = z
88             in match filler with
89             | Leaf _ -> z
90             | Node(left, right) ->
91                 let zdown = {level = Starring_Left {parent = level; sibling = right}; filler = left}
92                 in move_botleft zdown
93             ;;
94 -->
96         let rec move_right_or_up (z : 'a zipper) : 'a zipper option =
97             (* if it's possible to move right in z, returns Some (the result of doing so) *)
98             (* else if it's not possible to move any further up in z, returns None *)
99             (* else returns move_right_or_up (result of moving up in z) *)
101 <!--
102             let {level; filler} = z
103             in match level with
104             | Starring_Left {parent; sibling = right} -> Some {level = Starring_Right {parent; sibling = filler}; filler = right}
105             | Root -> None
106             | Starring_Right {parent; sibling = left} ->
107                 let z' = {level = parent; filler = Node(left, filler)}
108                 in move_right_or_up z'
109             ;;
110 -->
112 The following function takes an 'a tree and returns an 'a zipper focused on its root:
114         let new_zipper (t : 'a tree) : 'a zipper =
115             {level = Root; filler = t}
116             ;;
118 Finally, we can use a mutable reference cell to define a function that enumerates a tree's fringe until it's exhausted:
120         let make_fringe_enumerator (t: 'a tree) =
121             (* create a zipper targetting the botleft of t *)
122             let zbotleft = move_botleft (new_zipper t)
123             (* create a refcell initially pointing to zbotleft *)
124             in let zcell = ref (Some zbotleft)
125             (* construct the next_leaf function *)
126             in let next_leaf () : 'a option =
127                 match !zcell with
128                 | Some z -> (
129                     (* extract label of currently-targetted leaf *)
130                     let Leaf current = z.filler
131                     (* update zcell to point to next leaf, if there is one *)
132                     in let () = zcell := match move_right_or_up z with
133                         | None -> None
134                         | Some z' -> Some (move_botleft z')
135                     (* return saved label *)
136                     in Some current
137                 | None -> (* we've finished enumerating the fringe *)
138                     None
139                 )
140             (* return the next_leaf function *)
141             in next_leaf
142             ;;
144 Here's an example of `make_fringe_enumerator` in action:
146         # let tree1 = Leaf 1;;
147         val tree1 : int tree = Leaf 1
148         # let next1 = make_fringe_enumerator tree1;;
149         val next1 : unit -> int option = <fun>
150         # next1 ();;
151         - : int option = Some 1
152         # next1 ();;
153         - : int option = None
154         # next1 ();;
155         - : int option = None
156         # let tree2 = Node (Node (Leaf 1, Leaf 2), Leaf 3);;
157         val tree2 : int tree = Node (Node (Leaf 1, Leaf 2), Leaf 3)
158         # let next2 = make_fringe_enumerator tree2;;
159         val next2 : unit -> int option = <fun>
160         # next2 ();;
161         - : int option = Some 1
162         # next2 ();;
163         - : int option = Some 2
164         # next2 ();;
165         - : int option = Some 3
166         # next2 ();;
167         - : int option = None
168         # next2 ();;
169         - : int option = None
171 You might think of it like this: `make_fringe_enumerator` returns a little subprogram that will keep returning the next leaf in a tree's fringe, in the form `Some ...`, until it gets to the end of the fringe. After that, it will keep returning `None`.
173 Using these fringe enumerators, we can write our `same_fringe` function like this:
175         let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
176                 let next1 = make_fringe_enumerator t1
177                 in let next2 = make_fringe_enumerator t2
178                 in let rec loop () : bool =
179                         match next1 (), next2 () with
180                         | Some a, Some b when a = b -> loop ()
181                         | None, None -> true
182                         | _ -> false
183                 in loop ()
184                 ;;
186 The auxiliary `loop` function will keep calling itself recursively until a difference in the fringes has manifested itself---either because one fringe is exhausted before the other, or because the next leaves in the two fringes have different labels. If we get to the end of both fringes at the same time (`next1 (), next2 ()` matches the pattern `None, None`) then we've established that the trees do have the same fringe.
188 The technique illustrated here with our fringe enumerators is a powerful and important one. It's an example of what's sometimes called **cooperative threading**. A "thread" is a subprogram that the main computation spawns off. Threads are called "cooperative" when the code of the main computation and the thread fixes when control passes back and forth between them. (When the code doesn't control this---for example, it's determined by the operating system or the hardware in ways that the programmer can't predict---that's called "preemptive threading.") Cooperative threads are also sometimes called *coroutines* or *generators*.
190 With cooperative threads, one typically yields control to the thread, and then back again to the main program, multiple times. Here's the pattern in which that happens in our `same_fringe` function:
193         ------------            ------------            ------------
194         start next1
195         (paused)                        starting
196         (paused)                        calculate first leaf
197         (paused)                        <--- return it
198         start next2                     (paused)                        starting
199         (paused)                        (paused)                        calculate first leaf
200         (paused)                        (paused)                        <-- return it
201         compare leaves          (paused)                        (paused)
202         call loop again         (paused)                        (paused)
203         call next1 again        (paused)                        (paused)
204         (paused)                        calculate next leaf     (paused)
205         (paused)                        <-- return it           (paused)
206         ... and so on ...
213 *       [[!wikipedia Coroutine]]
214 *       [[!wikipedia Iterator]]
215 *       [[!wikipedia Generator_(computer_science)]]
216 *       [[!wikipedia Fiber_(computer_science)]]
220 The way we built cooperative threads here crucially relied on two heavyweight tools. First, it relied on our having a data structure (the tree zipper) capable of being a static snapshot of where we left off in the tree whose fringe we're enumerating. Second, it relied on our using mutable reference cells so that we could update what the current snapshot (that is, tree zipper) was, so that the next invocation of the `next_leaf` function could start up again where the previous invocation left off.
222 It's possible to build cooperative threads without using those tools, however. Some languages have a native syntax for them. Here's how we'd write the same-fringe solution above using native coroutines in the language Lua:
224         > function fringe_enumerator (tree)
225             if tree.leaf then
226                 coroutine.yield (tree.leaf)
227             else
228                 fringe_enumerator (tree.left)
229                 fringe_enumerator (tree.right)
230             end
231         end
233         > function same_fringe (tree1, tree2)
234             local next1 = coroutine.wrap (fringe_enumerator)
235             local next2 = coroutine.wrap (fringe_enumerator)
236             local function loop (leaf1, leaf2)
237                 if leaf1 or leaf2 then
238                     return leaf1 == leaf2 and loop( next1(), next2() )
239                 elseif not leaf1 and not leaf2 then
240                     return true
241                 else
242                     return false
243                 end
244             end
245             return loop (next1(tree1), next2(tree2))
246         end
248         > return same_fringe ( {leaf=1}, {leaf=2} )
249         false
251         > return same_fringe ( {leaf=1}, {leaf=1} )
252         true
254         > return same_fringe ( {left = {leaf=1}, right = {left = {leaf=2}, right = {leaf=3}}},
255             {left = {left = {leaf=1}, right = {leaf=2}}, right = {leaf=3}} )
256         true
258 We're going to think about the underlying principles to this execution pattern, and instead learn how to implement it from scratch---without necessarily having zippers to rely on.
261 ##Exceptions and Aborts##
263 To get a better understanding of how that execution pattern works, we'll add yet a second execution pattern to our plate, and then think about what they have in common.
265 While writing OCaml code, you've probably come across errors. In fact, you've probably come across errors of two sorts. One sort of error comes about when you've got syntax errors or type errors and the OCaml interpreter isn't even able to understand your code:
267         # let lst = [1; 2] in
268           "a" :: lst;;
269         Error: This expression has type int list
270                    but an expression was expected of type string list
272 But you may also have encountered other kinds of error, that arise while your program is running. For example:
274         # 1/0;;
275         Exception: Division_by_zero.
276         # List.nth [1;2] 10;;
277         Exception: Failure "nth".
279 These "Exceptions" are **run-time errors**. OCaml will automatically detect some of them, like when you attempt to divide by zero. Other exceptions are *raised* by code. For instance, here is the implementation of `List.nth`:
281         let nth l n =
282           if n < 0 then invalid_arg "List.nth" else
283           let rec nth_aux l n =
284                 match l with
285                 | [] -> failwith "nth"
286                 | a::l -> if n = 0 then a else nth_aux l (n-1)
287           in nth_aux l n
289 Notice the two clauses `invalid_arg "List.nth"` and `failwith "nth"`. These are two helper functions which are shorthand for:
291         raise (Invalid_argument "List.nth");;
292         raise (Failure "nth");;
294 where `Invalid_argument "List.nth"` is a value of type `exn`, and so too `Failure "nth"`. When you have some value `bad` of type `exn` and evaluate the expression:
298 the effect is for the program to immediately stop without evaluating any further code:
300         # let xcell = ref 0;;
301         val xcell : int ref = {contents = 0}
302         # let bad = Failure "test"
303           in let _ = raise bad
304           in xcell := 1;;
305         Exception: Failure "test".
306         # !xcell;;
307         - : int = 0
309 Notice that the line `xcell := 1` was never evaluated, so the contents of `xcell` are still `0`.
311 I said when you evaluate the expression:
315 the effect is for the program to immediately stop. That's not exactly true. You can also programmatically arrange to *catch* errors, without the program necessarily stopping. In OCaml we do that with a `try ... with PATTERN -> ...` construct, analogous to the `match ... with PATTERN -> ...` construct:
317         # let foo x =
318             try
319                 if x = 1 then 10
320                 else if x = 2 then raise (Failure "two")
321                 else raise (Failure "three")
322             with Failure "two" -> 20
323             ;;
324         val foo : int -> int = <fun>
325         # foo 1;;
326         - : int = 10
327         # foo 2;;
328         - : int = 20
329         # foo 3;;
330         Exception: Failure "three".
332 Notice what happens here. If we call `foo 1`, then the code between `try` and `with` evaluates to `10`, with no exceptions being raised. That then is what the entire `try ... with ...` block evaluates to; and so too what `foo 1` evaluates to. If we call `foo 2`, then the code between `try` and `with` raises an exception `Failure "two"`. The pattern in the `with` clause matches that exception, so we get instead `20`. If we call `foo 3`, we again raise an exception. This exception isn't matched by the `with` block, so it percolates up to the top of the program, and then the program immediately stops.
334 So what I should have said is that when you evaluate the expression:
338 *and that exception is never caught*, then the effect is for the program to immediately stop.
340 Of course, it's possible to handle errors in other ways too. There's no reason why the implementation of `List.nth` *had* to do things this way. They might instead have returned `Some a` when the list had an nth member `a`, and `None` when it does not. But it's pedagogically useful for us to think about this pattern now.
342 When an exception is raised, it percolates up through the code that called it, until it finds a surrounding `try ... with ...` that matches it. That might not be the first `try ... with ...` that it encounters. For example:
344         # try
345             try
346                 raise (Failure "blah")
347             with Failure "fooey" -> 10
348           with Failure "blah" -> 20;;
349         - : int = 20
351 The matching `try ... with ...` block need not *lexically surround* the site where the error was raised:
353         # let foo b x =
354             try
355                 b x
356             with Failure "blah" -> 20
357         in let bar x =
358             raise (Failure "blah")
359         in foo bar 0;;
360         - : int = 20
362 Here we call `foo bar 0`, and `foo` in turn calls `bar 0`, and `bar` raises the exception. Since there's no matching `try ... with ...` block in `bar`, we percolate back up the history of who called that function, and we find a matching `try ... with ...` block in `foo`. This catches the error and so then the `try ... with ...` block in `foo` (the code that called `bar` in the first place) will evaluate to `20`.
364 OK, now this exception-handling apparatus does exemplify the second execution pattern we want to focus on. But it may bring it into clearer focus if we simplify the pattern even more. Imagine we could write code like this instead:
366         # let foo x =
367             try begin
368                 (if x = 1 then 10
369                 else abort 20) + 100
370             end
371             ;;
373 then if we called `foo 1`, we'd get the result `110`. If we called `foo 2`, on the other hand, we'd get `20` (note, not `120`). This exemplifies the same interesting "jump out of this part of the code" behavior that the `try ... raise ... with ...` code does, but without the details of matching which exception was raised, and handling the exception to produce a new result.
375 Many programming languages have this simplified exceution pattern, either instead of or alongside a `try ... with ...`-like pattern. In Lua and many other languages, `abort` is instead called `return`. In Lua, the preceding example would be written:
377         > function foo(x)
378             local value
379             if (x == 1) then
380                 value = 10
381             else
382                 return 20
383             end
384             return value + 100
385         end
387         > return foo(1)
388         110
390         > return foo(2)
391         20
393 Okay, so that's our second execution pattern.
395 ##What do these have in common?##
397 In both of these patterns, we need to have some way to take a snapshot of where we are in the evaluation of a complex piece of code, so that we might later resume execution at that point. In the coroutine example, the two threads need to have a snapshot of where they were in the enumeration of their tree's leaves. In the abort example, we need to have a snapshot of where to pick up again if some embedded piece of code aborts. Sometimes we might distill that snapshot into a data structure like a zipper. But we might not always know how to do so; and learning how to think about these snapshots without the help of zippers will help us see patterns and similarities we might otherwise miss.
399 A more general way to think about these snapshots is to think of the code we're taking a snapshot of as a *function.* For example, in this code:
401         let foo x =
402             try begin
403                 (if x = 1 then 10
404                 else abort 20) + 100
405             end
406         in (foo 2) + 1;;
408 we can imagine a box:
410         let foo x =
411         +---try begin----------------+
412         |       (if x = 1 then 10    |
413         |       else abort 20) + 100 |
414         +---end----------------------+
415         in (foo 2) + 1000;;
417 and as we're about to enter the box, we want to take a snapshot of the code *outside* the box. If we decide to abort, we'd be aborting to that snapshotted code.
420 What would a "snapshot of the code outside the box" look like? Well, let's rearrange the code somewhat. It should be equivalent to this:
422         let x = 2 in
423         let foo_result =
424         +---try begin----------------+
425         |       (if x = 1 then 10    |
426         |       else abort 20) + 100 |
427         +---end----------------------+
428         in (foo_result) + 1000;;
430 and we can think of the code starting with `let foo_result = ...` as a function, with the box being its parameter, like this:
432         fun box ->
433                 let foo_result = box
434                 in (foo_result) + 1000
436 That function is our "snapshot". Normally what happens is that code *inside* the box delivers up a value, and that value gets supplied as an argument to the snapshot-function just described. That is, our code is essentially working like this:
438         let x = 2
439         in let snapshot = fun box ->
440                 let foo_result = box
441                 in (foo_result) + 1000
442         in let value =
443                 (if x = 1 then 10
444                 else ... (* we'll come back to this part *)
445                 ) + 100
446         in shapshot value;;
448 But now how should the `abort 20` part, that we ellided here, work? What should happen when we try to evaluate that?
450 Well, that's when we use the snapshot code in an unusual way. If we encounter an `abort 20`, we should abandon the code we're currently executing, and instead just supply `20` to the snapshot we saved when we entered the box. That is, something like this:
452         let x = 2
453         in let snapshot = fun box ->
454                 let foo_result = box
455                 in (foo_result) + 1000
456         in let value =
457                 (if x = 1 then 10
458                 else snapshot 20
459                 ) + 100
460         in shapshot value;;
462 Except that isn't quite right, yet---in this fragment, after the snapshot code is finished, we'd pick up again inside `let value = (...) + 100 in snapshot value`. We don't want to pick up again there. We want instead to do this:
464         let x = 2
465         in let snapshot = fun box ->
466                 let foo_result = box
467                 in (foo_result) + 1000
468         in let value =
469                 (if x = 1 then 10
470                 else snapshot 20 THEN STOP
471                 ) + 100
472         in shapshot value;;
474 We can get that by some further rearranging of the code:
476         let x = 2
477         in let snapshot = fun box ->
478                 let foo_result = box
479                 in (foo_result) + 1000
480         in let finish_value = fun start ->
481                 let value = start + 100
482                 in snapshot value
483         in
484                 if x = 1 then finish_value 10
485                 else snapshot 20;;
487 And this is indeed what is happening, at a fundamental level, when you use an expression like `abort 20`.
489 <!--
490 # #require "delimcc";;
491 # open Delimcc;;
492 # let reset body = let p = new_prompt () in push_prompt p (body p);;
493 # let test_cps x =
494           let snapshot = fun box ->
495                   let foo_result = box
496                   in (foo_result) + 1000
497           in let finish_value = fun start ->
498                   let value = start + 100
499                   in snapshot value
500           in if x = 1 then finish_value 10
501           else snapshot 20;;
503         let foo x =
504         +===try begin================+
505         |       (if x = 1 then 10    |
506         |       else abort 20) + 100 |
507         +===end======================+
508         in (foo 2) + 1000;;
510 # let test_shift x =
511         let foo x = reset(fun p () ->
512                 (shift p (fun k ->
513                         if x = 1 then k 10 else 20)
514                 ) + 100)
515         in foo z + 1000;;
517 # test_cps 1;;
518 - : int = 1110
519 # test_shift 1;;
520 - : int = 1110
521 # test_cps 2;;
522 - : int = 1020
523 # test_shift 2;;
524 - : int = 1020
525 -->
527 A similar kind of "snapshotting" lets coroutines keep track of where the left off, so that they can start up again at that same place.
529 These snapshots are called **continuations** because they represent how the computation will "continue" once some target code (in our example, the code in the box) delivers up a value.
531 You can think of them as functions that represent "how the rest of the computation proposes to continue." Except that, once we're able to get our hands on those functions, we can do exotic and unwholesome things with them. Like use them to abort from deep inside a sub-computation. Or suspend and resume a thread. One function might pass the command to abort *it* to a subfunction, so that the subfunction has the power to jump directly to the outside caller. Or a function might *return* its continuation function to the outside caller, giving the outside caller the ability to "abort" the function (that has already returned its value---what should happen then?) Maybe we'd call the same continuation function *multiple times* (what should happen then?). All of these weird and wonderful possibilities await us.