Application to the truth teller/liar paradoxes

Curry originally called Y the "paradoxical" combinator, and discussed it in connection with certain well-known paradoxes from the philosophy literature. The truth-teller paradox has the flavor of a recursive function without a base case:

(1) This sentence meaning is true.

If we assume that the complex demonstrative "this sentence meaning" can refer to the very meaning displayed in (1), then that meaning (1) will be true just in case the thing referred to by this sentence meaning is true. Thus, (1) will be true just in case (1) is true, and (1) is true just in case (1) is true, and so on. If (1) is true, then (1) is true; but if (1) is not true, then (1) is not true.

Without pretending to give a serious analysis of the paradox, let's assume that sentences can have for their meaning boolean values like the ones we have been working with in the Lambda Calculus. Then the sentence John is John might have as its meaning our true, namely \y n. y.

Now, the verb phrase in (1) expresses a function from whatever the referent of this sentence meaning is to a boolean. That is, \m. m true false, where the argument m is the referent of this sentence meaning. Of course, if m is a boolean, m true false <~~> m, so for our purposes, we can assume that the verb phrase of (1) denotes the identity function I.

If we use (1) in a context in which this sentence meaning refers to the meaning expressed by the very sentence in which that demonstrative occurs, then we must find a meaning m such that it is equivalent to the application of the verb phrase meaning to itself. That is, m <~~> I m. In other words, m is a fixed point for the meaning of the verb phrase.

That means that in a context in which this sentence meaning refers to the meaning expressed by the sentence in which it occurs, the sentence's meaning is a fixed point for the identity function. As we observed earlier, anything is a fixed point for the identity function. In particular, each of the boolean values true and false are fixed points for the identity function. What fixed point does Y give us?

Y I ≡
(\h. (\u. h (u u)) (\u. h (u u))) I ~~>
(\u. I (u u)) (\u. I (u u))) ~~>
(\u. (u u)) (\u. (u u))) ≡
ω ω

Well! That feels right. The meaning of This sentence meaning is true could be Ω, our prototypical infinite loop...

What about the liar?

Let's consider:

(2) This sentence meaning is false.

Used in a context in which this sentence meaning refers to the meaning expressed by the utterance of (2) in which that noun phrase occurs, (2) will denote a fixed point for \m. neg m, or \m y n. m n y, which is the C combinator. So in such a context, (2) might denote

 Y C ≡
 (\h. (\u. h (u u)) (\u. h (u u))) C ~~>
 (\u. C (u u)) (\u. C (u u))) ~~>
 C ((\u. C (u u)) (\u. C (u u))) ~~>
 C (C ((\u. C (u u)) (\u. C (u u)))) ~~>
 C (C (C ((\u. C (u u)) (\u. C (u u))))) ~~>

An infinite sequence of Cs, each one negating the remainder of the sequence. Yep, that feels like a reasonable representation of the liar paradox.

See Barwise and Etchemendy's 1987 OUP book, The Liar: an essay on truth and circularity for an approach that is similar, but expressed in terms of non-well-founded sets rather than recursive functions.


You should be cautious about feeling too comfortable with these results. Thinking again of the truth-teller paradox, yes, Ω is a fixed point for I, and perhaps it has some privileged status among all the fixed points for I, being the one delivered by Y and all (though it is not obvious why Y should have any special status, versus other fixed point combinators).

But one could observe: look, literally every formula is a fixed point for I, since

X <~~> I X

for any choice of X whatsoever.

