+ mcomp f g 7 ==> [49, 50, 14, 15]
+
+`g 7` produced `[49, 14]`, which after being fed through `f` gave us `[49, 50, 14, 15]`.
+
+Contrast that to `m$` (`mapply`, which operates not on two *box-producing functions*, but instead on two *values of a boxed type*, one containing functions to be applied to the values in the other box, via some predefined scheme. Thus:
+
+ let gs = [(\a->a*a),(\a->a+a)] in
+ let xs = [7, 5] in
+ mapply gs xs ==> [49, 25, 14, 10]
+
+
+As we illustrated in class, there are clear patterns shared between lists and option types and trees, so perhaps you can see why people want to identify the general structures. But it probably isn't obvious yet why it would be useful to do so. To a large extent, this will only emerge over the next few classes. But we'll begin to demonstrate the usefulness of these patterns by talking through a simple example, that uses the Monadic functions of the Option/Maybe box type.
+
+
+Safe division
+-------------
+
+Integer division presupposes that its second argument
+(the divisor) is not zero, upon pain of presupposition failure.
+Here's what my OCaml interpreter says:
+
+ # 12/0;;
+ Exception: Division_by_zero.
+
+Say we want to explicitly allow for the possibility that
+division will return something other than a number.
+To do that, we'll use OCaml's `option` type, which works like this:
+
+ # type 'a option = None | Some of 'a;;
+ # None;;
+ - : 'a option = None
+ # Some 3;;
+ - : int option = Some 3
+
+So if a division is normal, we return some number, but if the divisor is
+zero, we return `None`. As a mnemonic aid, we'll prepend a `safe_` to the start of our new divide function.
+
+<pre>
+let safe_div (x:int) (y:int) =
+ match y with
+ | 0 -> None
+ | _ -> Some (x / y);;
+
+(*
+val safe_div : int -> int -> int option = fun
+# safe_div 12 2;;
+- : int option = Some 6
+# safe_div 12 0;;
+- : int option = None
+# safe_div (safe_div 12 2) 3;;
+# safe_div (safe_div 12 2) 3;;
+ ~~~~~~~~~~~~~
+Error: This expression has type int option
+ but an expression was expected of type int
+*)
+</pre>
+
+This starts off well: dividing 12 by 2, no problem; dividing 12 by 0,
+just the behavior we were hoping for. But we want to be able to use
+the output of the safe-division function as input for further division
+operations. So we have to jack up the types of the inputs:
+
+<pre>
+let safe_div2 (u:int option) (v:int option) =
+ match u with
+ None -> None
+ | Some x -> (match v with
+ Some 0 -> None
+ | Some y -> Some (x / y));;
+
+(*
+val safe_div2 : int option -> int option -> int option = <fun>
+# safe_div2 (Some 12) (Some 2);;
+- : int option = Some 6
+# safe_div2 (Some 12) (Some 0);;
+- : int option = None
+# safe_div2 (safe_div2 (Some 12) (Some 0)) (Some 3);;
+- : int option = None
+*)
+</pre>
+
+Beautiful, just what we need: now we can try to divide by anything we
+want, without fear that we're going to trigger any system errors.
+
+I prefer to line up the `match` alternatives by using OCaml's
+built-in tuple type:
+
+<pre>
+let safe_div2 (u:int option) (v:int option) =
+ match (u, v) with
+ | (None, _) -> None
+ | (_, None) -> None
+ | (_, Some 0) -> None
+ | (Some x, Some y) -> Some (x / y);;
+</pre>
+
+So far so good. But what if we want to combine division with
+other arithmetic operations? We need to make those other operations
+aware of the possibility that one of their arguments has triggered a
+presupposition failure:
+
+<pre>
+let safe_add (u:int option) (v:int option) =
+ match (u, v) with
+ | (None, _) -> None
+ | (_, None) -> None
+ | (Some x, Some y) -> Some (x + y);;
+
+(*
+val safe_add : int option -> int option -> int option = <fun>
+# safe_add (Some 12) (Some 4);;
+- : int option = Some 16
+# safe_add (safe_div (Some 12) (Some 0)) (Some 4);;
+- : int option = None
+*)
+</pre>
+
+This works, but is somewhat disappointing: the `safe_add` operation
+doesn't trigger any presupposition of its own, so it is a shame that
+it needs to be adjusted because someone else might make trouble.
+
+But we can automate the adjustment. The standard way in OCaml,
+Haskell, and other functional programming languages, is to use the monadic
+`bind` operator, `>>=`. (The name "bind" is not well chosen from our
+perspective, but this is too deeply entrenched by now.) As mentioned above,
+there needs to be a different `>>=` operator for each Monad or box type you're working with.
+Haskell finesses this by "overloading" the single symbol `>>=`; you can just input that
+symbol and it will calculate from the context of the surrounding type constraints what
+monad you must have meant. In OCaml, the `>>=` or `bind` operator is not pre-defined, but we will
+give you a library that has definitions for all the standard monads, as in Haskell.
+For now, though, we will define our `bind` operation by hand:
+
+<pre>
+let bind (u: int option) (f: int -> (int option)) =
+ match u with
+ | None -> None
+ | Some x -> f x;;
+
+let safe_add3 (u: int option) (v: int option) =
+ bind u (fun x -> bind v (fun y -> Some (x + y)));;
+
+(* This is really just `map2 (+)`, using the `map2` operation that corresponds to
+ definition of `bind`. *)
+
+let safe_div3 (u: int option) (v: int option) =
+ bind u (fun x -> bind v (fun y -> if 0 = y then None else Some (x / y)));;
+
+(* This goes back to some of the simplicity of the original safe_div, without the complexity
+ introduced by safe_div2. *)
+</pre>
+
+The above definitions look even simpler if you focus on the fact that `safe_add3` can be written as simply `map2 (+)`, and that `safe_div3` could be written as `u >>= fun x -> v >>= fun y -> if 0 = y then None else Some (x / y)`. Haskell has an even more user-friendly notation for this, namely:
+
+ safe_div3 :: Maybe Int -> Maybe Int -> Maybe Int
+ safe_div3 u v = do {x <- u;
+ y <- v;
+ if 0 == y then Nothing else return (x `div` y)}
+
+Let's see our new functions in action:
+
+<pre>
+(*
+# safe_div3 (safe_div3 (Some 12) (Some 2)) (Some 3);;
+- : int option = Some 2
+# safe_div3 (safe_div3 (Some 12) (Some 0)) (Some 3);;
+- : int option = None
+# safe_add3 (safe_div3 (Some 12) (Some 0)) (Some 3);;
+- : int option = None
+*)
+</pre>
+
+Compare the new definitions of `safe_add3` and `safe_div3` closely: the definition
+for `safe_add3` shows what it looks like to equip an ordinary operation to
+survive in dangerous presupposition-filled world. Note that the new
+definition of `safe_add3` does not need to test whether its arguments are
+None objects or real numbers---those details are hidden inside of the
+`bind` function.
+
+The definition of `safe_div3` shows exactly what extra needs to be said in
+order to trigger the no-division-by-zero presupposition. Here, too, we don't
+need to keep track of what presuppositions may have already failed
+for whatever reason on our inputs.
+
+(Linguistics note: Dividing by zero is supposed to feel like a kind of
+presupposition failure. If we wanted to adapt this approach to
+building a simple account of presupposition projection, we would have
+to do several things. First, we would have to make use of the
+polymorphism of the `option` type. In the arithmetic example, we only
+made use of `int option`s, but when we're composing natural language
+expression meanings, we'll need to use types like `N option`, `Det option`,
+`VP option`, and so on. But that works automatically, because we can use
+any type for the `'a` in `'a option`. Ultimately, we'd want to have a
+theory of accommodation, and a theory of the situations in which
+material within the sentence can satisfy presuppositions for other
+material that otherwise would trigger a presupposition violation; but,
+not surprisingly, these refinements will require some more
+sophisticated techniques than the super-simple Option monad.)