[[!toc]] Today we're going to encounter continuations. We're going to come at them from three different directions, and each time we're going to end up at the same place: a particular monad, which we'll call the continuation monad. Much of this discussion benefited from detailed comments and suggestions from Ken Shan. Rethinking the list monad ------------------------- To construct a monad, the key element is to settle on a type constructor, and the monad naturally follows from that. We'll remind you of some examples of how monads follow from the type constructor in a moment. This will involve some review of familair material, but it's worth doing for two reasons: it will set up a pattern for the new discussion further below, and it will tie together some previously unconnected elements of the course (more specifically, version 3 lists and monads). For instance, take the **Reader Monad**. Once we decide that the type constructor is type 'a reader = env -> 'a then the choice of unit and bind is natural: let r_unit (a : 'a) : 'a reader = fun (e : env) -> a Since the type of an `'a reader` is `env -> 'a` (by definition), the type of the `r_unit` function is `'a -> env -> 'a`, which is a specific case of the type of the *K* combinator. So it makes sense that *K* is the unit for the reader monad. Since the type of the `bind` operator is required to be r_bind : ('a reader) -> ('a -> 'b reader) -> ('b reader) We can reason our way to the correct `bind` function as follows. We start by declaring the types determined by the definition of a bind operation: let r_bind (u : 'a reader) (f : 'a -> 'b reader) : ('b reader) = ... Now we have to open up the `u` box and get out the `'a` object in order to feed it to `f`. Since `u` is a function from environments to objects of type `'a`, the way we open a box in this monad is by applying it to an environment: ... f (u e) ... This subexpression types to `'b reader`, which is good. The only problem is that we invented an environment `e` that we didn't already have , so we have to abstract over that variable to balance the books: fun e -> f (u e) ... This types to `env -> 'b reader`, but we want to end up with `env -> 'b`. Once again, the easiest way to turn a `'b reader` into a `'b` is to apply it to an environment. So we end up as follows: r_bind (u : 'a reader) (f : 'a -> 'b reader) : ('b reader) = f (u e) e And we're done. This gives us a bind function of the right type. We can then check whether, in combination with the unit function we chose, it satisfies the monad laws, and behaves in the way we intend. And it does. [The bind we cite here is a condensed version of the careful `let a = u e in ...` constructions we provided in earlier lectures. We use the condensed version here in order to emphasize similarities of structure across monads.] The **State Monad** is similar. Once we've decided to use the following type constructor: type 'a state = store -> ('a, store) Then our unit is naturally: let s_unit (a : 'a) : ('a state) = fun (s : store) -> (a, s) And we can reason our way to the bind function in a way similar to the reasoning given above. First, we need to apply `f` to the contents of the `u` box: let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state = ... f (...) ... But unlocking the `u` box is a little more complicated. As before, we need to posit a state `s` that we can apply `u` to. Once we do so, however, we won't have an `'a`, we'll have a pair whose first element is an `'a`. So we have to unpack the pair: ... let (a, s') = u s in ... (f a) ... Abstracting over the `s` and adjusting the types gives the result: let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state = fun (s : store) -> let (a, s') = u s in f a s' The **Option/Maybe Monad** doesn't follow the same pattern so closely, so we won't pause to explore it here, though conceptually its unit and bind follow just as naturally from its type constructor. Our other familiar monad is the **List Monad**, which we were told looks like this: type 'a list = ['a];; l_unit (a : 'a) = [a];; l_bind u f = List.concat (List.map f u);; Thinking through the list monad will take a little time, but doing so will provide a connection with continuations. Recall that `List.map` takes a function and a list and returns the result to applying the function to the elements of the list: List.map (fun i -> [i;i+1]) [1;2] ~~> [[1; 2]; [2; 3]] and List.concat takes a list of lists and erases the embdded list boundaries: List.concat [[1; 2]; [2; 3]] ~~> [1; 2; 2; 3] And sure enough, l_bind [1;2] (fun i -> [i, i+1]) ~~> [1; 2; 2; 3] Now, why this unit, and why this bind? Well, ideally a unit should not throw away information, so we can rule out `fun x -> []` as an ideal unit. And units should not add more information than required, so there's no obvious reason to prefer `fun x -> [x,x]`. In other words, `fun x -> [x]` is a reasonable choice for a unit. As for bind, an `'a list` monadic object contains a lot of objects of type `'a`, and we want to make some use of each of them (rather than arbitrarily throwing some of them away). The only thing we know for sure we can do with an object of type `'a` is apply the function of type `'a -> 'a list` to them. Once we've done so, we have a collection of lists, one for each of the `'a`'s. One possibility is that we could gather them all up in a list, so that `bind' [1;2] (fun i -> [i;i]) ~~> [[1;1];[2;2]]`. But that restricts the object returned by the second argument of `bind` to always be of type `'b list list`. We can elimiate that restriction by flattening the list of lists into a single list: this is just List.concat applied to the output of List.map. So there is some logic to the choice of unit and bind for the list monad. Yet we can still desire to go deeper, and see if the appropriate bind behavior emerges from the types, as it did for the previously considered monads. But we can't do that if we leave the list type as a primitive Ocaml type. However, we know several ways of implementing lists using just functions. In what follows, we're going to use type 3 lists (the right fold implementation), though it's important to wonder how things would change if we used some other strategy for implementating lists. These were the lists that made lists look like Church numerals with extra bits embdded in them: empty list: fun f z -> z list with one element: fun f z -> f 1 z list with two elements: fun f z -> f 2 (f 1 z) list with three elements: fun f z -> f 3 (f 2 (f 1 z)) and so on. To save time, we'll let the OCaml interpreter infer the principle types of these functions (rather than inferring what the types should be ourselves): # fun f z -> z;; - : 'a -> 'b -> 'b = # fun f z -> f 1 z;; - : (int -> 'a -> 'b) -> 'a -> 'b = # fun f z -> f 2 (f 1 z);; - : (int -> 'a -> 'a) -> 'a -> 'a = # fun f z -> f 3 (f 2 (f 1 z)) - : (int -> 'a -> 'a) -> 'a -> 'a = We can see what the consistent, general principle types are at the end, so we can stop. These types should remind you of the simply-typed lambda calculus types for Church numerals (`(o -> o) -> o -> o`) with one extra type thrown in, the type of the element a the head of the list (in this case, an int). So here's our type constructor for our hand-rolled lists: type 'b list' = (int -> 'b -> 'b) -> 'b -> 'b Generalizing to lists that contain any kind of element (not just ints), we have type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b So an `('a, 'b) list'` is a list containing elements of type `'a`, where `'b` is the type of some part of the plumbing. This is more general than an ordinary OCaml list, but we'll see how to map them into OCaml lists soon. We don't need to fully grasp the role of the `'b`'s in order to proceed to build a monad: l'_unit (a : 'a) : ('a, 'b) list = fun a -> fun f z -> f a z No problem. Arriving at bind is a little more complicated, but exactly the same principles apply, you just have to be careful and systematic about it. l'_bind (u : ('a,'b) list') (f : 'a -> ('c, 'd) list') : ('c, 'd) list' = ... Unpacking the types gives: l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b) (f : 'a -> ('c -> 'd -> 'd) -> 'd -> 'd) : ('c -> 'd -> 'd) -> 'd -> 'd = ... Perhaps a bit intimiating. But it's a rookie mistake to quail before complicated types. You should be no more intimiated by complex types than by a linguistic tree with deeply embedded branches: complex structure created by repeated application of simple rules. [This would be a good time to try to build your own term for the types just given. Doing so (or attempting to do so) will make the next paragraph much easier to follow.] As usual, we need to unpack the `u` box. Examine the type of `u`. This time, `u` will only deliver up its contents if we give `u` an argument that is a function expecting an `'a` and a `'b`. `u` will fold that function over its type `'a` members, and that's how we'll get the `'a`s we need. Thus: ... u (fun (a : 'a) (b : 'b) -> ... f a ... ) ... In order for `u` to have the kind of argument it needs, the `... (f a) ...` has to evaluate to a result of type `'b`. The easiest way to do this is to collapse (or "unify") the types `'b` and `'d`, with the result that `f a` will have type `('c -> 'b -> 'b) -> 'b -> 'b`. Let's postulate an argument `k` of type `('c -> 'b -> 'b)` and supply it to `(f a)`: ... u (fun (a : 'a) (b : 'b) -> ... f a k ... ) ... Now we have an argument `b` of type `'b`, so we can supply that to `(f a) k`, getting a result of type `'b`, as we need: ... u (fun (a : 'a) (b : 'b) -> f a k b) ... Now, we've used a `k` that we pulled out of nowhere, so we need to abstract over it: fun (k : 'c -> 'b -> 'b) -> u (fun (a : 'a) (b : 'b) -> f a k b) This whole expression has type `('c -> 'b -> 'b) -> 'b -> 'b`, which is exactly the type of a `('c, 'b) list'`. So we can hypothesize that we our bind is: l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b) (f : 'a -> ('c -> 'b -> 'b) -> 'b -> 'b) : ('c -> 'b -> 'b) -> 'b -> 'b = fun k -> u (fun a b -> f a k b) That is a function of the right type for our bind, but to check whether it works, we have to verify it (with the unit we chose) against the monad laws, and reason whether it will have the right behavior. Here's a way to persuade yourself that it will have the right behavior. First, it will be handy to eta-expand our `fun k -> u (fun a b -> f a k b)` to: fun k z -> u (fun a b -> f a k b) z Now let's think about what this does. It's a wrapper around `u`. In order to behave as the list which is the result of mapping `f` over each element of `u`, and then joining (`concat`ing) the results, this wrapper would have to accept arguments `k` and `z` and fold them in just the same way that the list which is the result of mapping `f` and then joining the results would fold them. Will it? Suppose we have a list' whose contents are `[1; 2; 4; 8]`---that is, our list' will be `fun f z -> f 1 (f 2 (f 4 (f 8 z)))`. We call that list' `u`. Suppose we also have a function `f` that for each `int` we give it, gives back a list of the divisors of that `int` that are greater than 1. Intuitively, then, binding `u` to `f` should give us: concat (map f u) = concat [[]; [2]; [2; 4]; [2; 4; 8]] = [2; 2; 4; 2; 4; 8] Or rather, it should give us a list' version of that, which takes a function `k` and value `z` as arguments, and returns the right fold of `k` and `z` over those elements. What does our formula fun k z -> u (fun a b -> f a k b) z do? Well, for each element `a` in `u`, it applies `f` to that `a`, getting one of the lists: [] [2] [2; 4] [2; 4; 8] (or rather, their list' versions). Then it takes the accumulated result `b` of previous steps in the fold, and it folds `k` and `b` over the list generated by `f a`. The result of doing so is passed on to the next step as the accumulated result so far. So if, for example, we let `k` be `+` and `z` be `0`, then the computation would proceed: 0 ==> right-fold + and 0 over [2; 4; 8] = 2+4+8+0 ==> right-fold + and 2+4+8+0 over [2; 4] = 2+4+2+4+8+0 ==> right-fold + and 2+4+2+4+8+0 over [2] = 2+2+4+2+4+8+0 ==> right-fold + and 2+2+4+2+4+8+0 over [] = 2+2+4+2+4+8+0 which indeed is the result of right-folding + and 0 over `[2; 2; 4; 2; 4; 8]`. If you trace through how this works, you should be able to persuade yourself that our formula: fun k z -> u (fun a b -> f a k b) z will deliver just the same folds, for arbitrary choices of `k` and `z` (with the right types), and arbitrary list's `u` and appropriately-typed `f`s, as fun k z -> List.fold_right k (concat (map f u)) z would. For future reference, we might make two eta-reductions to our formula, so that we have instead: let l'_bind = fun k -> u (fun a -> f a k);; Let's make some more tests: l_bind [1;2] (fun i -> [i, i+1]) ~~> [1; 2; 2; 3] l'_bind (fun f z -> f 1 (f 2 z)) (fun i -> fun f z -> f i (f (i+1) z)) ~~> Sigh. OCaml won't show us our own list. So we have to choose an `f` and a `z` that will turn our hand-crafted lists into standard OCaml lists, so that they will print out. # let cons h t = h :: t;; (* OCaml is stupid about :: *) # l'_bind (fun f z -> f 1 (f 2 z)) (fun i -> fun f z -> f i (f (i+1) z)) cons [];; - : int list = [1; 2; 2; 3] Ta da! Montague's PTQ treatment of DPs as generalized quantifiers ---------------------------------------------------------- We've hinted that Montague's treatment of DPs as generalized quantifiers embodies the spirit of continuations (see de Groote 2001, Barker 2002 for lengthy discussion). Let's see why. First, we'll need a type constructor. As you probably know, Montague replaced individual-denoting determiner phrases (with type `e`) with generalized quantifiers (with [extensional] type `(e -> t) -> t`. In particular, the denotation of a proper name like *John*, which might originally denote a object `j` of type `e`, came to denote a generalized quantifier `fun pred -> pred j` of type `(e -> t) -> t`. Let's write a general function that will map individuals into their corresponding generalized quantifier: gqize (a : e) = fun (p : e -> t) -> p a This function is what Partee 1987 calls LIFT, and it would be reasonable to use it here, but we will avoid that name, given that we use that word to refer to other functions. This function wraps up an individual in a box. That is to say, we are in the presence of a monad. The type constructor, the unit and the bind follow naturally. We've done this enough times that we won't belabor the construction of the bind function, the derivation is highly similar to the List monad just given: type 'a continuation = ('a -> 'b) -> 'b c_unit (a : 'a) = fun (p : 'a -> 'b) -> p a c_bind (u : ('a -> 'b) -> 'b) (f : 'a -> ('c -> 'd) -> 'd) : ('c -> 'd) -> 'd = fun (k : 'a -> 'b) -> u (fun (a : 'a) -> f a k) Note that `c_bind` is exactly the `gqize` function that Montague used to lift individuals into the continuation monad. That last bit in `c_bind` looks familiar---we just saw something like it in the List monad. How similar is it to the List monad? Let's examine the type constructor and the terms from the list monad derived above: type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b l'_unit a = fun f -> f a l'_bind u f = fun k -> u (fun a -> f a k) (We performed a sneaky but valid eta reduction in the unit term.) The unit and the bind for the Montague continuation monad and the homemade List monad are the same terms! In other words, the behavior of the List monad and the behavior of the continuations monad are parallel in a deep sense. Have we really discovered that lists are secretly continuations? Or have we merely found a way of simulating lists using list continuations? Well, strictly speaking, what we have done is shown that one particular implementation of lists---the right fold implementation---gives rise to a continuation monad fairly naturally, and that this monad can reproduce the behavior of the standard list monad. But what about other list implementations? Do they give rise to monads that can be understood in terms of continuations? Manipulating trees with monads ------------------------------ This thread develops an idea based on a detailed suggestion of Ken Shan's. We'll build a series of functions that operate on trees, doing various things, including replacing leaves, counting nodes, and converting a tree to a list of leaves. The end result will be an application for continuations. From an engineering standpoint, we'll build a tree transformer that deals in monads. We can modify the behavior of the system by swapping one monad for another. (We've already seen how adding a monad can add a layer of funtionality without disturbing the underlying system, for instance, in the way that the reader monad allowed us to add a layer of intensionality to an extensional grammar, but we have not yet seen the utility of replacing one monad with other.) First, we'll be needing a lot of trees during the remainder of the course. Here's a type constructor for binary trees: type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree) These are trees in which the internal nodes do not have labels. [How would you adjust the type constructor to allow for labels on the internal nodes?] We'll be using trees where the nodes are integers, e.g.,
let t1 = Node ((Node ((Leaf 2), (Leaf 3))),
               (Node ((Leaf 5),(Node ((Leaf 7),
                                      (Leaf 11))))))

    .
 ___|___
 |     |
 .     .
_|__  _|__
|  |  |  |
2  3  5  .
        _|__
        |  |
        7  11
Our first task will be to replace each leaf with its double:
let rec treemap (newleaf:'a -> 'b) (t:'a tree):('b tree) =
  match t with Leaf x -> Leaf (newleaf x)
             | Node (l, r) -> Node ((treemap newleaf l),
                                    (treemap newleaf r));;
`treemap` takes a function that transforms old leaves into new leaves, and maps that function over all the leaves in the tree, leaving the structure of the tree unchanged. For instance:
let double i = i + i;;
treemap double t1;;
- : int tree =
Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))

    .
 ___|____
 |      |
 .      .
