--- /dev/null
+[[!toc]]
+
+Manipulating trees with monads
+------------------------------
+
+This topic develops an idea based on a suggestion of Ken Shan's.
+We'll build a series of functions that operate on trees, doing various
+things, including updating leaves with a Reader monad, counting nodes
+with a State monad, copying the tree with a List monad, and converting
+a tree into a list of leaves with a Continuation monad. It will turn
+out that the continuation monad can simulate the behavior of each of
+the other monads.
+
+From an engineering standpoint, we'll build a tree machine that
+deals in monads. We can modify the behavior of the system by swapping
+one monad for another. We've already seen how adding a monad can add
+a layer of funtionality without disturbing the underlying system, for
+instance, in the way that the Reader monad allowed us to add a layer
+of intensionality to an extensional grammar. But we have not yet seen
+the utility of replacing one monad with other.
+
+First, we'll be needing a lot of trees for the remainder of the
+course. Here again is a type constructor for leaf-labeled, binary trees:
+
+ type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree);;
+
+[How would you adjust the type constructor to allow for labels on the
+internal nodes?]
+
+We'll be using trees where the nodes are integers, e.g.,
+
+
+ let t1 = Node (Node (Leaf 2, Leaf 3),
+ Node (Leaf 5, Node (Leaf 7,
+ Leaf 11)))
+ .
+ ___|___
+ | |
+ . .
+ _|_ _|__
+ | | | |
+ 2 3 5 .
+ _|__
+ | |
+ 7 11
+
+Our first task will be to replace each leaf with its double:
+
+ let rec tree_map (leaf_modifier : 'a -> 'b) (t : 'a tree) : 'b tree =
+ match t with
+ | Leaf i -> Leaf (leaf_modifier i)
+ | Node (l, r) -> Node (tree_map leaf_modifier l,
+ tree_map leaf_modifier r);;
+
+`tree_map` takes a tree and a function that transforms old leaves into
+new leaves, and maps that function over all the leaves in the tree,
+leaving the structure of the tree unchanged. For instance:
+
+ let double i = i + i;;
+ tree_map double t1;;
+ - : int tree =
+ Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
+
+ .
+ ___|____
+ | |
+ . .
+ _|__ __|__
+ | | | |
+ 4 6 10 .
+ __|___
+ | |
+ 14 22
+
+We could have built the doubling operation right into the `tree_map`
+code. However, because we've made what to do to each leaf a
+parameter, we can decide to do something else to the leaves without
+needing to rewrite `tree_map`. For instance, we can easily square
+each leaf instead, by supplying the appropriate `int -> int` operation
+in place of `double`:
+
+ let square i = i * i;;
+ tree_map square t1;;
+ - : int tree =
+ Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
+
+Note that what `tree_map` does is take some unchanging contextual
+information---what to do to each leaf---and supplies that information
+to each subpart of the computation. In other words, `tree_map` has the
+behavior of a Reader monad. Let's make that explicit.
+
+In general, we're on a journey of making our `tree_map` function more and
+more flexible. So the next step---combining the tree transformer with
+a Reader monad---is to have the `tree_map` function return a (monadized)
+tree that is ready to accept any `int -> int` function and produce the
+updated tree.
+
+ fun e -> .
+ _____|____
+ | |
+ . .
+ __|___ __|___
+ | | | |
+ e 2 e 3 e 5 .
+ __|___
+ | |
+ e 7 e 11
+
+That is, we want to transform the ordinary tree `t1` (of type `int
+tree`) into a reader monadic object of type `(int -> int) -> int
+tree`: something that, when you apply it to an `int -> int` function
+`e` returns an `int tree` in which each leaf `i` has been replaced
+with `e i`.
+
+[Application note: this kind of reader object could provide a model
+for Kaplan's characters. It turns an ordinary tree into one that
+expects contextual information (here, the `e`) that can be
+used to compute the content of indexicals embedded arbitrarily deeply
+in the tree.]
+
+With our previous applications of the Reader monad, we always knew
+which kind of environment to expect: either an assignment function, as
+in the original calculator simulation; a world, as in the
+intensionality monad; an individual, as in the Jacobson-inspired link
+monad; etc. In the present case, we expect that our "environment"
+will be some function of type `int -> int`. "Looking up" some `int` in
+the environment will return us the `int` that comes out the other side
+of that function.
+
+ type 'a reader = (int -> int) -> 'a;;
+ let reader_unit (a : 'a) : 'a reader = fun _ -> a;;
+ let reader_bind (u: 'a reader) (f : 'a -> 'b reader) : 'b reader =
+ fun e -> f (u e) e;;
+
+It would be a simple matter to turn an *integer* into an `int reader`:
+
+ let asker : int -> int reader =
+ fun (a : int) ->
+ fun (modifier : int -> int) -> modifier a;;
+ asker 2 (fun i -> i + i);;
+ - : int = 4
+
+`asker a` is a monadic box that waits for an an environment (here, the argument `modifier`) and returns what that environment maps `a` to.
+
+How do we do the analagous transformation when our `int`s are scattered over the leaves of a tree? How do we turn an `int tree` into a reader?
+A tree is not the kind of thing that we can apply a
+function of type `int -> int` to.
+
+But we can do this:
+
+ let rec tree_monadize (f : 'a -> 'b reader) (t : 'a tree) : 'b tree reader =
+ match t with
+ | Leaf a -> reader_bind (f a) (fun b -> reader_unit (Leaf b))
+ | Node (l, r) -> reader_bind (tree_monadize f l) (fun l' ->
+ reader_bind (tree_monadize f r) (fun r' ->
+ reader_unit (Node (l', r'))));;
+
+This function says: give me a function `f` that knows how to turn
+something of type `'a` into an `'b reader`---this is a function of the same type that you could bind an `'a reader` to, such as `asker` or `reader_unit`---and I'll show you how to
+turn an `'a tree` into an `'b tree reader`. That is, if you show me how to do this:
+
+ ------------
+ 1 ---> | 1 |
+ ------------
+
+then I'll give you back the ability to do this:
+
+ ____________
+ . | . |
+ __|___ ---> | __|___ |
+ | | | | | |
+ 1 2 | 1 2 |
+ ------------
+
+And how will that boxed tree behave? Whatever actions you perform on it will be transmitted down to corresponding operations on its leaves. For instance, our `int reader` expects an `int -> int` environment. If supplying environment `e` to our `int reader` doubles the contained `int`:
+
+ ------------
+ 1 ---> | 1 | applied to e ~~> 2
+ ------------
+
+Then we can expect that supplying it to our `int tree reader` will double all the leaves:
+
+ ____________
+ . | . | .
+ __|___ ---> | __|___ | applied to e ~~> __|___
+ | | | | | | | |
+ 1 2 | 1 2 | 2 4
+ ------------
+
+In more fanciful terms, the `tree_monadize` function builds plumbing that connects all of the leaves of a tree into one connected monadic network; it threads the
+`'b reader` monad through the original tree's leaves.
+
+ # tree_monadize asker t1 double;;
+ - : int tree =
+ Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
+
+Here, our environment is the doubling function (`fun i -> i + i`). If
+we apply the very same `int tree reader` (namely, `tree_monadize
+asker t1`) to a different `int -> int` function---say, the
+squaring function, `fun i -> i * i`---we get an entirely different
+result:
+
+ # tree_monadize asker t1 square;;
+ - : int tree =
+ Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
+
+Now that we have a tree transformer that accepts a *reader* monad as a
+parameter, we can see what it would take to swap in a different monad.
+
+For instance, we can use a State monad to count the number of leaves in
+the tree.
+
+ type 'a state = int -> 'a * int;;
+ let state_unit a = fun s -> (a, s);;
+ let state_bind u f = fun s -> let (a, s') = u s in f a s';;
+
+Gratifyingly, we can use the `tree_monadize` function without any
+modification whatsoever, except for replacing the (parametric) type
+`'b reader` with `'b state`, and substituting in the appropriate unit and bind:
+
+ let rec tree_monadize (f : 'a -> 'b state) (t : 'a tree) : 'b tree state =
+ match t with
+ | Leaf a -> state_bind (f a) (fun b -> state_unit (Leaf b))
+ | Node (l, r) -> state_bind (tree_monadize f l) (fun l' ->
+ state_bind (tree_monadize f r) (fun r' ->
+ state_unit (Node (l', r'))));;
+
+Then we can count the number of leaves in the tree:
+
+ # let incrementer = fun a ->
+ fun s -> (a, s+1);;
+
+ # tree_monadize incrementer t1 0;;
+ - : int tree * int =
+ (Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11))), 5)
+
+ .
+ ___|___
+ | |
+ . .
+ ( _|__ _|__ , 5 )
+ | | | |
+ 2 3 5 .
+ _|__
+ | |
+ 7 11
+
+Note that the value returned is a pair consisting of a tree and an
+integer, 5, which represents the count of the leaves in the tree.
+
+Why does this work? Because the operation `incrementer`
+takes an argument `a` and wraps it in an State monadic box that
+increments the store and leaves behind a wrapped `a`. When we give that same operations to our
+`tree_monadize` function, it then wraps an `int tree` in a box, one
+that does the same store-incrementing for each of its leaves.
+
+We can use the state monad to annotate leaves with a number
+corresponding to that leave's ordinal position. When we do so, we
+reveal the order in which the monadic tree forces evaluation:
+
+ # tree_monadize (fun a -> fun s -> ((a,s+1), s+1)) t1 0;;
+ - : int tree * int =
+ (Node
+ (Node (Leaf (2, 1), Leaf (3, 2)),
+ Node
+ (Leaf (5, 3),
+ Node (Leaf (7, 4), Leaf (11, 5)))),
+ 5)
+
+The key thing to notice is that instead of just wrapping `a` in the
+monadic box, we wrap a pair of `a` and the current store.
+
+Reversing the annotation order requires reversing the order of the `state_bind`
+operations. It's not obvious that this will type correctly, so think
+it through:
+
+ let rec tree_monadize_rev (f : 'a -> 'b state) (t : 'a tree) : 'b tree state =
+ match t with
+ | Leaf a -> state_bind (f a) (fun b -> state_unit (Leaf b))
+ | Node (l, r) -> state_bind (tree_monadize f r) (fun r' -> (* R first *)
+ state_bind (tree_monadize f l) (fun l'-> (* Then L *)
+ state_unit (Node (l', r'))));;
+
+ # tree_monadize_rev (fun a -> fun s -> ((a,s+1), s+1)) t1 0;;
+ - : int tree * int =
+ (Node
+ (Node (Leaf (2, 5), Leaf (3, 4)),
+ Node
+ (Leaf (5, 3),
+ Node (Leaf (7, 2), Leaf (11, 1)))),
+ 5)
+
+Later, we will talk more about controlling the order in which nodes are visited.
+
+One more revealing example before getting down to business: replacing
+`state` everywhere in `tree_monadize` with `list` lets us do:
+
+ # let decider i = if i = 2 then [20; 21] else [i];;
+ # tree_monadize decider t1;;
+ - : int tree List_monad.m =
+ [
+ Node (Node (Leaf 20, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)));
+ Node (Node (Leaf 21, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))
+ ]
+
+
+Unlike the previous cases, instead of turning a tree into a function
+from some input to a result, this monadized tree gives us back a list of trees,
+one for each choice of `int`s for its leaves.
+
+Now for the main point. What if we wanted to convert a tree to a list
+of leaves?
+
+ type ('r,'a) continuation = ('a -> 'r) -> 'r;;
+ let continuation_unit a = fun k -> k a;;
+ let continuation_bind u f = fun k -> u (fun a -> f a k);;
+
+ let rec tree_monadize (f : 'a -> ('r,'b) continuation) (t : 'a tree) : ('r,'b tree) continuation =
+ match t with
+ | Leaf a -> continuation_bind (f a) (fun b -> continuation_unit (Leaf b))
+ | Node (l, r) -> continuation_bind (tree_monadize f l) (fun l' ->
+ continuation_bind (tree_monadize f r) (fun r' ->
+ continuation_unit (Node (l', r'))));;
+
+We use the Continuation monad described above, and insert the
+`continuation` type in the appropriate place in the `tree_monadize` code. Then if we give the `tree_monadize` function an operation that converts `int`s into `'b`-wrapping Continuation monads, it will give us back a way to turn `int tree`s into corresponding `'b tree`-wrapping Continuation monads.
+
+So for example, we compute:
+
+ # tree_monadize (fun a k -> a :: k ()) t1 (fun _ -> []);;
+ - : int list = [2; 3; 5; 7; 11]
+
+We have found a way of collapsing a tree into a list of its
+leaves. Can you trace how this is working? Think first about what the
+operation `fun a k -> a :: k a` does when you apply it to a
+plain `int`, and the continuation `fun _ -> []`. Then given what we've
+said about `tree_monadize`, what should we expect `tree_monadize (fun
+a -> fun k -> a :: k a)` to do?
+
+Soon we'll return to the same-fringe problem. Since the
+simple but inefficient way to solve it is to map each tree to a list
+of its leaves, this transformation is on the path to a more efficient
+solution. We'll just have to figure out how to postpone computing the
+tail of the list until it's needed...
+
+The Continuation monad is amazingly flexible; we can use it to
+simulate some of the computations performed above. To see how, first
+note that an interestingly uninteresting thing happens if we use
+`continuation_unit` as our first argument to `tree_monadize`, and then
+apply the result to the identity function:
+
+ # tree_monadize continuation_unit t1 (fun t -> t);;
+ - : int tree =
+ Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))
+
+That is, nothing happens. But we can begin to substitute more
+interesting functions for the first argument of `tree_monadize`:
+
+ (* Simulating the tree reader: distributing a operation over the leaves *)
+ # tree_monadize (fun a -> fun k -> k (square a)) t1 (fun t -> t);;
+ - : int tree =
+ Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
+
+ (* Counting leaves *)
+ # tree_monadize (fun a -> fun k -> 1 + k a) t1 (fun t -> 0);;
+ - : int = 5
+
+It's not immediately obvious to us how to simulate the List monadization of the tree using this technique.
+
+We could simulate the tree annotating example by setting the relevant
+type to `(store -> 'result, 'a) continuation`.
+
+Andre Filinsky has proposed that the continuation monad is
+able to simulate any other monad (Google for "mother of all monads").
+
+If you want to see how to parameterize the definition of the `tree_monadize` function, so that you don't have to keep rewriting it for each new monad, see [this code](/code/tree_monadize.ml).
+
+The idea of using continuations to characterize natural language meaning
+------------------------------------------------------------------------
+
+We might a philosopher or a linguist be interested in continuations,
+especially if efficiency of computation is usually not an issue?
+Well, the application of continuations to the same-fringe problem
+shows that continuations can manage order of evaluation in a
+well-controlled manner. In a series of papers, one of us (Barker) and
+Ken Shan have argued that a number of phenomena in natural langauge
+semantics are sensitive to the order of evaluation. We can't
+reproduce all of the intricate arguments here, but we can give a sense
+of how the analyses use continuations to achieve an analysis of
+natural language meaning.
+
+**Quantification and default quantifier scope construal**.
+
+We saw in the copy-string example ("abSd") and in the same-fringe example that
+local properties of a structure (whether a character is `'S'` or not, which
+integer occurs at some leaf position) can control global properties of
+the computation (whether the preceeding string is copied or not,
+whether the computation halts or proceeds). Local control of
+surrounding context is a reasonable description of in-situ
+quantification.
+
+ (1) John saw everyone yesterday.
+
+This sentence means (roughly)
+
+ forall x . yesterday(saw x) john
+
+That is, the quantifier *everyone* contributes a variable in the
+direct object position, and a universal quantifier that takes scope
+over the whole sentence. If we have a lexical meaning function like
+the following:
+
+ let lex (s:string) k = match s with
+ | "everyone" -> Node (Leaf "forall x", k "x")
+ | "someone" -> Node (Leaf "exists y", k "y")
+ | _ -> k s;;
+
+Then we can crudely approximate quantification as follows:
+
+ # let sentence1 = Node (Leaf "John",
+ Node (Node (Leaf "saw",
+ Leaf "everyone"),
+ Leaf "yesterday"));;
+
+ # tree_monadize lex sentence1 (fun x -> x);;
+ - : string tree =
+ Node
+ (Leaf "forall x",
+ Node (Leaf "John", Node (Node (Leaf "saw", Leaf "x"), Leaf "yesterday")))
+
+In order to see the effects of evaluation order,
+observe what happens when we combine two quantifiers in the same
+sentence:
+
+ # let sentence2 = Node (Leaf "everyone", Node (Leaf "saw", Leaf "someone"));;
+ # tree_monadize lex sentence2 (fun x -> x);;
+ - : string tree =
+ Node
+ (Leaf "forall x",
+ Node (Leaf "exists y", Node (Leaf "x", Node (Leaf "saw", Leaf "y"))))
+
+The universal takes scope over the existential. If, however, we
+replace the usual `tree_monadizer` with `tree_monadizer_rev`, we get
+inverse scope:
+
+ # tree_monadize_rev lex sentence2 (fun x -> x);;
+ - : string tree =
+ Node
+ (Leaf "exists y",
+ Node (Leaf "forall x", Node (Leaf "x", Node (Leaf "saw", Leaf "y"))))
+
+There are many crucially important details about quantification that
+are being simplified here, and the continuation treatment used here is not
+scalable for a number of reasons. Nevertheless, it will serve to give
+an idea of how continuations can provide insight into the behavior of
+quantifiers.
+
+
+The Tree monad
+==============
+
+Of course, by now you may have realized that we are working with a new
+monad, the binary, leaf-labeled Tree monad. Just as mere lists are in fact a monad,
+so are trees. Here is the type constructor, unit, and bind:
+
+ type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
+ let tree_unit (a: 'a) : 'a tree = Leaf a;;
+ let rec tree_bind (u : 'a tree) (f : 'a -> 'b tree) : 'b tree =
+ match u with
+ | Leaf a -> f a
+ | Node (l, r) -> Node (tree_bind l f, tree_bind r f);;
+
+For once, let's check the Monad laws. The left identity law is easy:
+
+ Left identity: bind (unit a) f = bind (Leaf a) f = f a
+
+To check the other two laws, we need to make the following
+observation: it is easy to prove based on `tree_bind` by a simple
+induction on the structure of the first argument that the tree
+resulting from `bind u f` is a tree with the same strucure as `u`,
+except that each leaf `a` has been replaced with the tree returned by `f a`:
+
+ . .
+ __|__ __|__
+ | | /\ |
+ a1 . f a1 .
+ _|__ __|__
+ | | | /\
+ . a5 . f a5
+ bind _|__ f = __|__
+ | | | /\
+ . a4 . f a4
+ __|__ __|___
+ | | /\ /\
+ a2 a3 f a2 f a3
+
+Given this equivalence, the right identity law
+
+ Right identity: bind u unit = u
+
+falls out once we realize that
+
+ bind (Leaf a) unit = unit a = Leaf a
+
+As for the associative law,
+
+ Associativity: bind (bind u f) g = bind u (\a. bind (f a) g)
+
+we'll give an example that will show how an inductive proof would
+proceed. Let `f a = Node (Leaf a, Leaf a)`. Then
+
+ .
+ ____|____
+ . . | |
+ bind __|__ f = __|_ = . .
+ | | | | __|__ __|__
+ a1 a2 f a1 f a2 | | | |
+ a1 a1 a1 a1
+
+Now when we bind this tree to `g`, we get
+
+ .
+ _____|______
+ | |
+ . .
+ __|__ __|__
+ | | | |
+ g a1 g a1 g a1 g a1
+
+At this point, it should be easy to convince yourself that
+using the recipe on the right hand side of the associative law will
+build the exact same final tree.
+
+So binary trees are a monad.
+
+Haskell combines this monad with the Option monad to provide a monad
+called a
+[SearchTree](http://hackage.haskell.org/packages/archive/tree-monad/0.2.1/doc/html/src/Control-Monad-SearchTree.html#SearchTree)
+that is intended to represent non-deterministic computations as a tree.
+
+
+What's this have to do with tree\_monadize?
+--------------------------------------------
+
+Our different implementations of `tree_monadize` above were different *layerings* of the Tree monad with other monads (Reader, State, List, and Continuation). We'll explore that further here: [[Monad Transformers]].
+