--- /dev/null
+[[!toc]]
+
+
+Towards Monads: Safe division
+-----------------------------
+
+[This section used to be near the end of the lecture notes for week 6]
+
+We begin by reasoning about what should happen when someone tries to
+divide by zero. This will lead us to a general programming technique
+called a *monad*, which we'll see in many guises in the weeks to come.
+
+Integer division presupposes that its second argument
+(the divisor) is not zero, upon pain of presupposition failure.
+Here's what my OCaml interpreter says:
+
+ # 12/0;;
+ Exception: Division_by_zero.
+
+So we want to explicitly allow for the possibility that
+division will return something other than a number.
+We'll use OCaml's `option` type, which works like this:
+
+ # type 'a option = None | Some of 'a;;
+ # None;;
+ - : 'a option = None
+ # Some 3;;
+ - : int option = Some 3
+
+So if a division is normal, we return some number, but if the divisor is
+zero, we return `None`. As a mnemonic aid, we'll append a `'` to the end of our new divide function.
+
+<pre>
+let div' (x:int) (y:int) =
+ match y with
+ 0 -> None
+ | _ -> Some (x / y);;
+
+(*
+val div' : int -> int -> int option = fun
+# div' 12 2;;
+- : int option = Some 6
+# div' 12 0;;
+- : int option = None
+# div' (div' 12 2) 3;;
+Characters 4-14:
+ div' (div' 12 2) 3;;
+ ^^^^^^^^^^
+Error: This expression has type int option
+ but an expression was expected of type int
+*)
+</pre>
+
+This starts off well: dividing 12 by 2, no problem; dividing 12 by 0,
+just the behavior we were hoping for. But we want to be able to use
+the output of the safe-division function as input for further division
+operations. So we have to jack up the types of the inputs:
+
+<pre>
+let div' (u:int option) (v:int option) =
+ match u with
+ None -> None
+ | Some x -> (match v with
+ Some 0 -> None
+ | Some y -> Some (x / y));;
+
+(*
+val div' : int option -> int option -> int option = <fun>
+# div' (Some 12) (Some 2);;
+- : int option = Some 6
+# div' (Some 12) (Some 0);;
+- : int option = None
+# div' (div' (Some 12) (Some 0)) (Some 3);;
+- : int option = None
+*)
+</pre>
+
+Beautiful, just what we need: now we can try to divide by anything we
+want, without fear that we're going to trigger any system errors.
+
+I prefer to line up the `match` alternatives by using OCaml's
+built-in tuple type:
+
+<pre>
+let div' (u:int option) (v:int option) =
+ match (u, v) with
+ (None, _) -> None
+ | (_, None) -> None
+ | (_, Some 0) -> None
+ | (Some x, Some y) -> Some (x / y);;
+</pre>
+
+So far so good. But what if we want to combine division with
+other arithmetic operations? We need to make those other operations
+aware of the possibility that one of their arguments has triggered a
+presupposition failure:
+
+<pre>
+let add' (u:int option) (v:int option) =
+ match (u, v) with
+ (None, _) -> None
+ | (_, None) -> None
+ | (Some x, Some y) -> Some (x + y);;
+
+(*
+val add' : int option -> int option -> int option = <fun>
+# add' (Some 12) (Some 4);;
+- : int option = Some 16
+# add' (div' (Some 12) (Some 0)) (Some 4);;
+- : int option = None
+*)
+</pre>
+
+This works, but is somewhat disappointing: the `add'` operation
+doesn't trigger any presupposition of its own, so it is a shame that
+it needs to be adjusted because someone else might make trouble.
+
+But we can automate the adjustment. The standard way in OCaml,
+Haskell, etc., is to define a `bind` operator (the name `bind` is not
+well chosen to resonate with linguists, but what can you do). To continue our mnemonic association, we'll put a `'` after the name "bind" as well.
+
+<pre>
+let bind' (u: int option) (f: int -> (int option)) =
+ match u with
+ None -> None
+ | Some x -> f x;;
+
+let add' (u: int option) (v: int option) =
+ bind' u (fun x -> bind' v (fun y -> Some (x + y)));;
+
+let div' (u: int option) (v: int option) =
+ bind' u (fun x -> bind' v (fun y -> if (0 = y) then None else Some (x / y)));;
+
+(*
+# div' (div' (Some 12) (Some 2)) (Some 3);;
+- : int option = Some 2
+# div' (div' (Some 12) (Some 0)) (Some 3);;
+- : int option = None
+# add' (div' (Some 12) (Some 0)) (Some 3);;
+- : int option = None
+*)
+</pre>
+
+Compare the new definitions of `add'` and `div'` closely: the definition
+for `add'` shows what it looks like to equip an ordinary operation to
+survive in dangerous presupposition-filled world. Note that the new
+definition of `add'` does not need to test whether its arguments are
+None objects or real numbers---those details are hidden inside of the
+`bind'` function.
+
+The definition of `div'` shows exactly what extra needs to be said in
+order to trigger the no-division-by-zero presupposition.
+
+[Linguitics note: Dividing by zero is supposed to feel like a kind of
+presupposition failure. If we wanted to adapt this approach to
+building a simple account of presupposition projection, we would have
+to do several things. First, we would have to make use of the
+polymorphism of the `option` type. In the arithmetic example, we only
+made use of `int option`s, but when we're composing natural language
+expression meanings, we'll need to use types like `N option`, `Det option`,
+`VP option`, and so on. But that works automatically, because we can use
+any type for the `'a` in `'a option`. Ultimately, we'd want to have a
+theory of accommodation, and a theory of the situations in which
+material within the sentence can satisfy presuppositions for other
+material that otherwise would trigger a presupposition violation; but,
+not surprisingly, these refinements will require some more
+sophisticated techniques than the super-simple Option monad.]
+
+