_|__  __|__
|  |  |   |
4  6  10  .
        __|___
        |    |
        14   22
We could have built the doubling operation right into the `treemap` code. However, because what to do to each leaf is a parameter, we can decide to do something else to the leaves without needing to rewrite `treemap`. For instance, we can easily square each leaf instead by supplying the appropriate `int -> int` operation in place of `double`:
let square x = x * x;;
treemap square t1;;
- : int tree =ppp
Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
Note that what `treemap` does is take some global, contextual information---what to do to each leaf---and supplies that information to each subpart of the computation. In other words, `treemap` has the behavior of a reader monad. Let's make that explicit. In general, we're on a journey of making our treemap function more and more flexible. So the next step---combining the tree transducer with a reader monad---is to have the treemap function return a (monadized) tree that is ready to accept any `int->int` function and produce the updated tree. \tree (. (. (f2) (f3))(. (f5) (.(f7)(f11))))
\f    .
  ____|____
  |       |
  .       .
__|__   __|__
|   |   |   |
f2  f3  f5  .
          __|___
          |    |
          f7  f11
That is, we want to transform the ordinary tree `t1` (of type `int tree`) into a reader object of type `(int->int)-> int tree`: something that, when you apply it to an `int->int` function returns an `int tree` in which each leaf `x` has been replaced with `(f x)`. With previous readers, we always knew which kind of environment to expect: either an assignment function (the original calculator simulation), a world (the intensionality monad), an integer (the Jacobson-inspired link monad), etc. In this situation, it will be enough for now to expect that our reader will expect a function of type `int->int`.
type 'a reader = (int->int) -> 'a;;  (* mnemonic: e for environment *)
let reader_unit (x:'a): 'a reader = fun _ -> x;;
let reader_bind (u: 'a reader) (f:'a -> 'c reader):'c reader = fun e -> f (u e) e;;
It's easy to figure out how to turn an `int` into an `int reader`:
let int2int_reader (x:'a): 'b reader = fun (op:'a -> 'b) -> op x;;
int2int_reader 2 (fun i -> i + i);;
- : int = 4
But what do we do when the integers are scattered over the leaves of a tree? A binary tree is not the kind of thing that we can apply a function of type `int->int` to.
let rec treemonadizer (f:'a -> 'b reader) (t:'a tree):('b tree) reader =
  match t with Leaf x -> reader_bind (f x) (fun x' -> reader_unit (Leaf x'))
             | Node (l, r) -> reader_bind (treemonadizer f l) (fun x ->
                                reader_bind (treemonadizer f r) (fun y ->
                                  reader_unit (Node (x, y))));;
This function says: give me a function `f` that knows how to turn something of type `'a` into an `'b reader`, and I'll show you how to turn an `'a tree` into an `'a tree reader`. In more fanciful terms, the `treemonadizer` function builds plumbing that connects all of the leaves of a tree into one connected monadic network; it threads the monad through the leaves.
# treemonadizer int2int_reader t1 (fun i -> i + i);;
- : int tree =
Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
Here, our environment is the doubling function (`fun i -> i + i`). If we apply the very same `int tree reader` (namely, `treemonadizer int2int_reader t1`) to a different `int->int` function---say, the squaring function, `fun i -> i * i`---we get an entirely different result:
# treemonadizer int2int_reader t1 (fun i -> i * i);;
- : int tree =
Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
Now that we have a tree transducer that accepts a monad as a parameter, we can see what it would take to swap in a different monad. For instance, we can use a state monad to count the number of nodes in the tree.
type 'a state = int -> 'a * int;;
let state_unit x i = (x, i+.5);;
let state_bind u f i = let (a, i') = u i in f a (i'+.5);;
Gratifyingly, we can use the `treemonadizer` function without any modification whatsoever, except for replacing the (parametric) type `reader` with `state`:
let rec treemonadizer (f:'a -> 'b state) (t:'a tree):('b tree) state =
  match t with Leaf x -> state_bind (f x) (fun x' -> state_unit (Leaf x'))
             | Node (l, r) -> state_bind (treemonadizer f l) (fun x ->
                                state_bind (treemonadizer f r) (fun y ->
                                  state_unit (Node (x, y))));;
Then we can count the number of nodes in the tree:
# treemonadizer state_unit t1 0;;
- : int tree * int =
(Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11))), 13)

    .
 ___|___
 |     |
 .     .