So the Y combinator is only guaranteed to give us one fixed point out of infinitely many --- and not always the intuitively most useful one. (For instance, the squaring function \x. mul x x has 0 as a fixed point, since square 0 <~~> 0, and 1 as a fixed point, since square 1 <~~> 1, but Y (\x. mul x x) doesn't give us 0 or 1.) So with respect to the truth-teller paradox, why in the reasoning we've just gone through should we be reaching for just this fixed point at just this juncture?

One obstacle to thinking this through is the fact that a sentence normally has only two truth values. We might consider instead a noun phrase such as

(3) the entity that this noun phrase refers to

The reference of (3) depends on the reference of the embedded noun phrase this noun phrase. As with (1), it will again need to be some fixed point of I. It's easy to see that any object is a fixed point for this referential function: if this pen cap is the referent of the demonstrated noun phrase, then it is the referent of (3), and so on for any object.

Ultimately, in the context of this course, these paradoxes are more useful as a way of gaining leverage on the concepts of fixed points and recursion, rather than the other way around.

Q: How do you know that every term in the untyped lambda calculus has a fixed point?

A: That's easy: let N be an arbitrary term in the lambda calculus. If N has a fixed point, then there exists some ξ such that ξ <~~> N ξ (that's what it means to have a fixed point).

let H = \u. N (u u) in
let ξ = H H in
ξ ≡ H H ≡ (\u. N (u u)) H ~~> N (H H) ≡ N ξ

Please slow down and make sure that you understand what justified each of the equalities in the last line.

Q: How do you know that for any term N, Y N is a fixed point of N?

A: Note that in the proof given in the previous answer, we chose N and then set ξ ≡ H H ≡ (\u. N (u u)) (\u. N (u u)). If we abstract over N, we get the Y combinator, \N. (\u. N (u u)) (\u. N (u u)). No matter what argument N we feed Y, it returns some ξ that is a fixed point of N, by the reasoning in the previous answer.

Q: So if every term has a fixed point, even Y has fixed point.

A: Right:

let Y = \h. (\u. h (u u)) (\u. h (u u)) in
Y Y ≡
\h. (\u. h (u u)) (\u. h (u u)) Y ~~>
    (\u. Y (u u)) (\u. Y (u u)) ~~>
         Y ((\u. Y (u u)) (\u. Y (u u))) ~~>
         Y (     Y ((\u. Y (u u)) (\u. Y (u u)))) <~~>
         Y (     Y (     Y (...(Y (Y Y))...)))

Q: Ouch! Stop hurting my brain.

A: Is that a question?

Let's come at it from the direction of arithmetic. Recall that we claimed that even succ --- the function that added one to any number --- had a fixed point. How could there be an ξ such that ξ <~~> succ ξ? That would imply that

ξ <~~> succ ξ <~~> succ (succ ξ) <~~> succ (succ (succ ξ)) <~~> succ (...(succ ξ)...)

In other words, the fixed point of succ is a term that is its own successor. Let's just check that ξ = succ ξ:

let succ = \n s z. s (n s z) in
let ξ = (\u. succ (u u)) (\u. succ (u u)) in
succ ξ
≡   succ ((\u. succ (u u)) (\u. succ (u u))) 
~~> succ (succ ((\u. succ (u u)) (\u. succ (u u))))
≡   succ (succ ξ)

You should see the close similarity with Y Y here.

Q: So Y applied to succ returns a number that is not finite?

A: Well, if it makes sense to think of it as a number at all. It doesn't have the same structure as our encodings of finite Church numbers. But let's see if it behaves like they do:

; assume same definitions as before
succ ξ
≡    (\n s z. s (n s z)) ξ
~~>  \s z. s (ξ s z)
<~~> succ (\s z. s (ξ s z)) ; using fixed-point reasoning
≡    (\n s z. s (n s z)) (\s z. s (ξ s z))
~~>  \s z. s ((\s z. s (ξ s z)) s z)
~~>  \s z. s (s (ξ s z))

So succ ξ looks something like a Church number: it takes two arguments, s and z, and returns a sequence of nested applications of s...

You should be able to prove that add 2 (Y succ) <~~> Y succ, likewise for mul, sub, pow. What happens if we try sub (Y succ) (Y succ)? What would you expect infinity minus infinity to be? (Hint: choose your evaluation strategy so that you add two ss to the first number for every s that you add to the second number.)

This is amazing, by the way: we're proving things about a term that represents arithmetic infinity.

