[[!toc]] Types, OCaml ------------ OCaml has type inference: the system can often infer what the type of an expression must be, based on the type of other known expressions. For instance, if we type # let f x = x + 3;; The system replies with val f : int -> int = Since `+` is only defined on integers, it has type # (+);; - : int -> int -> int = The parentheses are there to turn off the trick that allows the two arguments of `+` to surround it in infix (for linguists, SOV) argument order. That is, # 3 + 4 = (+) 3 4;; - : bool = true In general, tuples with one element are identical to their one element: # (3) = 3;; - : bool = true though OCaml, like many systems, refuses to try to prove whether two functional objects may be identical: # (f) = f;; Exception: Invalid_argument "equal: functional value". Oh well. Booleans in OCaml, and simple pattern matching ---------------------------------------------- Where we would write `true 1 2` in our pure lambda calculus and expect it to evaluate to `1`, in OCaml boolean types are not functions (equivalently, are functions that take zero arguments). Selection is accomplished as follows: # if true then 1 else 2;; - : int = 1 The types of the `then` clause and of the `else` clause must be the same. The `if` construction can be re-expressed by means of the following pattern-matching expression: match with true -> | false -> That is, # match true with true -> 1 | false -> 2;; - : int = 1 Compare with # match 3 with 1 -> 1 | 2 -> 4 | 3 -> 9;; - : int = 9 Unit and thunks --------------- All functions in OCaml take exactly one argument. Even this one: # let f x y = x + y;; # f 2 3;; - : int = 5 Here's how to tell that `f` has been curry'd: # f 2;; - : int -> int = After we've given our `f` one argument, it returns a function that is still waiting for another argument. There is a special type in OCaml called `unit`. There is exactly one object in this type, written `()`. So # ();; - : unit = () Just as you can define functions that take constants for arguments # let f 2 = 3;; # f 2;; - : int = 3;; you can also define functions that take the unit as its argument, thus # let f () = 3;; val f : unit -> int = Then the only argument you can possibly apply `f` to that is of the correct type is the unit: # f ();; - : int = 3 Let's have some fn: think of `rec` as our `Y` combinator. Then # let rec f n = if (0 = n) then 1 else (n * (f (n - 1)));; val f : int -> int = # f 5;; - : int = 120 We can't define a function that is exactly analogous to our ω. We could try `let rec omega x = x x;;` what happens? However, we can do this: # let rec omega x = omega x;; By the way, what's the type of this function? If you then apply this omega to an argument, # omega 3;; the interpreter goes into an infinite loop, and you have to control-C to break the loop. Oh, one more thing: lambda expressions look like this: # (fun x -> x);; - : 'a -> 'a = # (fun x -> x) true;; - : bool = true (But `(fun x -> x x)` still won't work.) So we can try our usual tricks: # (fun x -> true) omega;; - : bool = true OCaml declined to try to evaluate the argument before applying the functor. But remember that `omega` is a function too, so we can reverse the order of the arguments: # omega (fun x -> true);; Infinite loop. Now consider the following variations in behavior: # let test = omega omega;; [Infinite loop, need to control c out] # let test () = omega omega;; val test : unit -> 'a = # test;; - : unit -> 'a = # test ();; [Infinite loop, need to control c out] We can use functions that take arguments of type unit to control execution. In Scheme parlance, functions on the unit type are called *thunks* (which I've always assumed was a blend of "think" and "chunk"). Towards Monads -------------- So the integer division operation presupposes that its second argument (the divisor) is not zero, upon pain of presupposition failure. Here's what my OCaml interpreter says: # 12/0;; Exception: Division_by_zero. So we want to explicitly allow for the possibility that division will return something other than a number. We'll use OCaml's option type, which works like this: # type 'a option = None | Some of 'a;; # None;; - : 'a option = None # Some 3;; - : int option = Some 3 So if a division is normal, we return some number, but if the divisor is zero, we return None. As a mnemonic aid, we'll append a `'` to the end of our new divide function. 
let div' (x:int) (y:int) =
  match y with 0 -> None |
               _ -> Some (x / y);;

(*
val div' : int -> int -> int option = fun
# div' 12 3;;
- : int option = Some 4
# div' 12 0;;
- : int option = None
# div' (div' 12 3) 2;;
Characters 4-14:
  div' (div' 12 3) 2;;
      ^^^^^^^^^^
Error: This expression has type int option
       but an expression was expected of type int
*)
This starts off well: dividing 12 by 3, no problem; dividing 12 by 0, just the behavior we were hoping for. But we want to be able to use the output of the safe-division function as input for further division operations. So we have to jack up the types of the inputs: 
let div' (x:int option) (y:int option) =
  match y with None -> None |
               Some 0 -> None |
               Some n -> (match x with None -> None |
                                       Some m -> Some (m / n));;

(*
val div' : int option -> int option -> int option = 
# div' (Some 12) (Some 4);;
- : int option = Some 3
# div' (Some 12) (Some 0);;
- : int option = None
# div' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
*)
Beautiful, just what we need: now we can try to divide by anything we want, without fear that we're going to trigger any system errors. I prefer to line up the `match` alternatives by using OCaml's built-in tuple type: 
let div' (x:int option) (y:int option) =
  match (x, y) with (None, _) -> None |
                    (_, None) -> None |
                    (_, Some 0) -> None |
                    (Some m, Some n) -> Some (m / n);;
So far so good. But what if we want to combine division with other arithmetic operations? We need to make those other operations aware of the possibility that one of their arguments will trigger a presupposition failure: 
let add' (x:int option) (y:int option) =
  match (x, y) with (None, _) -> None |
                    (_, None) -> None |
                    (Some m, Some n) -> Some (m + n);;

(*
val add' : int option -> int option -> int option = 
# add' (Some 12) (Some 4);;
- : int option = Some 16
# add' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
*)
This works, but is somewhat disappointing: the `add'` operation doesn't trigger any presupposition of its own, so it is a shame that it needs to be adjusted because someone else might make trouble. But we can automate the adjustment. The standard way in OCaml, Haskell, etc., is to define a `bind` operator (the name `bind` is not well chosen to resonate with linguists, but what can you do). To continue our mnemonic association, we'll put a `'` after the name "bind" as well. 
let bind' (x: int option) (f: int -> (int option)) =
  match x with None -> None |
               Some n -> f n;;

let add' (x: int option) (y: int option)  =
  bind' x (fun x -> bind' y (fun y -> Some (x + y)));;

let div' (x: int option) (y: int option) =
  bind' x (fun x -> bind' y (fun y -> if (0 = y) then None else Some (x / y)));;

(*
#  div' (div' (Some 12) (Some 2)) (Some 4);;
- : int option = Some 1
#  div' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
# add' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
*)
Compare the new definitions of `add'` and `div'` closely: the definition for `add'` shows what it looks like to equip an ordinary operation to survive in dangerous presupposition-filled world. Note that the new definition of `add'` does not need to test whether its arguments are None objects or real numbers---those details are hidden inside of the `bind'` function. The definition of `div'` shows exactly what extra needs to be said in order to trigger the no-division-by-zero presupposition. For linguists: this is a complete theory of a particularly simply form of presupposition projection (every predicate is a hole).