_|__  _|__
|  |  |  |
2  3  5  .
        _|__
        |  |
        7  11
Notice that we've counted each internal node twice---it's a good exercise to adjust the code to count each node once. One more revealing example before getting down to business: replacing `state` everywhere in `treemonadizer` with `list` gives us
# treemonadizer (fun x -> [ [x; square x] ]) t1;;
- : int list tree list =
[Node
  (Node (Leaf [2; 4], Leaf [3; 9]),
   Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))]
Unlike the previous cases, instead of turning a tree into a function from some input to a result, this transformer replaces each `int` with a list of `int`'s. Now for the main point. What if we wanted to convert a tree to a list of leaves?
type ('a, 'r) continuation = ('a -> 'r) -> 'r;;
let continuation_unit x c = c x;;
let continuation_bind u f c = u (fun a -> f a c);;

let rec treemonadizer (f:'a -> ('b, 'r) continuation) (t:'a tree):(('b tree), 'r) continuation =
  match t with Leaf x -> continuation_bind (f x) (fun x' -> continuation_unit (Leaf x'))
             | Node (l, r) -> continuation_bind (treemonadizer f l) (fun x ->
                                continuation_bind (treemonadizer f r) (fun y ->
                                  continuation_unit (Node (x, y))));;
We use the continuation monad described above, and insert the `continuation` type in the appropriate place in the `treemonadizer` code. We then compute:
# treemonadizer (fun a c -> a :: (c a)) t1 (fun t -> []);;
- : int list = [2; 3; 5; 7; 11]
We have found a way of collapsing a tree into a list of its leaves. The continuation monad is amazingly flexible; we can use it to simulate some of the computations performed above. To see how, first note that an interestingly uninteresting thing happens if we use the continuation unit as our first argument to `treemonadizer`, and then apply the result to the identity function:
# treemonadizer continuation_unit t1 (fun x -> x);;
- : int tree =
Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))
That is, nothing happens. But we can begin to substitute more interesting functions for the first argument of `treemonadizer`:
(* Simulating the tree reader: distributing a operation over the leaves *)
# treemonadizer (fun a c -> c (square a)) t1 (fun x -> x);;
- : int tree =
Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))