It's important to bear in mind the simplest, least-evaluated term we begin with is not infinitely long:

Y succ = (\h. (\u. h (u u)) (\u. h (u u))) (\n s z. s (n s z))

The way that infinity enters into the picture is that this term has no normal form: no matter how many times we perform beta reduction, there will always be an opportunity for more beta reduction. (Lather, rinse, repeat!)

Q: That reminds me, what about ?evaluation order?

A: For a recursive function that has a well-behaved base case, such as the factorial function, evaluation order is crucial. In the following computation, we will arrive at a normal form. Watch for the moment at which we have to make a choice about which beta reduction to perform next: one choice leads to a normal form, the other choice leads to endless reduction:

let prefact = \fact n. (zero? n) 1 (mul n (fact (pred n))) in
let fact = Y prefact in
fact 2
≡   [(\h. (\u. h (u u)) (\u. h (u u))) prefact] 2
~~> [(\u. prefact (u u)) (\u. prefact (u u))] 2
~~> [prefact ((\u. prefact (u u)) (\u. prefact (u u)))] 2
~~> [prefact (prefact ((\u. prefact (u u)) (\u. prefact (u u))))] 2
≡   [(\fact n. (zero? n) 1 (mul n (fact (pred n)))) (prefact ((\u. prefact (u u)) (\u. prefact (u u))))] 2
~~> [\n. (zero? n) 1 (mul n ([prefact ((\u. prefact (u u)) (\u. prefact (u u)))] (pred n)))] 2
~~> (zero? 2) 1 (mul 2 ([prefact ((\u. prefact (u u)) (\u. prefact (u u)))] (pred 2)))
~~> mul 2 ([prefact ((\u. prefact (u u)) (\u. prefact (u u)))] 1)
~~> mul 2 (mul 1 ([prefact ((\u. prefact (u u)) (\u. prefact (u u)))] 0))
≡   mul 2 (mul 1 ((zero? 0) 1 (mul 1 ([prefact ((\u. prefact (u u)) (\u. prefact (u u)))] (pred 0)))))
~~> mul 2 (mul 1 1)
~~> mul 2 1
~~> 2

The crucial step is the third from the last. We have our choice of either evaluating the test (zero? 0) 1 ..., which evaluates to 1, no matter what the ... contains; or we can evaluate the Y pump, (\u. prefact (u u)) (\u. prefact (u u)), to produce another copy of prefact. If we postpone evaluating the zero? test, we'll pump out copy after copy of prefact, and never realize that we've bottomed out in the recursion. But if we adopt a leftmost/call-by-name/normal-order evaluation strategy, we'll always start with the zero? predicate, and only produce a fresh copy of prefact if we are forced to.

Q: You claimed that the Ackermann function couldn't be implemented using our primitive recursion techniques (such as the techniques that allow us to define addition and multiplication). But you haven't shown that it is possible to define the Ackermann function using full recursion.

A: OK:

A(m,n) =
    | when m == 0 -> n + 1
    | else when n == 0 -> A(m-1, 1)
    | else -> A(m-1, A(m,n-1))

let A = Y (\A m n. (zero? m) (succ n) ((zero? n) (A (pred m) 1) (A (pred m) (A m (pred n)))))

So for instance:

A 1 2
~~> A 0 (A 1 1)
~~> A 0 (A 0 (A 1 0))
~~> A 0 (A 0 (A 0 1))
~~> A 0 (A 0 2)
~~> A 0 3
~~> 4

A 1 x is to A 0 x as addition is to the successor function; A 2 x is to A 1 x as multiplication is to addition; A 3 x is to A 2 x as exponentiation is to multiplication --- so A 4 x is to A 3 x as hyper-exponentiation is to exponentiation...

Q: What other questions should I be asking?

  • What is it about the "primed" fixed-point combinators Θ′ and Y′ that makes them compatible with a call-by-value evaluation strategy?

  • What exactly is primitive recursion?

  • How do you know that the Ackermann function can't be computed using primitive recursion techniques?

  • I hear that Y delivers the/a least fixed point. Least according to what ordering? How do you know it's least? Is leastness important?

