+ System F:
+ ---------
+ types τ ::= c | 'a | τ1 -> τ2 | ∀'a. τ
+ expressions e ::= x | λx:τ. e | e1 e2 | Λ'a. e | e [τ]
+
+In the definition of the types, "`c`" is a type constant (e.g., `e` or
+`t`, or in arithmetic contexts, `N` or `Int`). "`'a`" is a type
+variable (the tick mark just indicates that the variable ranges over
+types rather than over values). "`τ1 -> τ2`" is the type of a
+function from expressions of type `τ1` to expressions of type `τ2`.
+And "`∀'a. τ`" is called a universal type, since it universally
+quantifies over the type variable `'a`. (You can expect that in
+`∀'a. τ`, the type `τ` will usually have at least one free occurrence
+of `'a` somewhere inside of it.)
+
+In the definition of the expressions, we have variables "`x`" as usual.
+Abstracts "`λx:τ. e`" are similar to abstracts in the simply-typed lambda
+calculus, except that they have their shrug variable annotated with a
+type. Applications "`e1 e2`" are just like in the simply-typed lambda calculus.
+
+In addition to variables, abstracts, and applications, we have two
+additional ways of forming expressions: "`Λ'a. e`" is called a *type
+abstraction*, and "`e [τ]`" is called a *type application*. The idea
+is that <code>Λ</code> is a capital <code>λ</code>: just
+like the lower-case <code>λ</code>, <code>Λ</code> binds
+variables in its body, except that unlike <code>λ</code>,
+<code>Λ</code> binds type variables instead of expression
+variables. So in the expression
+
+<code>Λ 'a (λ x:'a . x)</code>
+
+the <code>Λ</code> binds the type variable `'a` that occurs in
+the <code>λ</code> abstract. This expression is a polymorphic
+version of the identity function. It defines one general identity
+function that can be adapted for use with expressions of any type. In order
+to get it ready to apply to, say, a variable of type boolean, just do
+this:
+
+<code>(Λ 'a (λ x:'a . x)) [t]</code>
+
+This type application (where `t` is a type constant for Boolean truth
+values) specifies the value of the type variable α, which is
+the type of the variable bound in the λ expression. Not
+surprisingly, the type of this type application is a function from
+Booleans to Booleans:
+
+<code>((Λ 'a (λ x:'a . x)) [t]): (b -> b)</code>
+
+Likewise, if we had instantiated the type variable as an entity (base
+type `e`), the resulting identity function would have been a function
+of type `e -> e`:
+
+<code>((Λ 'a (λ x:'a . x)) [e]): (e -> e)</code>
+
+Clearly, for any choice of a type `'a`, the identity function can be
+instantiated as a function from expresions of type `'a` to expressions
+of type `'a`. In general, then, the type of the unapplied
+(polymorphic) identity function is
+
+<code>(Λ 'a (λ x:'a . x)): (∀ 'a . 'a -> 'a)</code>
+
+Pred in System F
+----------------
+
+We saw that the predecessor function couldn't be expressed in the
+simply-typed lambda calculus. It can be expressed in System F,
+however. Here is one way, coded in
+[[Benjamin Pierce's type-checker and evaluator for
+System F|http://www.cis.upenn.edu/~bcpierce/tapl/index.html]] (the
+part you want is called "fullpoly"):
+
+ N = All X . (X->X)->X->X;
+ Pair = All X . (N -> N -> X) -> X;
+ let zero = lambda X . lambda s:X->X . lambda z:X. z in
+ let snd = lambda x:N . lambda y:N . y in
+ let pair = lambda x:N . lambda y:N . lambda X . lambda z:N->N->X . z x y in
+ let suc = lambda n:N . lambda X . lambda s:X->X . lambda z:X . s (n [X] s z) in
+ let shift = lambda p:Pair . p [Pair] (lambda a:N . lambda b:N . pair (suc a) a) in
+ let pre = lambda n:N . n [Pair] shift (pair zero zero) [N] snd in
+
+ pre (suc (suc (suc zero)));
+
+We've truncated the names of "suc(c)" and "pre(d)", since those are
+reserved words in Pierce's system. Note that in this code, there is
+no typographic distinction between ordinary lambda and type-level
+lambda, though the difference is encoded in whether the variables are
+lower case (for ordinary lambda) or upper case (for type-level
+lambda).
+
+The key to the extra flexibility provided by System F is that we can
+instantiate the `pair` function to return a number, as in the
+definition of `pre`, or we can instantiate it to return an ordered
+pair, as in the definition of the `shift` function. Because we don't
+have to choose a single type for all uses of the pair-building
+function, we aren't forced into a infinite regress of types.
+
+[See Benjamin C. Pierce. 2002. *Types and Programming Languages*, MIT
+Press, pp. 350--353, for `tail` for lists in System F.]
+
+Typing ω
+--------------
+
+In fact, it is even possible to give a type for &omeage; in System F.
+
+ omega = lambda x:(All X. X->X) . x [All X . X->X] x in
+ omega;
+
+Each time the internal application is performed, the type of the head
+is chosen anew. And each time, we choose the same type as before, the
+type of a function that takes an argument of any type and returns a
+result of the same type...
+
+
+Types in OCaml
+--------------
+
+OCaml has type inference: the system can often infer what the type of
+an expression must be, based on the type of other known expressions.
+
+For instance, if we type
+
+ # let f x = x + 3;;
+
+The system replies with
+
+ val f : int -> int = <fun>
+
+Since `+` is only defined on integers, it has type
+
+ # (+);;
+ - : int -> int -> int = <fun>
+
+The parentheses are there to turn off the trick that allows the two
+arguments of `+` to surround it in infix (for linguists, SOV) argument
+order. That is,
+
+ # 3 + 4 = (+) 3 4;;
+ - : bool = true
+
+In general, tuples with one element are identical to their one
+element:
+
+ # (3) = 3;;
+ - : bool = true
+
+though OCaml, like many systems, refuses to try to prove whether two
+functional objects may be identical:
+
+ # (f) = f;;
+ Exception: Invalid_argument "equal: functional value".
+
+Oh well.
+
+[Note: There is a limited way you can compare functions, using the
+`==` operator instead of the `=` operator. Later when we discuss mutation,
+we'll discuss the difference between these two equality operations.
+Scheme has a similar pair, which they name `eq?` and `equal?`. In Python,
+these are `is` and `==` respectively. It's unfortunate that OCaml uses `==` for the opposite operation that Python and many other languages use it for. In any case, OCaml will accept `(f) == f` even though it doesn't accept
+`(f) = f`. However, don't expect it to figure out in general when two functions
+are equivalent. (That question is not Turing computable.)
+
+ # (f) == (fun x -> x + 3);;
+ - : bool = false
+
+Here OCaml says (correctly) that the two functions don't stand in the `==` relation, which basically means they're not represented in the same chunk of memory. However as the programmer can see, the functions are extensionally equivalent. The meaning of `==` is rather weird.]
+
+
+
+Booleans in OCaml, and simple pattern matching
+----------------------------------------------
+
+Where we would write `true 1 2` in our pure lambda calculus and expect
+it to evaluate to `1`, in OCaml boolean types are not functions
+(equivalently, they're functions that take zero arguments). Instead, selection is
+accomplished as follows:
+
+ # if true then 1 else 2;;
+ - : int = 1
+
+The types of the `then` clause and of the `else` clause must be the
+same.
+
+The `if` construction can be re-expressed by means of the following
+pattern-matching expression:
+
+ match <bool expression> with true -> <expression1> | false -> <expression2>
+
+That is,
+
+ # match true with true -> 1 | false -> 2;;
+ - : int = 1
+
+Compare with
+
+ # match 3 with 1 -> 1 | 2 -> 4 | 3 -> 9;;
+ - : int = 9
+
+Unit and thunks
+---------------
+
+All functions in OCaml take exactly one argument. Even this one:
+
+ # let f x y = x + y;;
+ # f 2 3;;
+ - : int = 5
+
+Here's how to tell that `f` has been curry'd:
+
+ # f 2;;
+ - : int -> int = <fun>
+
+After we've given our `f` one argument, it returns a function that is
+still waiting for another argument.
+
+There is a special type in OCaml called `unit`. There is exactly one
+object in this type, written `()`. So
+
+ # ();;
+ - : unit = ()
+
+Just as you can define functions that take constants for arguments
+
+ # let f 2 = 3;;
+ # f 2;;
+ - : int = 3;;
+
+you can also define functions that take the unit as its argument, thus
+
+ # let f () = 3;;
+ val f : unit -> int = <fun>
+
+Then the only argument you can possibly apply `f` to that is of the
+correct type is the unit:
+
+ # f ();;
+ - : int = 3
+
+Now why would that be useful?
+
+Let's have some fun: think of `rec` as our `Y` combinator. Then
+
+ # let rec f n = if (0 = n) then 1 else (n * (f (n - 1)));;
+ val f : int -> int = <fun>
+ # f 5;;
+ - : int = 120
+
+We can't define a function that is exactly analogous to our ω.
+We could try `let rec omega x = x x;;` what happens?
+
+[Note: if you want to learn more OCaml, you might come back here someday and try:
+
+ # let id x = x;;
+ val id : 'a -> 'a = <fun>
+ # let unwrap (`Wrap a) = a;;
+ val unwrap : [< `Wrap of 'a ] -> 'a = <fun>
+ # let omega ((`Wrap x) as y) = x y;;
+ val omega : [< `Wrap of [> `Wrap of 'a ] -> 'b as 'a ] -> 'b = <fun>
+ # unwrap (omega (`Wrap id)) == id;;
+ - : bool = true
+ # unwrap (omega (`Wrap omega));;
+ <Infinite loop, need to control-c to interrupt>
+
+But we won't try to explain this now.]
+
+
+Even if we can't (easily) express omega in OCaml, we can do this:
+
+ # let rec blackhole x = blackhole x;;
+
+By the way, what's the type of this function?
+
+If you then apply this `blackhole` function to an argument,
+
+ # blackhole 3;;
+
+the interpreter goes into an infinite loop, and you have to type control-c
+to break the loop.
+
+Oh, one more thing: lambda expressions look like this:
+
+ # (fun x -> x);;
+ - : 'a -> 'a = <fun>
+ # (fun x -> x) true;;
+ - : bool = true
+
+(But `(fun x -> x x)` still won't work.)
+
+You may also see this:
+
+ # (function x -> x);;
+ - : 'a -> 'a = <fun>
+
+This works the same as `fun` in simple cases like this, and slightly differently in more complex cases. If you learn more OCaml, you'll read about the difference between them.
+
+We can try our usual tricks:
+
+ # (fun x -> true) blackhole;;
+ - : bool = true
+
+OCaml declined to try to fully reduce the argument before applying the
+lambda function. Question: Why is that? Didn't we say that OCaml is a call-by-value/eager language?
+
+Remember that `blackhole` is a function too, so we can
+reverse the order of the arguments:
+
+ # blackhole (fun x -> true);;
+
+Infinite loop.
+
+Now consider the following variations in behavior:
+
+ # let test = blackhole blackhole;;
+ <Infinite loop, need to control-c to interrupt>
+
+ # let test () = blackhole blackhole;;
+ val test : unit -> 'a = <fun>
+
+ # test;;
+ - : unit -> 'a = <fun>
+
+ # test ();;
+ <Infinite loop, need to control-c to interrupt>
+
+We can use functions that take arguments of type `unit` to control
+execution. In Scheme parlance, functions on the `unit` type are called
+*thunks* (which I've always assumed was a blend of "think" and "chunk").
+
+Question: why do thunks work? We know that `blackhole ()` doesn't terminate, so why do expressions like:
+
+ let f = fun () -> blackhole ()
+ in true
+
+terminate?
+
+Bottom type, divergence
+-----------------------
+
+Expressions that don't terminate all belong to the **bottom type**. This is a subtype of every other type. That is, anything of bottom type belongs to every other type as well. More advanced type systems have more examples of subtyping: for example, they might make `int` a subtype of `real`. But the core type system of OCaml doesn't have any general subtyping relations. (Neither does System F.) Just this one: that expressions of the bottom type also belong to every other type. It's as if every type definition in OCaml, even the built in ones, had an implicit extra clause:
+
+ type 'a option = None | Some of 'a;;
+ type 'a option = None | Some of 'a | bottom;;
+
+Here are some exercises that may help better understand this. Figure out what is the type of each of the following:
+
+ fun x y -> y;;
+
+ fun x (y:int) -> y;;
+
+ fun x y : int -> y;;
+
+ let rec blackhole x = blackhole x in blackhole;;
+
+ let rec blackhole x = blackhole x in blackhole 1;;
+
+ let rec blackhole x = blackhole x in fun (y:int) -> blackhole y y y;;
+
+ let rec blackhole x = blackhole x in (blackhole 1) + 2;;
+
+ let rec blackhole x = blackhole x in (blackhole 1) || false;;
+
+ let rec blackhole x = blackhole x in 2 :: (blackhole 1);;
+
+By the way, what's the type of this:
+
+ let rec blackhole (x:'a) : 'a = blackhole x in blackhole
+
+
+Back to thunks: the reason you'd want to control evaluation with
+thunks is to manipulate when "effects" happen. In a strongly
+normalizing system, like the simply-typed lambda calculus or System F,
+there are no "effects." In Scheme and OCaml, on the other hand, we can
+write programs that have effects. One sort of effect is printing.
+Another sort of effect is mutation, which we'll be looking at soon.
+Continuations are yet another sort of effect. None of these are yet on
+the table though. The only sort of effect we've got so far is
+*divergence* or non-termination. So the only thing thunks are useful
+for yet is controlling whether an expression that would diverge if we
+tried to fully evaluate it does diverge. As we consider richer
+languages, thunks will become more useful.