(* Simulating the int list tree list *)
# treemonadizer (fun a c -> c [a; square a]) t1 (fun x -> x);;
- : int list tree =
Node
 (Node (Leaf [2; 4], Leaf [3; 9]),
  Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))

(* Counting leaves *)
# treemonadizer (fun a c -> 1 + c a) t1 (fun x -> 0);;
- : int = 5
We could simulate the tree state example too, but it would require generalizing the type of the continuation monad to type ('a -> 'b -> 'c) continuation = ('a -> 'b) -> 'c;; The binary tree monad --------------------- Of course, by now you may have realized that we have discovered a new monad, the binary tree monad:
type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
let tree_unit (x:'a) = Leaf x;;
let rec tree_bind (u:'a tree) (f:'a -> 'b tree):'b tree = 
  match u with Leaf x -> f x 
             | Node (l, r) -> Node ((tree_bind l f), (tree_bind r f));;
For once, let's check the Monad laws. The left identity law is easy: Left identity: bind (unit a) f = bind (Leaf a) f = fa To check the other two laws, we need to make the following observation: it is easy to prove based on `tree_bind` by a simple induction on the structure of the first argument that the tree resulting from `bind u f` is a tree with the same strucure as `u`, except that each leaf `a` has been replaced with `fa`: \tree (. (fa1) (. (. (. (fa2)(fa3)) (fa4)) (fa5)))
                .                         .       
              __|__                     __|__   
              |   |                     |   |   
              a1  .                    fa1  .   
                 _|__                     __|__ 
                 |  |                     |   | 
                 .  a5                    .  fa5
   bind         _|__       f   =        __|__   
                |  |                    |   |   
                .  a4                   .  fa4  
              __|__                   __|___   
              |   |                   |    |   
              a2  a3                 fa2  fa3         
Given this equivalence, the right identity law Right identity: bind u unit = u falls out once we realize that bind (Leaf a) unit = unit a = Leaf a As for the associative law, Associativity: bind (bind u f) g = bind u (\a. bind (fa) g) we'll give an example that will show how an inductive proof would proceed. Let `f a = Node (Leaf a, Leaf a)`. Then \tree (. (. (. (. (a1)(a2))))) \tree (. (. (. (. (a1) (a1)) (. (a1) (a1))) ))
                                           .
                                       ____|____
          .               .            |       |
bind    __|__   f  =    __|_    =      .       .
        |   |           |   |        __|__   __|__
        a1  a2         fa1 fa2       |   |   |   |
                                     a1  a1  a1  a1  
Now when we bind this tree to `g`, we get
           .
       ____|____
       |       |
       .       .
     __|__   __|__
     |   |   |   |
    ga1 ga1 ga1 ga1  
At this point, it should be easy to convince yourself that using the recipe on the right hand side of the associative law will built the exact same final tree. So binary trees are a monad. Haskell combines this monad with the Option monad to provide a monad called a [SearchTree](http://hackage.haskell.org/packages/archive/tree-monad/0.2.1/doc/html/src/Control-Monad-SearchTree.html#SearchTree) that is intended to represent non-deterministic computations as a tree. Refunctionalizing zippers: from lists to continuations ------------------------------------------------------ Let's work with lists of chars for a change. To maximize readability, we'll indulge in an abbreviatory convention that "abc" abbreviates the list `['a'; 'b'; 'c']`. Task 1: replace each occurrence of 'S' with a copy of the string up to that point. Expected behavior:
t1 "abSe" ~~> "ababe"
In linguistic terms, this is a kind of anaphora resolution, where `'S'` is functioning like an anaphoric element, and the preceding string portion is the antecedent. This deceptively simple task gives rise to some mind-bending complexity. Note that it matters which 'S' you target first (the position of the * indicates the targeted 'S'):
    t1 "aSbS" 
         *
~~> t1 "aabS" 
           *
~~> "aabaab"
versus
    t1 "aSbS"
           *
~~> t1 "aSbaSb" 
         *
~~> t1 "aabaSb"
            *
~~> "aabaaabab"
versus
    t1 "aSbS"
           *
~~> t1 "aSbaSb"
            *
~~> t1 "aSbaaSbab"
             *
~~> t1 "aSbaaaSbaabab"
              *
~~> ...
Aparently, this task, as simple as it is, is a form of computation, and the order in which the `'S'`s get evaluated can lead to divergent behavior. For now, as usual, we'll agree to always evaluate the leftmost `'S'`. This is a task well-suited to using a zipper.
type 'a list_zipper = ('a list) * ('a list);;

let rec t1 (z:char list_zipper) = 
    match z with (sofar, []) -> List.rev(sofar) (* Done! *)
               | (sofar, 'S'::rest) -> t1 ((List.append sofar sofar), rest) 
               | (sofar, fst::rest) -> t1 (fst::sofar, rest);; (* Move zipper *)

# t1 ([], ['a'; 'b'; 'S'; 'e']);;
- : char list = ['a'; 'b'; 'a'; 'b'; 'e']

# t1 ([], ['a'; 'S'; 'b'; 'S']);;
- : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
Note that this implementation enforces the evaluate-leftmost rule. Task 1 completed. One way to see exactly what is going on is to watch the zipper in action by tracing the execution of `t1`. By using the `#trace` directive in the Ocaml interpreter, the system will print out the arguments to `t1` each time it is (recurcively) called:
# #trace t1;;
t1 is now traced.
# t1 ([], ['a'; 'b'; 'S'; 'e']);;
t1 <-- ([], ['a'; 'b'; 'S'; 'e'])
t1 <-- (['a'], ['b'; 'S'; 'e'])
t1 <-- (['b'; 'a'], ['S'; 'e'])
t1 <-- (['b'; 'a'; 'b'; 'a'], ['e'])
t1 <-- (['e'; 'b'; 'a'; 'b'; 'a'], [])
t1 --> ['a'; 'b'; 'a'; 'b'; 'e']
t1 --> ['a'; 'b'; 'a'; 'b'; 'e']
t1 --> ['a'; 'b'; 'a'; 'b'; 'e']
t1 --> ['a'; 'b'; 'a'; 'b'; 'e']
t1 --> ['a'; 'b'; 'a'; 'b'; 'e']
- : char list = ['a'; 'b'; 'a'; 'b'; 'e']
The nice thing about computations involving lists is that it's so easy to visualize them as a data structure. Eventually, we want to get to a place where we can talk about more abstract computations. In order to get there, we'll first do the exact same thing we just did with concrete zipper using procedures. Think of a list as a procedural recipe: `['a'; 'b'; 'c']` means (1) start with the empty list `[]`; (2) make a new list whose first element is 'c' and whose tail is the list construted in the previous step; (3) make a new list whose first element is 'b' and whose tail is the list constructed in the previous step; and (4) make a new list whose first element is 'a' and whose tail is the list constructed in the previous step. What is the type of each of these steps? Well, it will be a function from the result of the previous step (a list) to a new list: it will be a function of type `char list -> char list`. We'll call each step a **continuation** of the recipe. So in this context, a continuation is a function of type `char list -> char list`. This means that we can now represent the sofar part of our zipper--the part we've already unzipped--as a continuation, a function describing how to finish building the list:
let rec t1c (l: char list) (c: (char list) -> (char list)) =
  match l with [] -> c []
             | 'S'::rest -> t1c rest (fun x -> c (c x))
             | a::rest -> t1c rest (fun x -> List.append (c x) [a]);;

# t1c ['a'; 'b'; 'S'] (fun x -> x);;
- : char list = ['a'; 'b'; 'a'; 'b']

# t1c ['a'; 'S'; 'b'; 'S'] (fun x -> x);;
- : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
Note that we don't need to do any reversing.