Dividing by zero ---------------- Integer division presupposes that its second argument (the divisor) is not zero, upon pain of presupposition failure. Here's what my OCaml interpreter says: # 12/0;; Exception: Division_by_zero. So we want to explicitly allow for the possibility that division will return something other than a number. We'll use OCaml's `option` type, which works like this: # type 'a option = None | Some of 'a;; # None;; - : 'a option = None # Some 3;; - : int option = Some 3 So if a division is normal, we return some number, but if the divisor is zero, we return `None`. As a mnemonic aid, we'll append a `'` to the end of our new divide function.
```let div' (x:int) (y:int) =
match y with
0 -> None
| _ -> Some (x / y);;

(*
val div' : int -> int -> int option = fun
# div' 12 3;;
- : int option = Some 4
# div' 12 0;;
- : int option = None
# div' (div' 12 3) 2;;
Characters 4-14:
div' (div' 12 3) 2;;
^^^^^^^^^^
Error: This expression has type int option
but an expression was expected of type int
*)
```
This starts off well: dividing 12 by 3, no problem; dividing 12 by 0, just the behavior we were hoping for. But we want to be able to use the output of the safe-division function as input for further division operations. So we have to jack up the types of the inputs:
```let div' (u:int option) (v:int option) =
match v with
None -> None
| Some 0 -> None
| Some y -> (match u with
None -> None
| Some x -> Some (x / y));;

(*
val div' : int option -> int option -> int option =
# div' (Some 12) (Some 4);;
- : int option = Some 3
# div' (Some 12) (Some 0);;
- : int option = None
# div' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
*)
```
Beautiful, just what we need: now we can try to divide by anything we want, without fear that we're going to trigger any system errors. I prefer to line up the `match` alternatives by using OCaml's built-in tuple type:
```let div' (u:int option) (v:int option) =
match (u, v) with
(None, _) -> None
| (_, None) -> None
| (_, Some 0) -> None
| (Some x, Some y) -> Some (x / y);;
```
So far so good. But what if we want to combine division with other arithmetic operations? We need to make those other operations aware of the possibility that one of their arguments has triggered a presupposition failure:
```let add' (u:int option) (v:int option) =
match (u, v) with
(None, _) -> None
| (_, None) -> None
| (Some x, Some y) -> Some (x + y);;

(*
val add' : int option -> int option -> int option =
# add' (Some 12) (Some 4);;
- : int option = Some 16
# add' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
*)
```
This works, but is somewhat disappointing: the `add'` operation doesn't trigger any presupposition of its own, so it is a shame that it needs to be adjusted because someone else might make trouble. But we can automate the adjustment. The standard way in OCaml, Haskell, etc., is to define a `bind` operator (the name `bind` is not well chosen to resonate with linguists, but what can you do). To continue our mnemonic association, we'll put a `'` after the name "bind" as well.
```let bind' (u: int option) (f: int -> (int option)) =
match u with
None -> None
| Some x -> f x;;

let add' (u: int option) (v: int option)  =
bind' u (fun x -> bind' v (fun y -> Some (x + y)));;

let div' (u: int option) (v: int option) =
bind' u (fun x -> bind' v (fun y -> if (0 = y) then None else Some (x / y)));;

(*
#  div' (div' (Some 12) (Some 2)) (Some 4);;
- : int option = Some 1
#  div' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
# add' (div' (Some 12) (Some 0)) (Some 4);;
- : int option = None
*)
```
Compare the new definitions of `add'` and `div'` closely: the definition for `add'` shows what it looks like to equip an ordinary operation to survive in dangerous presupposition-filled world. Note that the new definition of `add'` does not need to test whether its arguments are None objects or real numbers---those details are hidden inside of the `bind'` function. The definition of `div'` shows exactly what extra needs to be said in order to trigger the no-division-by-zero presupposition. For linguists: this is a complete theory of a particularly simply form of presupposition projection (every predicate is a hole).