new_stuff
[lambda.git] / week11.mdwn
1 [[!toc]]
2
3 Recall back in [[Assignment4]], we asked you to enumerate the "fringe" of a leaf-labeled tree. Both of these trees:
4
5             .                .
6            / \              / \
7           .   3            1   .
8          / \                  / \
9         1   2                2   3
10
11 have the same fringe: `[1;2;3]`. We also asked you to write a function that determined when two trees have the same fringe. The way you approached that back then was to enumerate each tree's fringe, and then compare the two lists for equality. Today, and then again in a later class, we'll encounter two new ways to approach the problem of determining when two trees have the same fringe.
12
13 ##List Zippers##
14
15 Say you've got some moderately-complex function for searching through a list, for example:
16
17         let find_nth (test : 'a -> bool) (n : int) (lst : 'a list) : (int * 'a) ->
18                 let rec helper (position : int) n lst =
19                         match lst with
20                         | [] -> failwith "not found"
21                         | x :: xs when test x -> (if n = 1
22                                 then (position, x)
23                                 else helper (position + 1) (n - 1) xs
24                         )
25                         | x :: xs -> helper (position + 1) n xs
26                 in helper 0 n lst;;
27
28 This searches for the `n`th element of a list that satisfies the predicate `test`, and returns a pair containing the position of that element, and the element itself. Good. But now what if you wanted to retrieve a different kind of information, such as the `n`th element matching `test`, together with its preceding and succeeding elements? In a real situation, you'd want to develop some good strategy for reporting when the target element doesn't have a predecessor and successor; but we'll just simplify here and report them as having some default value:
29
30         let find_nth' (test : 'a -> bool) (n : int) (lst : 'a list) (default : 'a) : ('a * 'a * 'a) ->
31                 let rec helper (predecessor : 'a) n lst =
32                         match lst with
33                         | [] -> failwith "not found"
34                         | x :: xs when test x -> (if n = 1
35                                 then (predecessor, x, match xs with [] -> default | y::ys -> y)
36                                 else helper x (n - 1) xs
37                         )
38                         | x :: xs -> helper x n xs
39                 in helper default n lst;;
40
41 This duplicates a lot of the structure of `find_nth`; it just has enough different code to retrieve different information when the matching element is found. But now what if you wanted to retrieve yet a different kind of information...? Ideally, there should be some way to factor out the code to find the target element---the `n`th element of the list satisfying the predicate `test`---from the code that retrieves the information you want once the target is found. We might build upon the initial `find_nth` function, since that returns the *position* of the matching element. We could hand that result off to some other function that's designed to retrieve information of a specific sort surrounding that position. But suppose our list has millions of elements, and the target element is at position 600512. The search function will already have traversed 600512 elements of the list looking for the target, then the retrieval function would have to *start again from the beginning* and traverse those same 600512 elements again. It could go a bit faster, since it doesn't have to check each element against `test` as it traverses. It already knows how far it has to travel. But still, this should seem a bit wasteful.
42
43 Here's an idea. What if we had some way of representing a list as "broken" at a specific point. For example, if our base list is:
44
45         [10; 20; 30; 40; 50; 60; 70; 80; 90]
46
47 we might imagine the list "broken" at position 3 like this (positions are numbered starting from 0):
48
49                     40;
50                 30;     50;
51             20;             60;
52         [10;                    70;
53                                     80;
54                                         90]
55
56 Then if we move one step forward in the list, it would be "broken" at position 4:
57
58                         50;
59                     40;     60;
60                 30;             70;
61             20;                     80;
62         [10;                            90]
63
64 If we had some convenient representation of these "broken" lists, then our search function could hand *that* off to the retrieval function, and the retrieval function could start right at the position where the list was broken, without having to start at the beginning and traverse many elements to get there. The retrieval function would also be able to inspect elements both forwards and backwards from the position where the list was "broken".
65
66 The kind of data structure we're looking for here is called a **list zipper**. To represent our first broken list, we'd use two lists: (1) containing the elements in the left branch, preceding the target element, *in the order reverse to their appearance in the base list*. (2) containing the target element and the rest of the list, in normal order. So:
67
68                     40;
69                 30;     50;
70             20;             60;
71         [10;                    70;
72                                     80;
73                                         90]
74
75 would be represented as `([30; 20; 10], [40; 50; 60; 70; 80; 90])`. To move forward in the base list, we pop the head element `40` off of the head element of the second list in the zipper, and push it onto the first list, getting `([40; 30; 20; 10], [50; 60; 70; 80; 90])`. To move backwards again, we pop off of the first list, and push it onto the second. To reconstruct the base list, we just "move backwards" until the first list is empty. (This is supposed to evoke the image of zipping up a zipper; hence the data structure's name.)
76
77 This is a very handy datastructure, and it will become even more handy when we translate it over to more complicated base structures, like trees. To help get a good conceptual grip on how to do that, it's useful to introduce a kind of symbolism for talking about zippers. This is just a metalanguage notation, for us theorists; we don't need our programs to interpret the notation. We'll use a specification like this:
78
79         [10; 20; 30; *; 50; 60; 70; 80; 90], * filled by 40
80
81 to represent a list zipper where the break is at position 3, and the element occupying that position is 40. For a list zipper, this is implemented using the pairs-of-lists structure described above.
82
83
84 ##Tree Zippers##
85
86 Now how could we translate a zipper-like structure over to trees? What we're aiming for is a way to keep track of where we are in a tree, in the same way that the "broken" lists let us keep track of where we are in the base list. In a particular application, you may only need to implement this for binary trees---trees where internal nodes always have exactly two subtrees. But to get the guiding idea, it's helpful first to think about trees that permit nodes to have many subtrees. Suppose we have the following tree:
87
88                                  1000
89                             /      |  \
90                          /         |    \
91                       /            |      \
92                    /               |        \
93                 /                  |          \
94                500                920          950
95             /   |    \          /  |  \      /  |  \
96          20     50     80      91  92  93   94  95  96
97         1 2 3  4 5 6  7 8 9
98
99 and we want to represent that we're at the node marked `50`. We might use the following metalanguage notation to specify this:
100
101         {parent = ...; siblings = [node 20; *; node 80]}, * filled by node 50
102
103 This is modeled on the notation suggested above for list zippers. Here `node 20` refers not to a `int` label associated with that node, but rather to the whole subtree rooted at that node:
104
105           20
106          / | \
107         1  2  3
108
109 Similarly for `node 50` and `node 80`. We haven't said yet what goes in the `parent = ...` slot. Well, the parent of a subtree targetted on `node 50` should intuitively be a tree targetted on `node 500`:
110
111         {parent = ...; siblings = [*; node 920; node 950]}, * filled by node 500
112
113 And the parent of that targetted subtree should intuitively be a tree targetted on `node 1000`:
114
115         {parent = None; siblings = [*]}, * filled by node 1000
116
117 This tree has no parents because it's the root of the base tree. Fully spelled out, then, our tree targetted on `node 50` would be:
118
119         {
120            parent = {
121               parent = {
122                  parent = None;
123                  siblings = [*]
124               }, * filled by node 1000;
125               siblings = [*; node 920; node 950]
126            }, * filled by node 500;
127            siblings = [node 20; *; node 80]
128         }, * filled by node 50
129
130 In fact, there's some redundancy in this structure, at the points where we have `* filled by node 1000` and `* filled by node 500`. Most of `node 1000`---with the exception of any label attached to node `1000` itself---is determined by the rest of this structure; and so too with `node 500`. So we could really work with:
131
132         {
133            parent = {
134               parent = {
135                  parent = None;
136                  siblings = [*]
137               }, label for * position (at node 1000);
138               siblings = [*; node 920; node 950]
139            }, label for * position (at node 500);
140            siblings = [node 20; *; node 80]
141         }, * filled by node 50
142
143 Or, if we only had labels on the leafs of our tree:
144
145         {
146            parent = {
147               parent = {
148                  parent = None;
149                  siblings = [*]
150               },
151               siblings = [*; node 920; node 950]
152            },
153            siblings = [node 20; *; node 80]
154         }, * filled by node 50
155
156 We're understanding the `20` here in `node 20` to just be a metalanguage marker to help us theorists keep track of which node we're referring to. We're supposing the tree structure itself doesn't associate any informative labelling information with those nodes. It only associates informative labels with the tree leafs. (We haven't represented any such labels in our diagrams.)
157
158 We still do need to keep track of what fills the outermost targetted position---`* filled by node 50`---because that contain a subtree of arbitrary complexity, that is not determined by the rest of this data structure.
159
160 For simplicity, I'll continue to use the abbreviated form:
161
162         {parent = ...; siblings = [node 20; *; node 80]}, * filled by node 50
163
164 But that should be understood as standing for the more fully-spelled-out structure. Structures of this sort are called **tree zippers**, for a reason that will emerge. They should already seem intuitively similar to list zippers, though, at least in what we're using them to represent. I think it may initially be more helpful to call these **targetted trees**, though, and so will be switching back and forth between this different terms.
165
166 Moving left in our targetted tree that's targetted on `node 50` would be a matter of shifting the `*` leftwards:
167
168         {parent = ...; siblings = [*; node 50; node 80]}, * filled by node 20
169
170 and similarly for moving right. If the sibling list is implemented as a list zipper, you should already know how to do that. If one were designing a tree zipper for a more restricted kind of tree, however, such as a binary tree, one would probably not represent siblings with a list zipper, but with something more special-purpose and economical.
171
172 Moving downward in the tree would be a matter of constructing a tree targetted on some child of `node 20`, with the first part of the targetted tree above as its parent:
173
174         {
175            parent = {parent = ...; siblings = [*; node 50; node 80]};
176            siblings = [*; leaf 2; leaf 3]
177         }, * filled by leaf 1
178
179 How would we move upward in a tree? Well, we'd build a regular, untargetted tree with a root node---let's call it `20`---and whose children are given by the outermost sibling list in the targetted tree above, after inserting the targetted subtree into the `*` position:
180
181                node 20
182             /     |    \
183          /        |      \
184         leaf 1  leaf 2  leaf 3
185
186 We'll call this new untargetted tree `node 20`. The result of moving upward from our previous targetter tree, targetted on `leaf 1`, would be the outermost `parent` element of that targetted tree, with `node 20` being the subtree that fills that parent's target position `*`:
187
188         {
189            parent = ...;
190            siblings = [*; node 50; node 80]
191         }, * filled by node 20
192
193 Or, spelling that structure out fully:
194
195         {
196            parent = {
197               parent = {
198                  parent = None;
199                  siblings = [*]
200               },
201               siblings = [*; node 920; node 950]
202            },
203            siblings = [*; node 50; node 80]
204         }, * filled by node 20
205
206 Moving upwards yet again would get us:
207
208         {
209            parent = {
210               parent = None;
211               siblings = [*]
212            },
213            siblings = [*; node 920; node 950]
214         }, * filled by node 500
215
216 where `node 500` refers to a tree built from a root node whose children are given by the list `[*; node 50; node 80]`, with `node 20` inserted into the `*` position. Moving upwards yet again would get us:
217
218         {
219            parent = None;
220            siblings = [*]
221         }, * filled by node 1000
222
223 where the targetted element is the root of our base tree. Like the "moving backward" operation for the list zipper, this "moving upward" operation is supposed to be reminiscent of closing a zipper, and that's why these data structures are called zippers.
224
225 We haven't given you a real implementation of the tree zipper, but only a suggestive notation. We have however told you enough that you should be able to implement it yourself. Or if you're lazy, you can read:
226
227 *       [[!wikipedia Zipper (data structure)]]
228 *       Huet, Gerard. ["Functional Pearl: The Zipper"](http://www.st.cs.uni-sb.de/edu/seminare/2005/advanced-fp/docs/huet-zipper.pdf) Journal of Functional Programming 7 (5): 549-554, September 1997.
229 *       As always, [Oleg](http://okmij.org/ftp/continuations/Continuations.html#zipper) takes this a few steps deeper.
230
231 ##Same-fringe using a tree zipper##
232
233 Supposing you did work out an implementation of the tree zipper, then one way to determine whether two trees have the same fringe would be: go downwards (and leftwards) in each tree as far as possible. Compare the targetted leaves. If they're different, stop because the trees have different fringes. If they're the same, then for each tree, move rightward if possible; if it's not (because you're at the rightmost position in a sibling list), more upwards then try again to move rightwards. Repeat until you are able to move rightwards. Once you do move rightwards, go downwards (and leftwards) as far as possible. Then you'll be targetted on the next leaf in the tree's fringe. The operations it takes to get to "the next leaf" may be different for the two trees. For example, in these trees:
234
235             .                .
236            / \              / \
237           .   3            1   .
238          / \                  / \
239         1   2                2   3
240
241 you won't move upwards at the same steps. Keep comparing "the next leafs" until they are different, or you exhaust the leafs of only one of the trees (then again the trees have different fringes), or you exhaust the leafs of both trees at the same time, without having found leafs with different labels. In this last case, the trees have the same fringe.
242
243 If your trees are very big---say, millions of leaves---you can imagine how this would be quicker and more memory-efficient than traversing each tree to construct a list of its fringe, and then comparing the two lists so built to see if they're equal. For one thing, the zipper method can abort early if the fringes diverge early, without needing to traverse or built a list containing the rest of each tree's fringe.
244
245 Let's sketch the implementation of this. We won't provide all the details for an implementation of the tree zipper, but we will sketch an interface for it.
246
247 First, we define a type for leaf-labeled, binary trees:
248
249         type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)
250
251 Next, the interface for our tree zippers. We'll help ourselves to OCaml's **record types**. These are nothing more than tuples with a pretty interface. Instead of saying:
252
253         # type blah = Blah of (int * int * (char -> bool));;
254
255 and then having to remember which element in the triple was which:
256
257         # let b1 = Blah (1, (fun c -> c = 'M'), 2);;
258         Error: This expression has type int * (char -> bool) * int
259        but an expression was expected of type int * int * (char -> bool)
260         # (* damnit *)
261         # let b1 = Blah (1, 2, (fun c -> c = 'M'));;
262         val b1 : blah = Blah (1, 2, <fun>)
263
264 records let you attach descriptive labels to the components of the tuple:
265
266         # type blah_record = { height : int; weight : int; char_tester : char -> bool };;
267         # let b2 = { height = 1; weight = 2; char_tester = fun c -> c = 'M' };;
268         val b2 : blah_record = {height = 1; weight = 2; char_tester = <fun>}
269
270 These were the strategies to extract the components of an unlabeled tuple:
271
272         let h = fst some_pair;; (* accessor functions fst and snd are only predefined for pairs *)
273
274         let (h, w, test) = b1;; (* works for arbitrary tuples *)
275
276         match b1 with
277         | (h, w, test) -> ...;; (* same as preceding *)
278
279 Here is how you can extract the components of a labeled record:
280
281         let h = b2.height;; (* handy! *)
282
283         let {height = h; weight = w; char_tester = test} = b2
284         in (* go on to use h, w, and test ... *)
285
286         match test with
287         | {height = h; weight = w; char_tester = test} ->
288                 (* go on to use h, w, and test ... *)
289
290 Anyway, using record types, we might define the tree zipper interface like so:
291
292         type 'a starred_tree = Root | Starring_Left of 'a starred_pair | Starring_Right of 'a starred_pair
293         and 'a starred_pair = { parent : 'a starred_tree; sibling: 'a tree }
294         and 'a zipper = { tree : 'a starred_tree; filler: 'a tree };;
295
296         let rec move_botleft (z : 'a zipper) : 'a zipper =
297             (* returns z if the targetted node in z has no children *)
298             (* else returns move_botleft (zipper which results from moving down and left in z) *)
299
300 <!--
301             let {tree; filler} = z
302             in match filler with
303             | Leaf _ -> z
304             | Node(left, right) ->
305                 let zdown = {tree = Starring_Left {parent = tree; sibling = right}; filler = left}
306                 in move_botleft zdown
307             ;;
308 -->
309
310         let rec move_right_or_up (z : 'a zipper) : 'a zipper option =
311             (* if it's possible to move right in z, returns Some (the result of doing so) *)
312             (* else if it's not possible to move any further up in z, returns None *)
313             (* else returns move_right_or_up (result of moving up in z) *)
314
315 <!--
316             let {tree; filler} = z
317             in match tree with
318             | Starring_Left {parent; sibling = right} -> Some {tree = Starring_Right {parent; sibling = filler}; filler = right}
319             | Root -> None
320             | Starring_Right {parent; sibling = left} ->
321                 let z' = {tree = parent; filler = Node(left, filler)}
322                 in move_right_or_up z'
323             ;;
324 -->
325
326 The following function takes an 'a tree and returns an 'a zipper focused on its root:
327
328         let new_zipper (t : 'a tree) : 'a zipper =
329             {tree = Root; filler = t}
330             ;;
331
332 Finally, we can use a mutable reference cell to define a function that enumerates a tree's fringe until it's exhausted:
333
334         let make_fringe_enumerator (t: 'a tree) =
335             (* create a zipper targetting the root of t *)
336             let zstart = new_zipper t
337             in let zbotleft = move_botleft zstart
338             (* create a refcell initially pointing to zbotleft *)
339             in let zcell = ref (Some zbotleft)
340             (* construct the next_leaf function *)
341             in let next_leaf () : 'a option =
342                 match !zcell with
343                 | None -> (* we've finished enumerating the fringe *)
344                     None
345                 | Some z -> (
346                     (* extract label of currently-targetted leaf *)
347                     let Leaf current = z.filler
348                     (* update zcell to point to next leaf, if there is one *)
349                     in let () = zcell := match move_right_or_up z with
350                         | None -> None
351                         | Some z' -> Some (move_botleft z')
352                     (* return saved label *)
353                     in Some current
354                 )
355             (* return the next_leaf function *)
356             in next_leaf
357             ;;
358
359 Here's an example of `make_fringe_enumerator` in action:
360
361         # let tree1 = Leaf 1;;
362         val tree1 : int tree = Leaf 1
363         # let next1 = make_fringe_enumerator tree1;;
364         val next1 : unit -> int option = <fun>
365         # next1 ();;
366         - : int option = Some 1
367         # next1 ();;
368         - : int option = None
369         # next1 ();;
370         - : int option = None
371         # let tree2 = Node (Node (Leaf 1, Leaf 2), Leaf 3);;
372         val tree2 : int tree = Node (Node (Leaf 1, Leaf 2), Leaf 3)
373         # let next2 = make_fringe_enumerator tree2;;
374         val next2 : unit -> int option = <fun>
375         # next2 ();;
376         - : int option = Some 1
377         # next2 ();;
378         - : int option = Some 2
379         # next2 ();;
380         - : int option = Some 3
381         # next2 ();;
382         - : int option = None
383         # next2 ();;
384         - : int option = None
385
386 You might think of it like this: `make_fringe_enumerator` returns a little subprogram that will keep returning the next leaf in a tree's fringe, in the form `Some ...`, until it gets to the end of the fringe. After that, it will keep returning `None`.
387
388 Using these fringe enumerators, we can write our `same_fringe` function like this:
389
390         let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
391                 let next1 = make_fringe_enumerator t1
392                 in let next2 = make_fringe_enumerator t2
393                 in let rec loop () : bool =
394                         match next1 (), next2 () with
395                         | Some a, Some b when a = b -> loop ()
396                         | None, None -> true
397                         | _ -> false
398                 in loop ()
399                 ;;
400
401 The auxiliary `loop` function will keep calling itself recursively until a difference in the fringes has manifested itself---either because one fringe is exhausted before the other, or because the next leaves in the two fringes have different labels. If we get to the end of both fringes at the same time (`next1 (), next2 ()` matches the pattern `None, None`) then we've established that the trees do have the same fringe.
402
403 The technique illustrated here with our fringe enumerators is a powerful and important one. It's an example of what's sometimes called **cooperative threading**. A "thread" is a subprogram that the main computation spawns off. Threads are called "cooperative" when the code of the main computation and the thread fixes when control passes back and forth between them. (When the code doesn't control this---for example, it's determined by the operating system or the hardware in ways that the programmer can't predict---that's called "preemptive threading.") With cooperative threads, one typically yields control to the thread, and then back again to the main program, multiple times. Here's the pattern in which that happens in our `same_fringe` function:
404
405         main program            next1 thread            next2 thread
406         ------------            ------------            ------------
407         start next1
408         (paused)                        starting
409         (paused)                        calculate first leaf
410         (paused)                        <--- return it
411         start next2                     (paused)                        starting
412         (paused)                        (paused)                        calculate first leaf
413         (paused)                        (paused)                        <-- return it
414         compare leaves          (paused)                        (paused)
415         call loop again         (paused)                        (paused)
416         call next1 again        (paused)                        (paused)
417         (paused)                        calculate next leaf     (paused)
418         (paused)                        <-- return it           (paused)
419         ... and so on ...
420
421 The way we built cooperative threads here crucially relied on two heavyweight tools. First, it relied on our having a data structure (the tree zipper) capable of being a static snapshot of where we left off in the tree whose fringe we're enumerating. Second, it relied on our using mutable reference cells so that we could update what the current snapshot (that is, tree zipper) was, so that the next invocation of the `next_leaf` function could start up again where the previous invocation left off.
422
423 In coming weeks, we'll learn about a different way to create threads, that relies on **continuations** rather than on those two tools. All of these tools are inter-related. As Oleg says, "Zipper can be viewed as a delimited continuation reified as a data structure." These different tools are also inter-related with monads. Many of these tools can be used to define the others. We'll explore some of the connections between them in the remaining weeks, but we encourage you to explore more.
424
425