+++ /dev/null
-[[!toc]]
-
-Manipulating trees with monads
-------------------------------
-
-This topic develops an idea based on a suggestion of Ken Shan's.
-We'll build a series of functions that operate on trees, doing various
-things, including updating leaves with a Reader monad, counting nodes
-with a State monad, replacing leaves with a List monad, and converting
-a tree into a list of leaves with a Continuation monad. It will turn
-out that the continuation monad can simulate the behavior of each of
-the other monads.
-
-From an engineering standpoint, we'll build a tree transformer that
-deals in monads. We can modify the behavior of the system by swapping
-one monad for another. We've already seen how adding a monad can add
-a layer of funtionality without disturbing the underlying system, for
-instance, in the way that the Reader monad allowed us to add a layer
-of intensionality to an extensional grammar, but we have not yet seen
-the utility of replacing one monad with other.
-
-First, we'll be needing a lot of trees for the remainder of the
-course. Here again is a type constructor for leaf-labeled, binary trees:
-
- type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)
-
-[How would you adjust the type constructor to allow for labels on the
-internal nodes?]
-
-We'll be using trees where the nodes are integers, e.g.,
-
-
- let t1 = Node (Node (Leaf 2, Leaf 3),
- Node (Leaf 5, Node (Leaf 7,
- Leaf 11)))
- .
- ___|___
- | |
- . .
- _|_ _|__
- | | | |
- 2 3 5 .
- _|__
- | |
- 7 11
-
-Our first task will be to replace each leaf with its double:
-
- let rec tree_map (leaf_modifier : 'a -> 'b) (t : 'a tree) : 'b tree =
- match t with
- | Leaf i -> Leaf (leaf_modifier i)
- | Node (l, r) -> Node (tree_map leaf_modifier l,
- tree_map leaf_modifier r);;
-
-`tree_map` takes a function that transforms old leaves into new leaves,
-and maps that function over all the leaves in the tree, leaving the
-structure of the tree unchanged. For instance:
-
- let double i = i + i;;
- tree_map double t1;;
- - : int tree =
- Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
-
- .
- ___|____
- | |
- . .
- _|__ __|__
- | | | |
- 4 6 10 .
- __|___
- | |
- 14 22
-
-We could have built the doubling operation right into the `tree_map`
-code. However, because we've made what to do to each leaf a
-parameter, we can decide to do something else to the leaves without
-needing to rewrite `tree_map`. For instance, we can easily square
-each leaf instead by supplying the appropriate `int -> int` operation
-in place of `double`:
-
- let square i = i * i;;
- tree_map square t1;;
- - : int tree =ppp
- Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
-
-Note that what `tree_map` does is take some unchanging contextual
-information---what to do to each leaf---and supplies that information
-to each subpart of the computation. In other words, `tree_map` has the
-behavior of a Reader monad. Let's make that explicit.
-
-In general, we're on a journey of making our `tree_map` function more and
-more flexible. So the next step---combining the tree transformer with
-a Reader monad---is to have the `tree_map` function return a (monadized)
-tree that is ready to accept any `int -> int` function and produce the
-updated tree.
-
-\tree (. (. (f 2) (f 3)) (. (f 5) (. (f 7) (f 11))))
-
- \f .
- _____|____
- | |
- . .
- __|___ __|___
- | | | |
- f 2 f 3 f 5 .
- __|___
- | |
- f 7 f 11
-
-That is, we want to transform the ordinary tree `t1` (of type `int
-tree`) into a reader monadic object of type `(int -> int) -> int
-tree`: something that, when you apply it to an `int -> int` function
-`f` returns an `int tree` in which each leaf `i` has been replaced
-with `f i`.
-
-[Application note: this kind of reader object could provide a model
-for Kaplan's characters. It turns an ordinary tree into one that
-expects contextual information (here, the `λ f`) that can be
-used to compute the content of indexicals embedded arbitrarily deeply
-in the tree.]
-
-With our previous applications of the Reader monad, we always knew
-which kind of environment to expect: either an assignment function, as
-in the original calculator simulation; a world, as in the
-intensionality monad; an individual, as in the Jacobson-inspired link
-monad; etc. In the present case, we expect that our "environment"
-will be some function of type `int -> int`. "Looking up" some `int` in
-the environment will return us the `int` that comes out the other side
-of that function.
-
- type 'a reader = (int -> int) -> 'a;; (* mnemonic: e for environment *)
- let reader_unit (a : 'a) : 'a reader = fun _ -> a;;
- let reader_bind (u: 'a reader) (f : 'a -> 'b reader) : 'b reader = fun e -> f (u e) e;;
-
-It would be a simple matter to turn an *integer* into an `int reader`:
-
- let int_readerize : int -> int reader = fun (a : int) -> fun (modifier : int -> int) -> modifier a;;
- int_readerize 2 (fun i -> i + i);;
- - : int = 4
-
-But how do we do the analagous transformation when our `int`s are scattered over the leaves of a tree? How do we turn an `int tree` into a reader?
-A tree is not the kind of thing that we can apply a
-function of type `int -> int` to.
-
-But we can do this:
-
- let rec tree_monadize (f : 'a -> 'b reader) (t : 'a tree) : 'b tree reader =
- match t with
- | Leaf a -> reader_bind (f a) (fun b -> reader_unit (Leaf b))
- | Node (l, r) -> reader_bind (tree_monadize f l) (fun l' ->
- reader_bind (tree_monadize f r) (fun r' ->
- reader_unit (Node (l', r'))));;
-
-This function says: give me a function `f` that knows how to turn
-something of type `'a` into an `'b reader`---this is a function of the same type that you could bind an `'a reader` to---and I'll show you how to
-turn an `'a tree` into an `'b tree reader`. That is, if you show me how to do this:
-
- ------------
- 1 ---> | 1 |
- ------------
-
-then I'll give you back the ability to do this:
-
- ____________
- . | . |
- __|___ ---> | __|___ |
- | | | | | |
- 1 2 | 1 2 |
- ------------
-
-And how will that boxed tree behave? Whatever actions you perform on it will be transmitted down to corresponding operations on its leaves. For instance, our `int reader` expects an `int -> int` environment. If supplying environment `e` to our `int reader` doubles the contained `int`:
-
- ------------
- 1 ---> | 1 | applied to e ~~> 2
- ------------
-
-Then we can expect that supplying it to our `int tree reader` will double all the leaves:
-
- ____________
- . | . | .
- __|___ ---> | __|___ | applied to e ~~> __|___
- | | | | | | | |
- 1 2 | 1 2 | 2 4
- ------------
-
-In more fanciful terms, the `tree_monadize` function builds plumbing that connects all of the leaves of a tree into one connected monadic network; it threads the
-`'b reader` monad through the original tree's leaves.
-
- # tree_monadize int_readerize t1 double;;
- - : int tree =
- Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
-
-Here, our environment is the doubling function (`fun i -> i + i`). If
-we apply the very same `int tree reader` (namely, `tree_monadize
-int_readerize t1`) to a different `int -> int` function---say, the
-squaring function, `fun i -> i * i`---we get an entirely different
-result:
-
- # tree_monadize int_readerize t1 square;;
- - : int tree =
- Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
-
-Now that we have a tree transformer that accepts a *reader* monad as a
-parameter, we can see what it would take to swap in a different monad.
-
-For instance, we can use a State monad to count the number of leaves in
-the tree.
-
- type 'a state = int -> 'a * int;;
- let state_unit a = fun s -> (a, s);;
- let state_bind u f = fun s -> let (a, s') = u s in f a s';;
-
-Gratifyingly, we can use the `tree_monadize` function without any
-modification whatsoever, except for replacing the (parametric) type
-`'b reader` with `'b state`, and substituting in the appropriate unit and bind:
-
- let rec tree_monadize (f : 'a -> 'b state) (t : 'a tree) : 'b tree state =
- match t with
- | Leaf a -> state_bind (f a) (fun b -> state_unit (Leaf b))
- | Node (l, r) -> state_bind (tree_monadize f l) (fun l' ->
- state_bind (tree_monadize f r) (fun r' ->
- state_unit (Node (l', r'))));;
-
-Then we can count the number of leaves in the tree:
-
- # tree_monadize (fun a -> fun s -> (a, s+1)) t1 0;;
- - : int tree * int =
- (Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11))), 5)
-
- .
- ___|___
- | |
- . .
- _|__ _|__ , 5
- | | | |
- 2 3 5 .
- _|__
- | |
- 7 11
-
-Note that the value returned is a pair consisting of a tree and an
-integer, 5, which represents the count of the leaves in the tree.
-
-Why does this work? Because the operation `fun a -> fun s -> (a, s+1)`
-takes an `int` and wraps it in an `int state` monadic box that
-increments the state. When we give that same operations to our
-`tree_monadize` function, it then wraps an `int tree` in a box, one
-that does the same state-incrementing for each of its leaves.
-
-One more revealing example before getting down to business: replacing
-`state` everywhere in `tree_monadize` with `list` gives us
-
- # tree_monadize (fun i -> [ [i; square i] ]) t1;;
- - : int list tree list =
- [Node
- (Node (Leaf [2; 4], Leaf [3; 9]),
- Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))]
-
-Unlike the previous cases, instead of turning a tree into a function
-from some input to a result, this transformer replaces each `int` with
-a list of `int`'s. We might also have done this with a Reader monad, though then our environments would need to be of type `int -> int list`. Experiment with what happens if you supply the `tree_monadize` based on the List monad an operation like `fun -> [ i; [2*i; 3*i] ]`. Use small trees for your experiment.
-
-[Why is the argument to tree_monadize `int -> int list list` instead
-of `int -> int list`? Well, as usual, the List monad bind operation
-will erase the outer list box, so if we want to replace the leaves
-with lists, we have to nest the replacement lists inside a disposable
-box.]
-
-Now for the main point. What if we wanted to convert a tree to a list
-of leaves?
-
- type ('a, 'r) continuation = ('a -> 'r) -> 'r;;
- let continuation_unit a = fun k -> k a;;
- let continuation_bind u f = fun k -> u (fun a -> f a k);;
-
- let rec tree_monadize (f : 'a -> ('b, 'r) continuation) (t : 'a tree) : ('b tree, 'r) continuation =
- match t with
- | Leaf a -> continuation_bind (f a) (fun b -> continuation_unit (Leaf b))
- | Node (l, r) -> continuation_bind (tree_monadize f l) (fun l' ->
- continuation_bind (tree_monadize f r) (fun r' ->
- continuation_unit (Node (l', r'))));;
-
-We use the Continuation monad described above, and insert the
-`continuation` type in the appropriate place in the `tree_monadize` code. Then if we give the `tree_monadize` function an operation that converts `int`s into `'b`-wrapping Continuation monads, it will give us back a way to turn `int tree`s into corresponding `'b tree`-wrapping Continuation monads.
-
-So for example, we compute:
-
- # tree_monadize (fun a -> fun k -> a :: k a) t1 (fun t -> []);;
- - : int list = [2; 3; 5; 7; 11]
-
-We have found a way of collapsing a tree into a list of its leaves. Can you trace how this is working? Think first about what the operation `fun a -> fun k -> a :: k a` does when you apply it to a plain `int`, and the continuation `fun _ -> []`. Then given what we've said about `tree_monadize`, what should we expect `tree_monadize (fun a -> fun k -> a :: k a` to do?
-
-The Continuation monad is amazingly flexible; we can use it to
-simulate some of the computations performed above. To see how, first
-note that an interestingly uninteresting thing happens if we use
-`continuation_unit` as our first argument to `tree_monadize`, and then
-apply the result to the identity function:
-
- # tree_monadize continuation_unit t1 (fun t -> t);;
- - : int tree =
- Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))
-
-That is, nothing happens. But we can begin to substitute more
-interesting functions for the first argument of `tree_monadize`:
-
- (* Simulating the tree reader: distributing a operation over the leaves *)
- # tree_monadize (fun a -> fun k -> k (square a)) t1 (fun t -> t);;
- - : int tree =
- Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
-
- (* Simulating the int list tree list *)
- # tree_monadize (fun a -> fun k -> k [a; square a]) t1 (fun t -> t);;
- - : int list tree =
- Node
- (Node (Leaf [2; 4], Leaf [3; 9]),
- Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))
-
- (* Counting leaves *)
- # tree_monadize (fun a -> fun k -> 1 + k a) t1 (fun t -> 0);;
- - : int = 5
-
-We could simulate the tree state example too, but it would require
-generalizing the type of the Continuation monad to
-
- type ('a, 'b, 'c) continuation = ('a -> 'b) -> 'c;;
-
-If you want to see how to parameterize the definition of the `tree_monadize` function, so that you don't have to keep rewriting it for each new monad, see [this code](/code/tree_monadize.ml).
-
-
-The Binary Tree monad
----------------------
-
-Of course, by now you may have realized that we have discovered a new
-monad, the Binary Tree monad. Just as mere lists are in fact a monad,
-so are trees. Here is the type constructor, unit, and bind:
-
- type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
- let tree_unit (a: 'a) : 'a tree = Leaf a;;
- let rec tree_bind (u : 'a tree) (f : 'a -> 'b tree) : 'b tree =
- match u with
- | Leaf a -> f a
- | Node (l, r) -> Node (tree_bind l f, tree_bind r f);;
-
-For once, let's check the Monad laws. The left identity law is easy:
-
- Left identity: bind (unit a) f = bind (Leaf a) f = f a
-
-To check the other two laws, we need to make the following
-observation: it is easy to prove based on `tree_bind` by a simple
-induction on the structure of the first argument that the tree
-resulting from `bind u f` is a tree with the same strucure as `u`,
-except that each leaf `a` has been replaced with `f a`:
-
-\tree (. (f a1) (. (. (. (f a2) (f a3)) (f a4)) (f a5)))
-
- . .
- __|__ __|__
- | | | |
- a1 . f a1 .
- _|__ __|__
- | | | |
- . a5 . f a5
- bind _|__ f = __|__
- | | | |
- . a4 . f a4
- __|__ __|___
- | | | |
- a2 a3 f a2 f a3
-
-Given this equivalence, the right identity law
-
- Right identity: bind u unit = u
-
-falls out once we realize that
-
- bind (Leaf a) unit = unit a = Leaf a
-
-As for the associative law,
-
- Associativity: bind (bind u f) g = bind u (\a. bind (f a) g)
-
-we'll give an example that will show how an inductive proof would
-proceed. Let `f a = Node (Leaf a, Leaf a)`. Then
-
-\tree (. (. (. (. (a1) (a2)))))
-\tree (. (. (. (. (a1) (a1)) (. (a1) (a1)))))
-
- .
- ____|____
- . . | |
- bind __|__ f = __|_ = . .
- | | | | __|__ __|__
- a1 a2 f a1 f a2 | | | |
- a1 a1 a1 a1
-
-Now when we bind this tree to `g`, we get
-
- .
- _____|______
- | |
- . .
- __|__ __|__
- | | | |
- g a1 g a1 g a1 g a1
-
-At this point, it should be easy to convince yourself that
-using the recipe on the right hand side of the associative law will
-built the exact same final tree.
-
-So binary trees are a monad.
-
-Haskell combines this monad with the Option monad to provide a monad
-called a
-[SearchTree](http://hackage.haskell.org/packages/archive/tree-monad/0.2.1/doc/html/src/Control-Monad-SearchTree.html#SearchTree)
-that is intended to represent non-deterministic computations as a tree.
-
-
-What's this have to do with tree\_mondadize?
---------------------------------------------
-
-So we've defined a Tree monad:
-
- type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
- let tree_unit (a: 'a) : 'a tree = Leaf a;;
- let rec tree_bind (u : 'a tree) (f : 'a -> 'b tree) : 'b tree =
- match u with
- | Leaf a -> f a
- | Node (l, r) -> Node (tree_bind l f, tree_bind r f);;
-
-What's this have to do with the `tree_monadize` functions we defined earlier?
-
- let rec tree_monadize (f : 'a -> 'b reader) (t : 'a tree) : 'b tree reader =
- match t with
- | Leaf a -> reader_bind (f a) (fun b -> reader_unit (Leaf b))
- | Node (l, r) -> reader_bind (tree_monadize f l) (fun l' ->
- reader_bind (tree_monadize f r) (fun r' ->
- reader_unit (Node (l', r'))));;
-
-... and so on for different monads?
-
-The answer is that each of those `tree_monadize` functions is adding a Tree monad *layer* to a pre-existing Reader (and so on) monad. So far, we've defined monads as single-layered things. Though in the Groenendijk, Stokhoff, and Veltmann homework, we had to figure out how to combine Reader, State, and Set monads in an ad-hoc way. In practice, one often wants to combine the abilities of several monads. Corresponding to each monad like Reader, there's a corresponding ReaderT **monad transformer**. That takes an existing monad M and adds a Reader monad layer to it. The way these are defined parallels the way the single-layer versions are defined. For example, here's the Reader monad:
-
- (* monadic operations for the Reader monad *)
-
- type 'a reader =
- env -> 'a;;
- let unit (a : 'a) : 'a reader =
- fun e -> a;;
- let bind (u: 'a reader) (f : 'a -> 'b reader) : 'b reader =
- fun e -> (fun v -> f v e) (u e);;
-
-We've just beta-expanded the familiar `f (u e) e` into `(fun v -> f v e) (u e)`, in order to factor out the parts where any Reader monad is being supplied as an argument to another function. Then if we want instead to add a Reader layer to some arbitrary other monad M, with its own M.unit and M.bind, here's how we do it:
-
- (* monadic operations for the ReaderT monadic transformer *)
-
- (* We're not giving valid OCaml code, but rather something
- * that's conceptually easier to digest.
- * How you really need to write this in OCaml is more circuitous...
- * see http://lambda.jimpryor.net/code/tree_monadize.ml for some details. *)
-
- type ('a, M) readerT =
- env -> 'a M;;
- (* this is just an 'a M reader; but don't rely on that pattern to generalize *)
-
- let unit (a : 'a) : ('a, M) readerT =
- fun e -> M.unit a;;
-
- let bind (u : ('a, M) readerT) (f : 'a -> ('b, M) readerT) : ('b, M) readerT =
- fun e -> M.bind (u e) (fun v -> f v e);;
-
-Notice the key differences: where before we just returned `a`, now we instead return `M.unit a`. Where before we just supplied value `u e` of type `'a reader` as an argument to a function, now we instead `M.bind` the `'a reader` to that function. Notice also the differences in the types.
-
-What is the relation between Reader and ReaderT? Well, suppose you started with the Identity monad:
-
- type 'a identity = 'a;;
- let unit (a : 'a) : 'a = a;;
- let bind (u : 'a) (f : 'a -> 'b) : 'b = f u;;
-
-and you used the ReaderT transformer to add a Reader monad layer to the Identity monad. What do you suppose you would get?
-
-The relations between the State monad and the StateT monadic transformer are parallel:
-
- (* monadic operations for the State monad *)
-
- type 'a state =
- store -> ('a * store);;
-
- let unit (a : 'a) : 'a state =
- fun s -> (a, s);;
-
- let bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
- fun s -> (fun (a, s') -> f a s') (u s);;
-
-We've used `(fun (a, s') -> f a s') (u s)` instead of the more familiar `let (a, s') = u s in f a s'` in order to factor out the part where a value of type `'a state` is supplied as an argument to a function. Now StateT will be:
-
- (* monadic operations for the StateT monadic transformer *)
-
- type ('a, M) stateT =
- store -> ('a * store) M;;
- (* notice this is not an 'a M state *)
-
- let unit (a : 'a) : ('a, M) stateT =
- fun s -> M.unit (a, s);;
-
- let bind (u : ('a, M) stateT) (f : 'a -> ('b, M) stateT) : ('b, M) stateT =
- fun s -> M.bind (u s) (fun (a, s') -> f a s');;
-
-Do you see the pattern? Where ordinarily we'd return an `'a` value, now we instead return an `'a M` value. Where ordinarily we'd supply a `'a state` value as an argument to a function, now we instead `M.bind` it to that function.
-
-Okay, now let's do the same thing for our Tree monad.
-
- (* monadic operations for the Tree monad *)
-
- type 'a tree =
- Leaf of 'a | Node of ('a tree) * ('a tree);;
-
- let unit (a: 'a) : 'a tree =
- Leaf a;;
-
- let rec bind (u : 'a tree) (f : 'a -> 'b tree) : 'b tree =
- match u with
- | Leaf a -> f a;;
- | Node (l, r) -> (fun l' r' -> Node (l', r')) (bind l f) (bind r f);;
-
- (* monadic operations for the TreeT monadic transformer *)
- (* NOTE THIS IS NOT YET WORKING --- STILL REFINING *)
-
- type ('a, M) treeT =
- 'a tree M;;
-
- let unit (a: 'a) : ('a, M) tree =
- M.unit (Leaf a);;
-
- let rec bind (u : ('a, M) tree) (f : 'a -> ('b, M) tree) : ('b, M) tree =
- match u with
- | Leaf a -> M.bind (f a) (fun b -> M.unit (Leaf b))
- | Node (l, r) -> M.bind (bind l f) (fun l' ->
- M.bind (bind r f) (fun r' ->
- M.unit (Node (l', r'));;
-
-Compare this definition of `bind` for the TreeT monadic transformer to our earlier definition of `tree_monadize`, specialized for the Reader monad:
-
- let rec tree_monadize (f : 'a -> 'b reader) (t : 'a tree) : 'b tree reader =
- match t with
- | Leaf a -> reader_bind (f a) (fun b -> reader_unit (Leaf b))
- | Node (l, r) -> reader_bind (tree_monadize f l) (fun l' ->
- reader_bind (tree_monadize f r) (fun r' ->
- reader_unit (Node (l', r'))));;
-
-