[lambda.git] / damn.mdwn

Expressives such as "damn" have side effects that don't affect the
at-issue value of the sentence in which they occur.  What this claim
says is unpacked at some length here: <http://tinyurl.com/cbarker/salt/interaction/salt.pdf>.

<!--
Chris also emailed me this paper, may this be publicly posted?
<http://tinyurl.com/cbarker/salt/interaction/salt.pdf>
-->


In brief, "The man read the damn book" means the same thing as "The
man read the book" as far as what must be the case in the world for
the sentence to be true.  However, the sentence with the "damn" in it
in addition conveys the claim that something about the described
situtation is not as it should be.  (The person who is committed to
that claim is whoever utters the sentence.)

So we need a way of evaluating sentences that allows "damn" to launch
a side effect without affecting the truth conditions of the sentence
in which it occurs.

Furthermore, we don't want to change the meaning of "the", "man",
"read", or "book"---those elements are completely innocent, and
shouldn't be burdened with helping compute affective content.


Some nice things: we can remove one or both of the damns, or add more,
and everything works.  As desired, the rest of the words don't need to
know anything about side effects.

Some of the complexities:

Because the compositional semantics doesn't know about words that
denote functions, "damn" contributes a trivial adjectival meaning
(here, the identity function 'id) to the composition.



What we did in Monday's seminar:

We start with a simulation of semantic composition:

        (cons (cons 'the 'man) 
                  (cons 'read
                                (cons 'the
                                          'book)))

; evaluates to ((the . man) . (read . (the . book)))

`(cons M N)` is a request to build an ordered pair out of the values M and N.
Scheme displays that pair as `(M . N)` You can't write the pair that way yourself:
if you tried to, Scheme would think you're trying to apply the function M to some arguments, which you're not, and also
Scheme would be confused by what argument the `.` is supposed to be. So, you say:
        (cons M N)
and that evaluates to an ordered pair, and Scheme displays that ordered pair as
        (M . N)
There is an underlying reason why parentheses are used both when displaying the ordered pair, and also to mean "apply this function to these arguments." However, at this point, you may well see this as a confusing overloading of parentheses to fill different syntactic roles.

Now what about the elements of our ordered pairs. Why do we say `(cons 'the 'man)`. Why are those single quotes there? Well, if you just said `(cons the man)`, Scheme would understand `the` and `man` to be variables, and it would complain that you hadn't bound these variables to any values. We don't want to build an ordered pair out of the values possessed by variables `the` and `man`. Instead, we want to just make up some dummy value THE to stand for the meaning of an object-language determiner, and some dummy value MAN to stand for the meaning of an object-language noun phrase. The notation `'the` is Scheme's way of representing a dummy, atomic value. Note there is no closing single quote, only a prefixed one. Scheme calls these dummy atomic values "symbols." That term is a bit misleading, because the symbol `'the` is not the same as the variable `the`. Neither is it the same as what's called the string `"the"`. The latter is a structured value, composed out of three character values. The symbol `'the`, on the other hand, is an atomic value. It has no parts. (The notation the programmer uses to designate this atomic value has four characters, but the value itself has no parts.) If you think this is all somewhat confusing, you're right. It gets easier with practice.

`'the` can also be written `(quote the)`. This is even more confusing, because here the `the` is not interpreted as a variable. (Try `(let* ((the 3)) (quote the))`.) If you come across this, just read `(quote the)` as a verbose (and perhaps misleading) way of writing 'the, not as the application of any function to any value.

Okay, so what we've done is just create a bunch of new atomic values `'the`, `'man`, and so on. Scheme doesn't know how to do much with these. It knows for instance that `'the` is the same value as `'the` and a different value than `'man`. But it doesn't know much more than that. That's all we need or want here.

And we built a tree out of those values, representing the tree by a nested structure of pairs of leaf-labels.

The program we submitted to Scheme:

        (cons (cons 'the 'man) 
                  (cons 'read
                                (cons 'the
                                          'book)))

evaluates to the nested structure of pairs that Scheme displays as:

        ((the . man) . (read . (the . book)))

and that we can think of as the tree:
;

             /----------------\
            /                  \
           /                    \
          /                      \
         /                        \                                  
        / \                      / \
       /   \                    /   \
      /     \                  /     \
     /       \                /       \
meaning of   meaning of   meaning of   \
  "the"        "man"       "read"      / \
                                      /   \
                                     /     \
                                    /       \
                                                                meaning of  meaning of
                                                                  "the"      "book"

Okay, let's get back to "damn."

We start by defining `damn` as a "thunk" that when applied to 0 arguments returns a trivial adjectival meaning, which we'll designate with the dummy symbol `'id`.

What's a "thunk"?

Remember, in Scheme you can have functions that take 1 value, and also functions that take 2 values, and also functions that take 0 values. The last ones are called "thunks." The thunk is not identical to the value it returns. For instance:

        (lambda () 3)

is a thunk that returns the integer 3. If we bind the variable `t` to that thunk, then `t` is a function (Scheme will call it a "procedure") not an integer. Whereas `(t)` is an integer not a function.

There's no reason yet on hand for us to make `damn` be a thunk. For present purposes, we could also just define `damn` to be the symbol `'id`. But what we're going to go on to do does require us to make `damn` be a thunk. The reason for that is to postpone the evaluation of some expressions until the continuations we want to operate on are in place.

So for uniformity we're going to make `damn` be a thunk right from the beginning.

As we said, `damn` starts as a thunk that returns a trivial adjectival meaning `'id`:

        (define damn (lambda () 'id))

Now we can say:

        (cons (cons 'the 'man) 
                  (cons 'read
                                (cons 'the
                                          (cons (damn) 
                                                'book))))

and we get back:

        ((the . man) . (read . (the . (id . book))))


Now we want to get some expressive meaning into damn. So we might try:


        (define damn (lambda () 'bad))

But then:

        (cons (cons 'the 'man) 
                  (cons 'read
                                (cons 'the
                                          (cons (damn) 
                                                'book))))

gives us:

        ((the . man) . (read . (the . (bad . book))))

Which is not quite what we're looking for. We don't want to contribute the normal adjectival meaning of "bad" to the proposition asserted. Instead we want "bad" to be contributed as a linguistic move on the side. We might try:

        (define damn (lambda () (cons 'side-effect 'bad)))

But then we'd get:


        ((the . man) . (read . (the . ((side-effect . bad) . book))))

And the context `(the . ( ... . book))` presumably doesn't know how to interact with side-effects. That's precisely the problem we're trying to solve.


A promising way to handle this is with **continuations**, which you will get much more familiar with as this seminar progresses. Don't worry about not understanding what's going on quite yet. This is just an advertisement that's supposed to provoke your imagination.

Chris and others have applied the apparatus of continuations to the analysis of expressives in the papers linked above. For a simple in-class demonstration, we tried to do this.

`(call/cc (lambda k ...))` is Scheme's way of writing: bind the continuation of this very complex expression to k and evaluate the `...`.

So now we define `damn` like this:


        (define damn (lambda () (call/cc (lambda (k) (print "bad") (k 'id)))))

Now when we do:

        (cons (cons 'the 'man) 
                  (cons 'read
                                (cons 'the
                                          (cons (damn) 
                                                'book))))

we get something like this:

        <bold>"bad"</bad> ((the . man) . (read . (the . (id . book))))

Yay! The expressive meaning has jumped out of the compositional evaluation of the main sentence, and the context `(the . (... . book))` only has to deal with the trivial adjectival meaning `'id`.

**But.** As came out in discussion, the `print` we're using here already constitutes a kind of side-effect mechanism of its own. If you say:

        (define three-thunk (lambda () (print "hi") 3))

and then ask for the evaluation of:

        (+ 2 (three-thunk))

you'll see something like:

        <bold>"hi"</bad> 5

So the demonstration we tried in class was pedagogically flawed. It didn't properly display how continuations represent a minimally effective apparatus for representing expressive content. In fact, continuations were still doing the work, but it wasn't the explicit continuations we were writing out for you. It was instead continuations implicit in the `print` operation.

So a better demonstration would do without any device like `print` that already incorporates continuations implicitly. Any continuation-manipulation should be fully explicit.








----- End forwarded message -----



#lang racket
;(define damn (lambda () 'id))
(define damn (lambda () (call/cc (lambda (k) 
                                  ; (k 'id)
                                   (print "Something's bad")
                                   (k 'id)
                                   ))))

(list (list 'the (list (damn) 'man))
      (list 'read 
            (list 'the (list (damn) 'book))))





#lang racket
(require racket/control)

(define damn0 (lambda ()
                                'id))

(define damn1 (lambda ()
                                (cons '("side effect" bad)
                                          'id)))

(define damn2 (lambda () (shift k
                                                                (cons '("side effect" bad) 
                                                                          (list (k 'id))))))

(define damn3 (lambda () (shift k
                                                                (list (k 'id)
                                                                          '("side effect" bad)))))


; Now if we use damn0, our compositional semantics will work OK but
; we don't yet have any expressive contribution:

(list "main content" 'i (list 'like (list 'the (damn0) 'boy)))
; '("main content" i (like (the id boy)))


; If we use damn1, we've added in the expressive side-effect:

(list "main content" 'i (list 'like (list 'the (damn1) 'boy)))
; '("main content" i (like (the (("side effect" bad) . id) boy)))

; However, the context (list 'the ... 'boy) is now being asked to operate
; on an element (("side effect" bad) . id), and it may complain it doesn't
; know what that is. It knows how to use 'id to get (list 'the 'id 'boy),
; and how to use 'bad to get (list 'the 'bad 'boy), but we're supposed to
; have something different here.

; To get what we want we need to use (delimited) continuations:
(reset (list "main content" 'i (list 'like (list 'the (damn2) 'boy))))
; '(("side effect" bad) ("main content" i (like (the id boy))))

; or to get the side effect at the end:

(reset (list "main content" 'i (list 'like (list 'the (damn3) 'boy))))
; '(("main content" i (like (the id boy))) ("side effect" bad))

; If you're working in the interactive interpreter, the outermost "reset" here
; is already in its default position, so it doesn't need to be explicitly
; specified:

(list "main content" 'i (list 'like (list 'the (damn2) 'boy)))
; '(("side effect" bad) ("main content" i (like (the id boy))))

; However, if you're executing this as a file, you would need to include explicit resets.



; Instead of using reset/shift you could use an element like "print" in
; building the side-effect, as we did in class. Here you wouldn't require an
; explicit continuation, but as Chris said, that's because "print" already
; represents an implicit continuation.

(define damn4 (lambda () (begin (print "bad") 'id)))
(list "main content" 'i (list 'like (list 'the (damn4) 'boy)))
; "bad"'("main content" i (like (the id boy)))
;




#lang racket

; thanks to Ken!

(let ((pragma
       ; An ordered pair whose first component is the assertion
       ; operator, a unary function, and whose second component
       ; is the meaning of "damn", a thunk.
       (call-with-current-continuation
        (lambda (k)
          (cons (lambda (prop) prop)
                (lambda () (k (cons (lambda (prop) (list 'bad prop))
                                    (lambda () 'id)))))))))
  (let ((assert (car pragma))
        (damn   (cdr pragma)))
    (assert (list 'the 'student 'read 'the (damn) 'book))))