Q: I still don't fully understand the Y combinator. Can you explain it in a different way?

Sure! Here is another way to derive Y. We'll start by choosing a specific goal, and at each decision point, we'll make a reasonable guess. The guesses will all turn out to be lucky, and we'll arrive at a fixed point combinator.

Given an arbitrary term h, we want to find a fixed point X such that:

X <~~> h X

Our strategy will be to seek an X such that X ~~> h X (this is just a guess). Because X and h X are syntactically different, the only way that X can reduce to h X is if X contains at least one redex. The simplest way to satisfy this constraint would be for the fixed point to itself be a redex (again, just a guess):

X ≡ ((\u. M) N) ~~> h X

The result of beta reduction on this redex will be M with some substitutions. We know that after these substitutions, M will have the form h X, since that is what the reduction arrow tells us. So we can refine the picture as follows:

X ≡ ((\u. h (___)) N) ~~> h X

Here, the ___ has to be something that reduces to the fixed point X. It's natural to assume that there will be at least one occurrence of u in the body of the head abstract:

X ≡ ((\u. h (__u__)) N) ~~> h X

After reduction of the redex, we're going to have

X ≡ h (__N__) ~~> h X

Apparently, __N__ will have to reduce to X. Therefore we should choose a skeleton for N that is consistent with what we have decided so far about the internal structure of X. We might like for N to syntactically match the whole of X, but this would require N to contain itself as a subpart. So we'll settle for the more modest assumption (or guess) that N matches the head of X:

X ≡ ((\u. h (__u__)) (\u. h (__u__))) ~~> h X

At this point, we've derived a skeleton for X on which it contains two so-far identical halves. We'll guess that the halves will be exactly identical. Note that at the point at which we perform the first reduction, u will get bound to N, which now corresponds to a term representing one of the halves of X. So in order to produce a full X, we simply make a second copy of u:

X ≡ ((\u. h (u u)) (\u. h (u u)))
~~>       h ((\u. h (u u)) (\u. h (u u)))
  ≡       h X


So the function \h. (\u. h (u u)) (\u. h (u u)) maps an arbitrary term h to a fixed point for h.

Q: How does this relate to the discussion in Chapter 9 of The Little Schemer?

A: Pages 160-172 of The Little Schemer introduce you to how to implement recursion in Scheme, without relying on the native capacity to do this expressed in letrec or define. The expression:

(lambda (length)
  (lambda (l)
      ((null? l) 0)
      (else (add1 (length (cdr l)))))))

that occurs starting on p. 162 and on several pages following corresponds to h in our exposition. The authors of The Little Schemer begin by applying that abstract to the argument eternity, which is a function that never returns; then they instead apply it to the argument h eternity, which is a function that works for lists of length zero, but otherwise never returns; then to the argument h (h eternity), which works for lists of length zero or one, but otherwise never returns; and so on.

They work their way towards the realization that they want an "infinite tower" of applications of h, except they don't really need an infinite tower, but rather just a finite tower whose height can't be bounded in advance. This is essentially the observation that they need a fixed point for h.

The authors attempt to self-apply h on p. 165, just as we did. As we explained in our exposition, though, that doesn't quite work.

On the top of p. 167, the authors have instead moved to our H, and attempt to self-apply that, instead. And this works.

However, on p. 168, they attempt to abstract out the part that in our H looks like (u u) and in their exposition looks like (mk-length mk-length). Doing that would work in our lambda evaluator, but you can't do it in Scheme, because Scheme has call-by-value evaluation order, which will try to fully reduce this expression before substituting it back into the term it's been abstracted out of. But it can't be fully reduced. Pages 168--170 explore this problem, and pp. 170--172 hit upon the solution of using what we called in our exposition the Y′ fixed-point combinator, rather than the Y combinator that we derived. The authors of The Little Schemer call Y′ the "applicative-order Y combinator".