tweak advanced

[lambda.git] / week4.mdwn

[[!toc]]

#Q: How do you know that every term in the untyped lambda calculus has a fixed point?#

A: That's easy: let `T` be an arbitrary term in the lambda calculus.  If
`T` has a fixed point, then there exists some `X` such that `X <~~>
TX` (that's what it means to *have* a fixed point).

<pre>
let W = \x.T(xx) in
let X = WW in
X = WW = (\x.T(xx))W = T(WW) = TX
</pre>

Please slow down and make sure that you understand what justified each
of the equalities in the last line.

#Q: How do you know that for any term `T`, `YT` is a fixed point of `T`?#

A: Note that in the proof given in the previous answer, we chose `T`
and then set `X = WW = (\x.T(xx))(\x.T(xx))`.  If we abstract over
`T`, we get the Y combinator, `\T.(\x.T(xx))(\x.T(xx))`.  No matter
what argument `T` we feed Y, it returns some `X` that is a fixed point
of `T`, by the reasoning in the previous answer.

#Q: So if every term has a fixed point, even `Y` has fixed point.#

A: Right:

    let Y = \T.(\x.T(xx))(\x.T(xx)) in
    Y Y = \T.(\x.T(xx))(\x.T(xx)) Y
        = (\x.Y(xx))(\x.Y(xx))
        = Y((\x.Y(xx))(\x.Y(xx)))
        = Y(Y((\x.Y(xx))(\x.Y(xx))))
        = Y(Y(Y(...(Y(YY))...)))

#Q: Ouch!  Stop hurting my brain.#

A: Let's come at it from the direction of arithmetic.  Recall that we
claimed that even `succ`---the function that added one to any
number---had a fixed point.  How could there be an X such that X = X+1?
That would imply that

    X = succ X = succ (succ X) = succ (succ (succ (X))) = succ (... (succ X)...)

In other words, the fixed point of `succ` is a term that is its own
successor.  Let's just check that `X = succ X`:

    let succ = \n s z. s (n s z) in
    let X = (\x.succ(xx))(\x.succ(xx)) in
    succ X 
      = succ ((\x.succ(xx))(\x.succ(xx))) 
      = succ (succ ((\x.succ(xx))(\x.succ(xx))))
      = succ (succ X)

You should see the close similarity with YY here.

#Q. So `Y` applied to `succ` returns a number that is not finite!#

A. Yes!  Let's see why it makes sense to think of `Y succ` as a Church
numeral:

      [same definitions]
      succ X
      = (\n s z. s (n s z)) X 
      = \s z. s (X s z)
      = succ (\s z. s (X s z)) ; using fixed-point reasoning
      = \s z. s ([succ (\s z. s (X s z))] s z)
      = \s z. s ([\s z. s ([succ (\s z. s (X s z))] s z)] s z)
      = \s z. s (s (succ (\s z. s (X s z))))

So `succ X` looks like a numeral: it takes two arguments, `s` and `z`,
and returns a sequence of nested applications of `s`...

You should be able to prove that `add 2 (Y succ) <~~> Y succ`,
likewise for `mult`, `minus`, `pow`.  What happens if we try `minus (Y
succ)(Y succ)`?  What would you expect infinity minus infinity to be?
(Hint: choose your evaluation strategy so that you add two `s`s to the
first number for every `s` that you add to the second number.)

This is amazing, by the way: we're proving things about a term that
represents arithmetic infinity.  

It's important to bear in mind the simplest term in question is not
infinite:

     Y succ = (\f.(\x.f(xx))(\x.f(xx)))(\n s z. s (n s z))

The way that infinity enters into the picture is that this term has
no normal form: no matter how many times we perform beta reduction,
there will always be an opportunity for more beta reduction.  (Lather,
rinse, repeat!)

#Q. That reminds me, what about [[evaluation order]]?#

A. For a recursive function that has a well-behaved base case, such as
the factorial function, evaluation order is crucial.  In the following
computation, we will arrive at a normal form.  Watch for the moment at
which we have to make a choice about which beta reduction to perform
next: one choice leads to a normal form, the other choice leads to
endless reduction:

    let prefac = \f n. isZero n 1 (mult n (f (pred n))) in
    let fac = Y prefac in
    fac 2
       = [(\f.(\x.f(xx))(\x.f(xx))) prefac] 2
       = [(\x.prefac(xx))(\x.prefac(xx))] 2
       = [prefac((\x.prefac(xx))(\x.prefac(xx)))] 2
       = [prefac(prefac((\x.prefac(xx))(\x.prefac(xx))))] 2
       = [(\f n. isZero n 1 (mult n (f (pred n))))
          (prefac((\x.prefac(xx))(\x.prefac(xx))))] 2
       = [\n. isZero n 1 (mult n ([prefac((\x.prefac(xx))(\x.prefac(xx)))] (pred n)))] 2
       = isZero 2 1 (mult 2 ([prefac((\x.prefac(xx))(\x.prefac(xx)))] (pred 2)))
       = mult 2 ([prefac((\x.prefac(xx))(\x.prefac(xx)))] 1)
       ...
       = mult 2 (mult 1 ([prefac((\x.prefac(xx))(\x.prefac(xx)))] 0))
       = mult 2 (mult 1 (isZero 0 1 ([prefac((\x.prefac(xx))(\x.prefac(xx)))] (pred 0))))
       = mult 2 (mult 1 1)
       = mult 2 1
       = 2

The crucial step is the third from the last.  We have our choice of
either evaluating the test `isZero 0 1 ...`, which evaluates to `1`,
no matter what the ... contains;
or we can evaluate the `Y` pump, `(\x.prefac(xx))(\x.prefac(xx))`, to
produce another copy of `prefac`.  If we postpone evaluting the
`isZero` test, we'll pump out copy after copy of `prefac`, and never
realize that we've bottomed out in the recursion.  But if we adopt a
leftmost/call-by-name/normal-order evaluation strategy, we'll always
start with the `isZero` predicate, and only produce a fresh copy of
`prefac` if we are forced to. 

#Q.  You claimed that the Ackerman function couldn't be implemented using our primitive recursion techniques (such as the techniques that allow us to define addition and multiplication).  But you haven't shown that it is possible to define the Ackerman function using full recursion.#

A. OK:
  
<pre>
A(m,n) =
    | when m == 0 -> n + 1
    | else when n == 0 -> A(m-1,1)
    | else -> A(m-1, A(m,n-1))

let A = Y (\A m n. isZero m (succ n) (isZero n (A (pred m) 1) (A (pred m) (A m (pred n))))) in
</pre>

For instance,

    A 1 2
    = A 0 (A 1 1)
    = A 0 (A 0 (A 1 0))
    = A 0 (A 0 (A 0 1))
    = A 0 (A 0 2)
    = A 0 3
    = 4

A 1 x is to A 0 x as addition is to the successor function;
A 2 x is to A 1 x as multiplication is to addition;
A 3 x is to A 2 x as exponentiation is to multiplication---
so A 4 x is to A 3 x as hyper-exponentiation is to exponentiation...

#Q. What other questions should I be asking?#

*    What is it about the variant fixed-point combinators that makes
     them compatible with a call-by-value evaluation strategy?

*    How do you know that the Ackerman function can't be computed
     using primitive recursion techniques?

*    What *exactly* is primitive recursion?

*    I hear that `Y` delivers the *least* fixed point.  Least
     according to what ordering?  How do you know it's least?
     Is leastness important?


##The simply-typed lambda calculus##

The uptyped lambda calculus is pure computation.  It is much more
common, however, for practical programming languages to be typed.
Likewise, systems used to investigate philosophical or linguistic
issues are almost always typed.  Types will help us reason about our
computations.  They will also facilitate a connection between logic
and computation.

Soon we will consider polymorphic type systems.  First, however, we
will consider the simply-typed lambda calculus.  There's good news and
bad news: the good news is that the simply-type lambda calculus is
strongly normalizing: every term has a normal form.  We shall see that
self-application is outlawed, so &Omega; can't even be written, let
alone undergo reduction.  The bad news is that fixed-point combinators
are also forbidden, so recursion is neither simple nor direct.

#Types#

We will have at least one ground type, `o`.  From a linguistic point
of view, think of the ground types as the bar-level 0 categories, that
is, the lexical types, such as Noun, Verb, Preposition (glossing over
the internal complexity of those categories in modern theories).

In addition, there will be a recursively-defined class of complex
types `T`, the smallest set such that

*    ground types, including `o`, are in `T`

*    for any types &sigma; and &tau; in `T`, the type &sigma; -->
     &tau; is in `T`.

For instance, here are some types in `T`:

     o
     o --> o
     o --> o --> o
     (o --> o) --> o
     (o --> o) --> o --> o

and so on.

#Typed lambda terms#

Given a set of types `T`, we define the set of typed lambda terms <code>&Lambda;_T</code>,
which is the smallest set such that

*    each type `t` has an infinite set of distinct variables, {x^t}_1,
     {x^t}_2, {x^t}_3, ...

*    If a term `M` has type &sigma; --> &tau;, and a term `N` has type
     &sigma;, then the application `(M N)` has type &tau;.

*    If a variable `a` has type &sigma;, and term `M` has type &tau;, 
     then the abstract <code>&lambda; a M</code> has type &sigma; --> &tau;.

The definitions of types and of typed terms should be highly familiar
to semanticists, except that instead of writing &sigma; --> &tau;,
linguists (following Montague, who followed Church) write <&sigma;,
&tau;>.  We will use the arrow notation, since it is more iconic.

Some examples (assume that `x` has type `o`):

      x            o
      \x.x         o --> o
      ((\x.x) x)   o

Excercise: write down terms that have the following types:

                   o --> o --> o
                   (o --> o) --> o --> o
                   (o --> o --> o) --> o

#Associativity of types versus terms#

As we have seen many times, in the lambda calculus, function
application is left associative, so that `f x y z == (((f x) y) z)`.
Types, *THEREFORE*, are right associative: if `f`, `x`, `y`, and `z`
have types `a`, `b`, `c`, and `d`, respectively, then `f` has type `a
--> b --> c --> d == (a --> (b --> (c --> d)))`.

It is a serious faux pas to associate to the left for types.  You may
as well use your salad fork to stir your tea.

#The simply-typed lambda calculus is strongly normalizing#

If `M` is a term with type &tau; in &Lambda;_T, then `M` has a
normal form.  The proof is not particularly complex, but we will not
present it here; see Berendregt or Hankin.

Since &Omega; does not have a normal form, it follows that &Omega;
cannot have a type in &Lambda;_T.  We can easily see why:

     &Omega; = (\x.xx)(\x.xx)

Assume &Omega; has type &tau;, and `\x.xx` has type &sigma;.  Then
because `\x.xx` takes an argument of type &sigma; and returns
something of type &tau;, `\x.xx` must also have type &sigma; -->
&tau;.  By repeating this reasoning, `\x.xx` must also have type
(&sigma; --> &tau;) --> &tau;; and so on.  Since variables have
finite types, there is no way to choose a type for the variable `x`
that can satisfy all of the requirements imposed on it.

In general, there is no way for a function to have a type that can
take itself for an argument.  It follows that there is no way to
define the identity function in such a way that it can take itself as
an argument.  Instead, there must be many different identity
functions, one for each type.

#Typing numerals#

Version 1 type numerals are not a good choice for the simply-typed
lambda calculus.  The reason is that each different numberal has a
different type!  For instance, if zero has type &sigma;, then `false`
has type &tau; --> &tau; --> &tau;, for some &tau;.  Since one is
represented by the function `\x.x false 0`, one must have type (&tau;
--> &tau; --> &tau;) --> &sigma; --> &sigma;.  But this is a different
type than zero!  Because each number has a different type, it becomes
impossible to write arithmetic operations that can combine zero with
one.  We would need as many different addition operations as we had
pairs of numbers that we wanted to add.

Fortunately, the Church numberals are well behaved with respect to
types.  They can all be given the type (&sigma; --> &sigma;) -->
&sigma; --> &sigma;.





<!--

Mau integrate some mention of this at some point.

http://okmij.org/ftp/Computation/lambda-calc.html#predecessor


Predecessor and lists are not representable in simply typed lambda-calculus

    The predecessor of a Church-encoded numeral, or, generally, the encoding of a list with the car and cdr operations are both impossible in the simply typed lambda-calculus. Henk Barendregt's ``The impact of the lambda-calculus in logic and computer science'' (The Bulletin of Symbolic Logic, v3, N2, June 1997) has the following phrase, on p. 186:

        Even for a function as simple as the predecessor lambda definability remained an open problem for a while. From our present knowledge it is tempting to explain this as follows. Although the lambda calculus was conceived as an untyped theory, typeable terms are more intuitive. Now the functions addition and multiplication are defineable by typeable terms, while [101] and [108] have characterized the lambda-defineable functions in the (simply) typed lambda calculus and the predecessor is not among them [the story of the removal of Kleene's four wisdom teeth is skipped...]
        Ref 108 is R.Statman: The typed lambda calculus is not elementary recursive. Theoretical Comp. Sci., vol 9 (1979), pp. 73-81.

    Since list is a generalization of numeral -- with cons being a successor, append being the addition, tail (aka cdr) being the predecessor -- it follows then the list cannot be encoded in the simply typed lambda-calculus.

    To encode both operations, we need either inductive (generally, recursive) types, or System F with its polymorphism. The first approach is the most common. Indeed, the familiar definition of a list

         data List a = Nil | Cons a (List a)

    gives an (iso-) recursive data type (in Haskell. In ML, it is an inductive data type).

    Lists can also be represented in System F. As a matter of fact, we do not need the full System F (where the type reconstruction is not decidable). We merely need the extension of the Hindley-Milner system with higher-ranked types, which requires a modicum of type annotations and yet is able to infer the types of all other terms. This extension is supported in Haskell and OCaml. With such an extension, we can represent a list by its fold, as shown in the code below. It is less known that this representation is faithful: we can implement all list operations, including tail, drop, and even zip.


-->