f1f5b42a7c12a0881aa9d457090b18ba4d396f02
1 [[!toc]]
3 Polymorphic Types and System F
4 ------------------------------
6 [Notes still to be added. Hope you paid attention during seminar.]
9 Types in OCaml
10 --------------
12 OCaml has type inference: the system can often infer what the type of
13 an expression must be, based on the type of other known expressions.
15 For instance, if we type
17     # let f x = x + 3;;
19 The system replies with
21     val f : int -> int = <fun>
23 Since `+` is only defined on integers, it has type
25      # (+);;
26      - : int -> int -> int = <fun>
28 The parentheses are there to turn off the trick that allows the two
29 arguments of `+` to surround it in infix (for linguists, SOV) argument
30 order. That is,
32     # 3 + 4 = (+) 3 4;;
33     - : bool = true
35 In general, tuples with one element are identical to their one
36 element:
38     # (3) = 3;;
39     - : bool = true
41 though OCaml, like many systems, refuses to try to prove whether two
42 functional objects may be identical:
44     # (f) = f;;
45     Exception: Invalid_argument "equal: functional value".
47 Oh well.
49 [Note: There is a limited way you can compare functions, using the
50 `==` operator instead of the `=` operator. Later when we discuss mutation,
51 we'll discuss the difference between these two equality operations.
52 Scheme has a similar pair, which they name `eq?` and `equal?`. In Python,
53 these are `is` and `==` respectively. It's unfortunate that OCaml uses `==` for the opposite operation that Python and many other languages use it for. In any case, OCaml will accept `(f) == f` even though it doesn't accept
54 `(f) = f`. However, don't expect it to figure out in general when two functions
55 are equivalent. (That question is not Turing computable.)
57         # (f) == (fun x -> x + 3);;
58         - : bool = false
60 Here OCaml says (correctly) that the two functions don't stand in the `==` relation, which basically means they're not represented in the same chunk of memory. However as the programmer can see, the functions are extensionally equivalent. The meaning of `==` is rather weird.]
64 Booleans in OCaml, and simple pattern matching
65 ----------------------------------------------
67 Where we would write `true 1 2` in our pure lambda calculus and expect
68 it to evaluate to `1`, in OCaml boolean types are not functions
69 (equivalently, they're functions that take zero arguments). Instead, selection is
70 accomplished as follows:
72     # if true then 1 else 2;;
73     - : int = 1
75 The types of the `then` clause and of the `else` clause must be the
76 same.
78 The `if` construction can be re-expressed by means of the following
79 pattern-matching expression:
81     match <bool expression> with true -> <expression1> | false -> <expression2>
83 That is,
85     # match true with true -> 1 | false -> 2;;
86     - : int = 1
88 Compare with
90     # match 3 with 1 -> 1 | 2 -> 4 | 3 -> 9;;
91     - : int = 9
93 Unit and thunks
94 ---------------
96 All functions in OCaml take exactly one argument.  Even this one:
98     # let f x y = x + y;;
99     # f 2 3;;
100     - : int = 5
102 Here's how to tell that `f` has been curry'd:
104     # f 2;;
105     - : int -> int = <fun>
107 After we've given our `f` one argument, it returns a function that is
108 still waiting for another argument.
110 There is a special type in OCaml called `unit`.  There is exactly one
111 object in this type, written `()`.  So
113     # ();;
114     - : unit = ()
116 Just as you can define functions that take constants for arguments
118     # let f 2 = 3;;
119     # f 2;;
120     - : int = 3;;
122 you can also define functions that take the unit as its argument, thus
124     # let f () = 3;;
125     val f : unit -> int = <fun>
127 Then the only argument you can possibly apply `f` to that is of the
128 correct type is the unit:
130     # f ();;
131     - : int = 3
133 Now why would that be useful?
135 Let's have some fun: think of `rec` as our `Y` combinator.  Then
137     # let rec f n = if (0 = n) then 1 else (n * (f (n - 1)));;
138     val f : int -> int = <fun>
139     # f 5;;
140     - : int = 120
142 We can't define a function that is exactly analogous to our &omega;.
143 We could try `let rec omega x = x x;;` what happens?
145 [Note: if you want to learn more OCaml, you might come back here someday and try:
147         # let id x = x;;
148         val id : 'a -> 'a = <fun>
149         # let unwrap (`Wrap a) = a;;
150         val unwrap : [< `Wrap of 'a ] -> 'a = <fun>
151         # let omega ((`Wrap x) as y) = x y;;
152         val omega : [< `Wrap of [> `Wrap of 'a ] -> 'b as 'a ] -> 'b = <fun>
153         # unwrap (omega (`Wrap id)) == id;;
154         - : bool = true
155         # unwrap (omega (`Wrap omega));;
156     <Infinite loop, need to control-c to interrupt>
158 But we won't try to explain this now.]
161 Even if we can't (easily) express omega in OCaml, we can do this:
163     # let rec blackhole x = blackhole x;;
165 By the way, what's the type of this function?
167 If you then apply this `blackhole` function to an argument,
169     # blackhole 3;;
171 the interpreter goes into an infinite loop, and you have to type control-c
172 to break the loop.
174 Oh, one more thing: lambda expressions look like this:
176     # (fun x -> x);;
177     - : 'a -> 'a = <fun>
178     # (fun x -> x) true;;
179     - : bool = true
181 (But `(fun x -> x x)` still won't work.)
183 You may also see this:
185         # (function x -> x);;
186         - : 'a -> 'a = <fun>
188 This works the same as `fun` in simple cases like this, and slightly differently in more complex cases. If you learn more OCaml, you'll read about the difference between them.
190 We can try our usual tricks:
192     # (fun x -> true) blackhole;;
193     - : bool = true
195 OCaml declined to try to fully reduce the argument before applying the
196 lambda function. Question: Why is that? Didn't we say that OCaml is a call-by-value/eager language?
198 Remember that `blackhole` is a function too, so we can
199 reverse the order of the arguments:
201     # blackhole (fun x -> true);;
203 Infinite loop.
205 Now consider the following variations in behavior:
207     # let test = blackhole blackhole;;
208     <Infinite loop, need to control-c to interrupt>
210     # let test () = blackhole blackhole;;
211     val test : unit -> 'a = <fun>
213     # test;;
214     - : unit -> 'a = <fun>
216     # test ();;
217     <Infinite loop, need to control-c to interrupt>
219 We can use functions that take arguments of type `unit` to control
220 execution.  In Scheme parlance, functions on the `unit` type are called
221 *thunks* (which I've always assumed was a blend of "think" and "chunk").
223 Question: why do thunks work? We know that `blackhole ()` doesn't terminate, so why do expressions like:
225         let f = fun () -> blackhole ()
226         in true
228 terminate?
230 Bottom type, divergence
231 -----------------------
233 Expressions that don't terminate all belong to the **bottom type**. This is a subtype of every other type. That is, anything of bottom type belongs to every other type as well. More advanced type systems have more examples of subtyping: for example, they might make `int` a subtype of `real`. But the core type system of OCaml doesn't have any general subtyping relations. (Neither does System F.) Just this one: that expressions of the bottom type also belong to every other type. It's as if every type definition in OCaml, even the built in ones, had an implicit extra clause:
235         type 'a option = None | Some of 'a;;
236         type 'a option = None | Some of 'a | bottom;;
238 Here are some exercises that may help better understand this. Figure out what is the type of each of the following:
240         fun x y -> y;;
242         fun x (y:int) -> y;;
244         fun x y : int -> y;;
246         let rec blackhole x = blackhole x in blackhole;;
248         let rec blackhole x = blackhole x in blackhole 1;;
250         let rec blackhole x = blackhole x in fun (y:int) -> blackhole y y y;;
252         let rec blackhole x = blackhole x in (blackhole 1) + 2;;
254         let rec blackhole x = blackhole x in (blackhole 1) || false;;
256         let rec blackhole x = blackhole x in 2 :: (blackhole 1);;
258 By the way, what's the type of this:
260         let rec blackhole (x:'a) : 'a = blackhole x in blackhole
263 Back to thunks: the reason you'd want to control evaluation with thunks is to
264 manipulate when "effects" happen. In a strongly normalizing system, like the
265 simply-typed lambda calculus or System F, there are no "effects." In Scheme and
266 OCaml, on the other hand, we can write programs that have effects. One sort of
267 effect is printing (think of the [[damn]] example at the start of term).
268 Another sort of effect is mutation, which we'll be looking at soon.
269 Continuations are yet another sort of effect. None of these are yet on the
270 table though. The only sort of effect we've got so far is *divergence* or
271 non-termination. So the only thing thunks are useful for yet is controlling
272 whether an expression that would diverge if we tried to fully evaluate it does
273 diverge. As we consider richer languages, thunks will become more useful.