As we discussed in class, there are clear patterns shared between lists and option types and trees, so perhaps you can see why people want to figure out the general structures. But it probably isn't obvious yet why it would be useful to do so. To a large extent, this will only emerge over the next few classes. But we'll begin to demonstrate the usefulness of these patterns by talking through a simple example, that uses the monadic functions of the Option/Maybe box type.
OCaml's /
operator expresses integer division, which throws away any remainder, thus:
# 11/3;;
- : int = 3
Integer division presupposes that its second argument (the divisor) is not zero, upon pain of presupposition failure. Here's what my OCaml interpreter says:
# 11/0;;
Exception: Division_by_zero.
Say we want to explicitly allow for the possibility that
division will return something other than a number.
To do that, we'll use OCaml's option
type, which works like this:
# type 'a option = None | Some of 'a;;
# None;;
- : 'a option = None
# Some 3;;
- : int option = Some 3
So if a division is normal, we return some number, but if the divisor is
zero, we return None
. As a mnemonic aid, we'll prepend a safe_
to the start of our new divide function.
let safe_div (x : int) (y : int) = match y with | 0 -> None | _ -> Some (x / y);; (* an Ocaml session could continue with OCaml's response: val safe_div : int -> int -> int option = fun # safe_div 12 2;; - : int option = Some 6 # safe_div 12 0;; - : int option = None # safe_div (safe_div 12 2) 3;; ~~~~~~~~~~~~~ Error: This expression has type int option but an expression was expected of type int *)
This starts off well: dividing 12
by 2
, no problem; dividing 12
by 0
,
just the behavior we were hoping for. But we want to be able to use
the output of the safe-division function as input for further division
operations. So we have to jack up the types of the inputs:
let safe_div2 (u : int option) (v : int option) = match u with | None -> None | Some x -> (match v with | None -> None | Some 0 -> None | Some y -> Some (x / y));; (* an Ocaml session could continue with OCaml's response: val safe_div2 : int option -> int option -> int option = # safe_div2 (Some 12) (Some 2);; - : int option = Some 6 # safe_div2 (Some 12) (Some 0);; - : int option = None # safe_div2 (safe_div2 (Some 12) (Some 0)) (Some 3);; - : int option = None *)
Calling the function now involves some extra verbosity, but it gives us what we need: now we can try to divide by anything we want, without fear that we're going to trigger system errors.
I prefer to line up the match
alternatives by using OCaml's
built-in tuple type:
let safe_div2 (u : int option) (v : int option) = match (u, v) with | (None, _) -> None | (_, None) -> None | (_, Some 0) -> None | (Some x, Some y) -> Some (x / y);;
So far so good. But what if we want to combine division with other arithmetic operations? We need to make those other operations aware of the possibility that one of their arguments has already triggered a presupposition failure:
let safe_add (u:int option) (v:int option) = match (u, v) with | (None, _) -> None | (_, None) -> None | (Some x, Some y) -> Some (x + y);; (* an Ocaml session could continue with OCaml's response: val safe_add : int option -> int option -> int option = # safe_add (Some 12) (Some 4);; - : int option = Some 16 # safe_add (safe_div (Some 12) (Some 0)) (Some 4);; - : int option = None *)
So now, wherever before our operations expected an int
, we'll instead
have them accept an int option
. A None
input signals that
something has gone wrong upstream.
This works, but is somewhat disappointing: the safe_add
operation
doesn't trigger any presupposition of its own, so it is a shame that
it needs to be adjusted because someone else might make trouble.
But we can automate the adjustment, using the monadic machinery we introduced before.
As we said, there needs to be different >>=
, map2
and so on operations for each
Monad or box type we're working with.
Haskell finesses this by "overloading" the single symbol >>=
; you can just input that
symbol and it will calculate from the context of the surrounding type constraints what
Monad you must have meant. In OCaml, the monadic operators are not pre-defined, but we will
give you a library that has definitions for all the standard Monads, as in Haskell. But you
will need to explicitly specify which Monad you mean to be deploying.
For now, though, we will define our >>=
and map2
operations by hand:
let (>>=) (u : 'a option) (j : 'a -> 'b option) : 'b option = match u with | None -> None | Some x -> j x;; let map2 (f : 'a -> 'b -> 'c) (u : 'a option) (v : 'b option) : 'c option = u >>= (fun x -> v >>= (fun y -> Some (f x y)));; let safe_add3 = map2 (+);; (* that was easy *) let safe_div3 (u: int option) (v: int option) = u >>= (fun x -> v >>= (fun y -> if 0 = y then None else Some (x / y)));;
Haskell has an even more user-friendly notation for defining safe_div3
, namely:
safe_div3 :: Maybe Int -> Maybe Int -> Maybe Int
safe_div3 u v = do {x <- u;
y <- v;
if 0 == y then Nothing else Just (x `div` y)}
You can read more about that here:
Let's see our new functions in action:
(* an Ocaml session could continue with OCaml's response: # safe_div3 (safe_div3 (Some 12) (Some 2)) (Some 3);; - : int option = Some 2 # safe_div3 (safe_div3 (Some 12) (Some 0)) (Some 3);; - : int option = None # safe_add3 (safe_div3 (Some 12) (Some 0)) (Some 3);; - : int option = None *)
Our definition for safe_add3
shows what it looks like to equip an ordinary operation to
survive in dangerous presupposition-filled world. We just need to mapN
it "into" the
Maybe monad, where N
is the function's adicity. Note that the new
definition of safe_add3
does not need to test whether its arguments are
None
values or genuine numbers---those details are hidden inside of the
bind
function.
Note also that our definition of safe_div3
recovers some of the simplicity of
the original safe_div
, without the complexity introduced by safe_div2
. We now
add exactly what extra is needed to track the no-division-by-zero presupposition. Here, too, we don't
need to keep track of what other presuppositions may have already failed
for whatever reason on our inputs.
So what the monadic machinery gives us here is a way to separate thinking
about error conditions (such as trying to divide by zero) from thinking about normal
arithmetic computations. When we're adding or multiplying, we don't have to worry about generating
any new errors, so we would rather not force these operations to explicitly
track the difference between int
s and int option
s. A linguistics analogy we'll
look at soon is that when we're giving the lexical entry for an ordinary
extensional verb, we'd rather not be forced to talk about possible worlds. In each case,
we instead just have a standard way of "lifting" (mapN
ing) the relevant notions into
the fancier type environment we ultimately want to work in.
Dividing by zero is supposed to feel like a kind of
presupposition failure. If we wanted to adapt this approach to
building a simple account of presupposition projection, we would have
to do several things. First, we would have to make use of the
polymorphism of the option
type. In the arithmetic example, we only
made use of int option
s, but when we're composing natural language
expression meanings, we'll need to use types like N option
, Det option
,
VP option
, and so on. But that works automatically, because we can use
any type for the 'a
in 'a option
. Ultimately, we'd want to have a
theory of accommodation, and a theory of the situations in which
material within the sentence can satisfy presuppositions for other
material that otherwise would trigger a presupposition violation; but,
not surprisingly, these refinements will require some more
sophisticated techniques than the super-simple Option/Maybe Monad.
To illustrate some of the polymorphism, here's how we could map1
the is_even
function:
# let is_even x = (x mod 2 = 0);;
val is_even : int -> bool = <fun>
# let map (g : 'a -> 'b) (u : 'a option) = u >>= fun x -> Some (g x);;
val map : ('a -> 'b) -> 'a option -> 'b option = <fun>
# map (is_even);;
- : int option -> bool option = <fun>
Wherever we have a well-defined monad, we can define the mapN
operations for them in terms
of their >>=
and ⇧
/mid
. The general pattern is:
mapN (g : 'a1 -> ... 'an -> 'result) (u1 : 'a1 option) ... (un : 'an option) : 'result option =
u1 >>= (fun x1 -> ... un >>= (fun xn -> ⇧(g x1 ... xn)) ...)
Our above definitions of map
and mapN
were of this form, except we just
explicitly supplied the definition of ⇧
for the Option/Maybe monad (namely, in OCamlese, the constructor Some
).
If you substitute in the definition of >>=
, you can see these are equivalent to:
map (g : 'a -> 'b) (u : 'a option) =
match u with
| None -> None
| Some x -> Some (g x)
map2 (g : 'a -> 'b -> 'c) (u : 'a option) (v : 'b option) =
match u with
| None -> None
| Some x ->
(match v with
| None -> None
| Some y -> Some (g x y));;