[lambda.git] / week11.mdwn

These notes may change in the next few days (today is 30 Nov 2010).
The material here benefited from many discussions with Ken Shan.

##[[Tree and List Zippers]]##

##[[Coroutines and Aborts]]##

##[[From Lists to Continuations]]##

This searches for the `n`th element of a list that satisfies the predicate `test`, and returns a pair containing the position of that element, and the element itself. Good. But now what if you wanted to retrieve a different kind of information, such as the `n`th element matching `test`, together with its preceding and succeeding elements? In a real situation, you'd want to develop some good strategy for reporting when the target element doesn't have a predecessor and successor; but we'll just simplify here and report them as having some default value:

        let find_nth' (test : 'a -> bool) (n : int) (lst : 'a list) (default : 'a) : ('a * 'a * 'a) ->
                let rec helper (predecessor : 'a) n lst =
                        match lst with
                        | [] -> failwith "not found"
                        | x :: xs when test x -> (if n = 1
                                then (predecessor, x, match xs with [] -> default | y::ys -> y)
                                else helper x (n - 1) xs
                        )
                        | x :: xs -> helper x n xs
                in helper default n lst;;

This duplicates a lot of the structure of `find_nth`; it just has enough different code to retrieve different information when the matching element is found. But now what if you wanted to retrieve yet a different kind of information...?

Ideally, there should be some way to factor out the code to find the target element---the `n`th element of the list satisfying the predicate `test`---from the code that retrieves the information you want once the target is found. We might build upon the initial `find_nth` function, since that returns the *position* of the matching element. We could hand that result off to some other function that's designed to retrieve information of a specific sort surrounding that position. But suppose our list has millions of elements, and the target element is at position 600512. The search function will already have traversed 600512 elements of the list looking for the target, then the retrieval function would have to *start again from the beginning* and traverse those same 600512 elements again. It could go a bit faster, since it doesn't have to check each element against `test` as it traverses. It already knows how far it has to travel. But still, this should seem a bit wasteful.

Here's an idea. What if we had some way of representing a list as "broken" at a specific point. For example, if our base list is:

        [10; 20; 30; 40; 50; 60; 70; 80; 90]

we might imagine the list "broken" at position 3 like this (positions are numbered starting from 0):

                    40;
                30;     50;
            20;             60;
        [10;                    70;
                                    80;
                                        90]

Then if we move one step forward in the list, it would be "broken" at position 4:

                        50;
                    40;     60;
                30;             70;
            20;                     80;
        [10;                            90]

If we had some convenient representation of these "broken" lists, then our search function could hand *that* off to the retrieval function, and the retrieval function could start right at the position where the list was broken, without having to start at the beginning and traverse many elements to get there. The retrieval function would also be able to inspect elements both forwards and backwards from the position where the list was "broken".

The kind of data structure we're looking for here is called a **list zipper**. To represent our first broken list, we'd use two lists: (1) containing the elements in the left branch, preceding the target element, *in the order reverse to their appearance in the base list*. (2) containing the target element and the rest of the list, in normal order. So:

                    40;
                30;     50;
            20;             60;
        [10;                    70;
                                    80;
                                        90]

would be represented as `([30; 20; 10], [40; 50; 60; 70; 80; 90])`. To move forward in the base list, we pop the head element `40` off of the head element of the second list in the zipper, and push it onto the first list, getting `([40; 30; 20; 10], [50; 60; 70; 80; 90])`. To move backwards again, we pop off of the first list, and push it onto the second. To reconstruct the base list, we just "move backwards" until the first list is empty. (This is supposed to evoke the image of zipping up a zipper; hence the data structure's name.)

We had some discussio in seminar of the right way to understand the "zipper" metaphor. I think it's best to think of the tab of the zipper being here:

                 t
                  a
                   b
                    40;
                30;     50;
            20;             60;
        [10;                    70;
                                    80;
                                        90]

And imagine that you're just seeing the left half of a real-zipper, rotated 60 degrees counter-clockwise. When the list is all "zipped up", we've "move backwards" to the state where the first element is targetted:

        ([], [10; 20; 30; 40; 50; 60; 70; 80; 90])

However you understand the "zipper" metaphor, this is a very handy datastructure, and it will become even more handy when we translate it over to more complicated base structures, like trees. To help get a good conceptual grip on how to do that, it's useful to introduce a kind of symbolism for talking about zippers. This is just a metalanguage notation, for us theorists; we don't need our programs to interpret the notation. We'll use a specification like this:

        [10; 20; 30; *; 50; 60; 70; 80; 90], * filled by 40

to represent a list zipper where the break is at position 3, and the element occupying that position is 40. For a list zipper, this is implemented using the pairs-of-lists structure described above.


##Tree Zippers##

Now how could we translate a zipper-like structure over to trees? What we're aiming for is a way to keep track of where we are in a tree, in the same way that the "broken" lists let us keep track of where we are in the base list.

It's important to set some ground rules for what will follow. If you don't understand these ground rules you will get confused. First off, for many uses of trees one wants some of the nodes or leafs in the tree to be *labeled* with additional information. It's important not to conflate the label with the node itself. Numerically one and the same piece of information---for example, the same `int`---could label two nodes of the tree without those nodes thereby being identical, as here:

                root
                / \
              /     \
            /  \    label 1
          /      \
        label 1  label 2

The leftmost leaf and the rightmost leaf have the same label; but they are different leafs. The leftmost leaf has a sibling leaf with the label 2; the rightmost leaf has no siblings that are leafs. Sometimes when one is diagramming trees, one will annotate the nodes with the labels, as above. Other times, when one is diagramming trees, one will instead want to annotate the nodes with tags to make it easier to refer to particular parts of the tree. So for instance, I could diagram the same tree as above as:

                 1
                / \
              2     \
            /  \     5
          /      \
         3        4

Here I haven't drawn what the labels are. The leftmost leaf, the node tagged "3" in this diagram, doesn't have the label `3`. It has the label 1, as we said before. I just haven't put that into the diagram. The node tagged "2" doesn't have the label `2`. It doesn't have any label. The tree in this example only has information labeling its leafs, not any of its inner nodes. The identity of its inner nodes is exhausted by their position in the tree.

That is a second thing to note. In what follows, we'll only be working with *leaf-labeled* trees. In some uses of trees, one also wants labels on inner nodes. But we won't be discussing any such trees now. Our trees only have labels on their leafs. The diagrams below will tag all of the nodes, as in the second diagram above, and won't display what the leafs' labels are.

Final introductory comment: in particular applications, you may only need to work with binary trees---trees where internal nodes always have exactly two subtrees. That is what we'll work with in the homework, for example. But to get the guiding idea of how tree zippers work, it's helpful first to think about trees that permit nodes to have many subtrees. So that's how we'll start.

Suppose we have the following tree:

                                 9200
                            /      |  \
                         /         |    \
                      /            |      \
                   /               |        \
                /                  |          \
               500                920          950
            /   |    \          /  |  \      /  |  \
         20     50     80      91  92  93   94  95  96
        1 2 3  4 5 6  7 8 9

This is a leaf-labeled tree whose labels aren't displayed. The `9200` and so on are tags to make it easier for us to refer to particular parts of the tree.

Suppose we want to represent that we're *at* the node marked `50`. We might use the following metalanguage notation to specify this:

        {parent = ...; siblings = [subtree 20; *; subtree 80]}, * filled by subtree 50

This is modeled on the notation suggested above for list zippers. Here `subtree 20` refers to the whole subtree rooted at node `20`:

          20
         / | \
        1  2  3

Similarly for `subtree 50` and `subtree 80`. We haven't said yet what goes in the `parent = ...` slot. Well, the parent of a subtree targetted on `node 50` should intuitively be a tree targetted on `node 500`:

        {parent = ...; siblings = [*; subtree 920; subtree 950]}, * filled by subtree 500

And the parent of that targetted subtree should intuitively be a tree targetted on `node 9200`:

        {parent = None; siblings = [*]}, * filled by tree 9200

This tree has no parents because it's the root of the base tree. Fully spelled out, then, our tree targetted on `node 50` would be:

        {
           parent = {
              parent = {
                 parent = None;
                 siblings = [*]
              }, * filled by tree 9200;
              siblings = [*; subtree 920; subtree 950]
           }, * filled by subtree 500;
           siblings = [subtree 20; *; subtree 80]
        }, * filled by subtree 50

In fact, there's some redundancy in this structure, at the points where we have `* filled by tree 9200` and `* filled by subtree 500`. Since node 9200 doesn't have any label attached to it, the subtree rooted in it is determined by the rest of this structure; and so too with `subtree 500`. So we could really work with:

        {
           parent = {
              parent = {
                 parent = None;
                 siblings = [*]
              },
              siblings = [*; subtree 920; subtree 950]
           },
           siblings = [subtree 20; *; subtree 80]
        }, * filled by subtree 50


We still do need to keep track of what fills the outermost targetted position---`* filled by subtree 50`---because that contain a subtree of arbitrary complexity, that is not determined by the rest of this data structure.

For simplicity, I'll continue to use the abbreviated form:

        {parent = ...; siblings = [subtree 20; *; subtree 80]}, * filled by subtree 50

But that should be understood as standing for the more fully-spelled-out structure. Structures of this sort are called **tree zippers**. They should already seem intuitively similar to list zippers, at least in what we're using them to represent. I think it may also be helpful to call them **targetted trees**, though, and so will be switching back and forth between these different terms.

Moving left in our targetted tree that's targetted on `node 50` would be a matter of shifting the `*` leftwards:

        {parent = ...; siblings = [*; subtree 50; subtree 80]}, * filled by subtree 20

and similarly for moving right. If the sibling list is implemented as a list zipper, you should already know how to do that. If one were designing a tree zipper for a more restricted kind of tree, however, such as a binary tree, one would probably not represent siblings with a list zipper, but with something more special-purpose and economical.

Moving downward in the tree would be a matter of constructing a tree targetted on some child of `node 20`, with the first part of the targetted tree above as its parent:

        {
           parent = {parent = ...; siblings = [*; subtree 50; subtree 80]};
           siblings = [*; leaf 2; leaf 3]
        }, * filled by leaf 1

How would we move upward in a tree? Well, we'd build a regular, untargetted tree with a root node---let's call it `20'`---and whose children are given by the outermost sibling list in the targetted tree above, after inserting the targetted subtree into the `*` position:

               node 20'
            /     |    \
         /        |      \
        leaf 1  leaf 2  leaf 3

We'll call this new untargetted tree `subtree 20'`. The result of moving upward from our previous targetted tree, targetted on `leaf 1`, would be the outermost `parent` element of that targetted tree, with `subtree 20'` being the subtree that fills that parent's target position `*`:

        {
           parent = ...;
           siblings = [*; subtree 50; subtree 80]
        }, * filled by subtree 20'

Or, spelling that structure out fully:

        {
           parent = {
              parent = {
                 parent = None;
                 siblings = [*]
              },
              siblings = [*; subtree 920; subtree 950]
           },
           siblings = [*; subtree 50; subtree 80]
        }, * filled by subtree 20'

Moving upwards yet again would get us:

        {
           parent = {
              parent = None;
              siblings = [*]
           },
           siblings = [*; subtree 920; subtree 950]
        }, * filled by subtree 500'

where `subtree 500'` refers to a tree built from a root node whose children are given by the list `[*; subtree 50; subtree 80]`, with `subtree 20'` inserted into the `*` position. Moving upwards yet again would get us:

        {
           parent = None;
           siblings = [*]
        }, * filled by tree 9200'

where the targetted element is the root of our base tree. Like the "moving backward" operation for the list zipper, this "moving upward" operation is supposed to be reminiscent of closing a zipper, and that's why these data structures are called zippers.

We haven't given you a real implementation of the tree zipper, but only a suggestive notation. We have however told you enough that you should be able to implement it yourself. Or if you're lazy, you can read:

*       [[!wikipedia Zipper (data structure)]]
*       Huet, Gerard. ["Functional Pearl: The Zipper"](http://www.st.cs.uni-sb.de/edu/seminare/2005/advanced-fp/docs/huet-zipper.pdf) Journal of Functional Programming 7 (5): 549-554, September 1997.
*       As always, [Oleg](http://okmij.org/ftp/continuations/Continuations.html#zipper) takes this a few steps deeper.


##Same-fringe using a zipper-based coroutine##

Recall back in [[Assignment4]], we asked you to enumerate the "fringe" of a leaf-labeled tree. Both of these trees (here I *am* drawing the labels in the diagram):

            .                .
           / \              / \
          .   3            1   .
         / \                  / \
        1   2                2   3

have the same fringe: `[1;2;3]`. We also asked you to write a function that determined when two trees have the same fringe. The way you approached that back then was to enumerate each tree's fringe, and then compare the two lists for equality. Today, and then again in a later class, we'll encounter new ways to approach the problem of determining when two trees have the same fringe.


Supposing you did work out an implementation of the tree zipper, then one way to determine whether two trees have the same fringe would be: go downwards (and leftwards) in each tree as far as possible. Compare the targetted leaves. If they're different, stop because the trees have different fringes. If they're the same, then for each tree, move rightward if possible; if it's not (because you're at the rightmost position in a sibling list), more upwards then try again to move rightwards. Repeat until you are able to move rightwards. Once you do move rightwards, go downwards (and leftwards) as far as possible. Then you'll be targetted on the next leaf in the tree's fringe. The operations it takes to get to "the next leaf" may be different for the two trees. For example, in these trees:

            .                .
           / \              / \
          .   3            1   .
         / \                  / \
        1   2                2   3

you won't move upwards at the same steps. Keep comparing "the next leafs" until they are different, or you exhaust the leafs of only one of the trees (then again the trees have different fringes), or you exhaust the leafs of both trees at the same time, without having found leafs with different labels. In this last case, the trees have the same fringe.

If your trees are very big---say, millions of leaves---you can imagine how this would be quicker and more memory-efficient than traversing each tree to construct a list of its fringe, and then comparing the two lists so built to see if they're equal. For one thing, the zipper method can abort early if the fringes diverge early, without needing to traverse or build a list containing the rest of each tree's fringe.

Let's sketch the implementation of this. We won't provide all the details for an implementation of the tree zipper, but we will sketch an interface for it.

First, we define a type for leaf-labeled, binary trees:

        type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)

Next, the interface for our tree zippers. We'll help ourselves to OCaml's **record types**. These are nothing more than tuples with a pretty interface. Instead of saying:

        # type blah = Blah of (int * int * (char -> bool));;

and then having to remember which element in the triple was which:

        # let b1 = Blah (1, (fun c -> c = 'M'), 2);;
        Error: This expression has type int * (char -> bool) * int
       but an expression was expected of type int * int * (char -> bool)
        # (* damnit *)
        # let b1 = Blah (1, 2, (fun c -> c = 'M'));;
        val b1 : blah = Blah (1, 2, <fun>)

records let you attach descriptive labels to the components of the tuple:

        # type blah_record = { height : int; weight : int; char_tester : char -> bool };;
        # let b2 = { height = 1; weight = 2; char_tester = fun c -> c = 'M' };;
        val b2 : blah_record = {height = 1; weight = 2; char_tester = <fun>}
        # let b3 = { height = 1; char_tester = (fun c -> c = 'K'); weight = 3 };; (* also works *)
        val b3 : blah_record = {height = 1; weight = 3; char_tester = <fun>}

These were the strategies to extract the components of an unlabeled tuple:

        let h = fst some_pair;; (* accessor functions fst and snd are only predefined for pairs *)

        let (h, w, test) = b1;; (* works for arbitrary tuples *)

        match b1 with
        | (h, w, test) -> ...;; (* same as preceding *)

Here is how you can extract the components of a labeled record:

        let h = b2.height;; (* handy! *)

        let {height = h; weight = w; char_tester = test} = b2
        in (* go on to use h, w, and test ... *)

        match test with
        | {height = h; weight = w; char_tester = test} ->
                (* go on to use h, w, and test ... *)

Anyway, using record types, we might define the tree zipper interface like so:

        type 'a starred_level = Root | Starring_Left of 'a starred_nonroot | Starring_Right of 'a starred_nonroot
        and 'a starred_nonroot = { parent : 'a starred_level; sibling: 'a tree };;

        type 'a zipper = { level : 'a starred_level; filler: 'a tree };;

        let rec move_botleft (z : 'a zipper) : 'a zipper =
            (* returns z if the targetted node in z has no children *)
            (* else returns move_botleft (zipper which results from moving down and left in z) *)

<!--
            let {level; filler} = z
            in match filler with
            | Leaf _ -> z
            | Node(left, right) ->
                let zdown = {level = Starring_Left {parent = level; sibling = right}; filler = left}
                in move_botleft zdown
            ;;
-->

        let rec move_right_or_up (z : 'a zipper) : 'a zipper option =
            (* if it's possible to move right in z, returns Some (the result of doing so) *)
            (* else if it's not possible to move any further up in z, returns None *)
            (* else returns move_right_or_up (result of moving up in z) *)

<!--
            let {level; filler} = z
            in match level with
            | Starring_Left {parent; sibling = right} -> Some {level = Starring_Right {parent; sibling = filler}; filler = right}
            | Root -> None
            | Starring_Right {parent; sibling = left} ->
                let z' = {level = parent; filler = Node(left, filler)}
                in move_right_or_up z'
            ;;
-->

The following function takes an 'a tree and returns an 'a zipper focused on its root:

        let new_zipper (t : 'a tree) : 'a zipper =
            {level = Root; filler = t}
            ;;

Finally, we can use a mutable reference cell to define a function that enumerates a tree's fringe until it's exhausted:

        let make_fringe_enumerator (t: 'a tree) =
            (* create a zipper targetting the botleft of t *)
            let zbotleft = move_botleft (new_zipper t)
            (* create a refcell initially pointing to zbotleft *)
            in let zcell = ref (Some zbotleft)
            (* construct the next_leaf function *)
            in let next_leaf () : 'a option =
                match !zcell with
                | Some z -> (
                    (* extract label of currently-targetted leaf *)
                    let Leaf current = z.filler
                    (* update zcell to point to next leaf, if there is one *)
                    in let () = zcell := match move_right_or_up z with
                        | None -> None
                        | Some z' -> Some (move_botleft z')
                    (* return saved label *)
                    in Some current
                | None -> (* we've finished enumerating the fringe *)
                    None
                )
            (* return the next_leaf function *)
            in next_leaf
            ;;

Here's an example of `make_fringe_enumerator` in action:

        # let tree1 = Leaf 1;;
        val tree1 : int tree = Leaf 1
        # let next1 = make_fringe_enumerator tree1;;
        val next1 : unit -> int option = <fun>
        # next1 ();;
        - : int option = Some 1
        # next1 ();;
        - : int option = None
        # next1 ();;
        - : int option = None
        # let tree2 = Node (Node (Leaf 1, Leaf 2), Leaf 3);;
        val tree2 : int tree = Node (Node (Leaf 1, Leaf 2), Leaf 3)
        # let next2 = make_fringe_enumerator tree2;;
        val next2 : unit -> int option = <fun>
        # next2 ();;
        - : int option = Some 1
        # next2 ();;
        - : int option = Some 2
        # next2 ();;
        - : int option = Some 3
        # next2 ();;
        - : int option = None
        # next2 ();;
        - : int option = None

You might think of it like this: `make_fringe_enumerator` returns a little subprogram that will keep returning the next leaf in a tree's fringe, in the form `Some ...`, until it gets to the end of the fringe. After that, it will keep returning `None`.

Using these fringe enumerators, we can write our `same_fringe` function like this:

        let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
                let next1 = make_fringe_enumerator t1
                in let next2 = make_fringe_enumerator t2
                in let rec loop () : bool =
                        match next1 (), next2 () with
                        | Some a, Some b when a = b -> loop ()
                        | None, None -> true
                        | _ -> false
                in loop ()
                ;;

The auxiliary `loop` function will keep calling itself recursively until a difference in the fringes has manifested itself---either because one fringe is exhausted before the other, or because the next leaves in the two fringes have different labels. If we get to the end of both fringes at the same time (`next1 (), next2 ()` matches the pattern `None, None`) then we've established that the trees do have the same fringe.

The technique illustrated here with our fringe enumerators is a powerful and important one. It's an example of what's sometimes called **cooperative threading**. A "thread" is a subprogram that the main computation spawns off. Threads are called "cooperative" when the code of the main computation and the thread fixes when control passes back and forth between them. (When the code doesn't control this---for example, it's determined by the operating system or the hardware in ways that the programmer can't predict---that's called "preemptive threading.") Cooperative threads are also sometimes called *coroutines* or *generators*.

With cooperative threads, one typically yields control to the thread, and then back again to the main program, multiple times. Here's the pattern in which that happens in our `same_fringe` function:

        main program            next1 thread            next2 thread
        ------------            ------------            ------------
        start next1
        (paused)                        starting
        (paused)                        calculate first leaf
        (paused)                        <--- return it
        start next2                     (paused)                        starting
        (paused)                        (paused)                        calculate first leaf
        (paused)                        (paused)                        <-- return it
        compare leaves          (paused)                        (paused)
        call loop again         (paused)                        (paused)
        call next1 again        (paused)                        (paused)
        (paused)                        calculate next leaf     (paused)
        (paused)                        <-- return it           (paused)
        ... and so on ...

If you want to read more about these kinds of threads, here are some links:

<!-- *  [[!wikipedia Computer_multitasking]]
*       [[!wikipedia Thread_(computer_science)]] -->

*       [[!wikipedia Coroutine]]
*       [[!wikipedia Iterator]]
*       [[!wikipedia Generator_(computer_science)]]
*       [[!wikipedia Fiber_(computer_science)]]
<!-- *  [[!wikipedia Green_threads]]
*       [[!wikipedia Protothreads]] -->

The way we built cooperative threads here crucially relied on two heavyweight tools. First, it relied on our having a data structure (the tree zipper) capable of being a static snapshot of where we left off in the tree whose fringe we're enumerating. Second, it relied on our using mutable reference cells so that we could update what the current snapshot (that is, tree zipper) was, so that the next invocation of the `next_leaf` function could start up again where the previous invocation left off.

It's possible to build cooperative threads without using those tools, however. Some languages have a native syntax for them. Here's how we'd write the same-fringe solution above using native coroutines in the language Lua:

        > function fringe_enumerator (tree)
            if tree.leaf then
                coroutine.yield (tree.leaf)
            else
                fringe_enumerator (tree.left)
                fringe_enumerator (tree.right)
            end
        end
        
        > function same_fringe (tree1, tree2)
            local next1 = coroutine.wrap (fringe_enumerator)
            local next2 = coroutine.wrap (fringe_enumerator)
            local function loop (leaf1, leaf2)
                if leaf1 or leaf2 then
                    return leaf1 == leaf2 and loop( next1(), next2() )
                elseif not leaf1 and not leaf2 then
                    return true
                else
                    return false
                end
            end
            return loop (next1(tree1), next2(tree2))
        end
        
        > return same_fringe ( {leaf=1}, {leaf=2})
        false
        
        > return same_fringe ( {leaf=1}, {leaf=1})
        true
        
        > return same_fringe ( {left = {leaf=1}, right = {left = {leaf=2}, right = {leaf=3}}},
            {left = {left = {leaf=1}, right = {leaf=2}}, right = {leaf=3}} )
        true

We're going to think about the underlying principles to this execution pattern, and instead learn how to implement it from scratch---without necessarily having zippers to rely on.


##Exceptions and Aborts##

To get a better understanding of how that execution patter works, we'll add yet a second execution pattern to our plate, and then think about what they have in common.

While writing OCaml code, you've probably come across errors. In fact, you've probably come across errors of two sorts. One sort of error comes about when you've got syntax errors or type errors and the OCaml interpreter isn't even able to understand your code:

        # let lst = [1; 2] in
          "a" :: lst;;
        Error: This expression has type int list
                   but an expression was expected of type string list

But you may also have encountered other kinds of error, that arise while your program is running. For example:

        # 1/0;;
        Exception: Division_by_zero.
        # List.nth [1;2] 10;;
        Exception: Failure "nth".

These "Exceptions" are **run-time errors**. OCaml will automatically detect some of them, like when you attempt to divide by zero. Other exceptions are *raised* by code. For instance, here is the implementation of `List.nth`:

        let nth l n =
          if n < 0 then invalid_arg "List.nth" else
          let rec nth_aux l n =
                match l with
                | [] -> failwith "nth"
                | a::l -> if n = 0 then a else nth_aux l (n-1)
          in nth_aux l n

Notice the two clauses `invalid_arg "List.nth"` and `failwith "nth"`. These are two helper functions which are shorthand for:

        raise (Invalid_argument "List.nth");;
        raise (Failure "nth");;

where `Invalid_argument "List.nth"` is a value of type `exn`, and so too `Failure "nth"`. When you have some value `ex` of type `exn` and evaluate the expression:

        raise ex

the effect is for the program to immediately stop without evaluating any further code:

        # let xcell = ref 0;;
        val xcell : int ref = {contents = 0}
        # let ex = Failure "test"
          in let _ = raise ex
          in xcell := 1;;
        Exception: Failure "test".
        # !xcell;;
        - : int = 0

Notice that the line `xcell := 1` was never evaluated, so the contents of `xcell` are still `0`.

I said when you evaluate the expression:

        raise ex

the effect is for the program to immediately stop. That's not exactly true. You can also programmatically arrange to *catch* errors, without the program necessarily stopping. In OCaml we do that with a `try ... with PATTERN -> ...` construct, analogous to the `match ... with PATTERN -> ...` construct:

        # let foo x =
            try
                if x = 1 then 10
                else if x = 2 then raise (Failure "two")
                else raise (Failure "three")
            with Failure "two" -> 20
            ;;
        val foo : int -> int = <fun>
        # foo 1;;
        - : int = 10
        # foo 2;;
        - : int = 20
        # foo 3;;
        Exception: Failure "three".

Notice what happens here. If we call `foo 1`, then the code between `try` and `with` evaluates to `10`, with no exceptions being raised. That then is what the entire `try ... with ...` block evaluates to; and so too what `foo 1` evaluates to. If we call `foo 2`, then the code between `try` and `with` raises an exception `Failure "two"`. The pattern in the `with` clause matches that exception, so we get instead `20`. If we call `foo 3`, we again raise an exception. This exception isn't matched by the `with` block, so it percolates up to the top of the program, and then the program immediately stops.

So what I should have said is that when you evaluate the expression:

        raise ex

*and that exception is never caught*, then the effect is for the program to immediately stop.

Of course, it's possible to handle errors in other ways too. There's no reason why the implementation of `List.nth` *had* to do things this way. They might instead have returned `Some a` when the list had an nth member `a`, and `None` when it does not. But it's pedagogically useful for us to think about this pattern now.

When an exception is raised, it percolates up through the code that called it, until it finds a surrounding `try ... with ...` that matches it. That might not be the first `try ... with ...` that it encounters. For example:

        # try
            try
                raise (Failure "blah")
            with Failure "fooey" -> 10
          with Failure "blah" -> 20;;
        - : int = 20

The matching `try ... with ...` block need not *lexically surround* the site where the error was raised:

        # let foo b x =
            try
                b x
            with Failure "blah" -> 20
        in let bar x =
            raise (Failure "blah")
        in foo bar 0;;
        - : int = 20

Here we call `foo bar 0`, and `foo` in turn calls `bar 0`, and `bar` raises the exception. Since there's no matching `try ... with ...` block in `bar`, we percolate back up the history of *who called this function?* and find a matching `try ... with ...` block in `foo`. This catches the error and so then the `try ... with ...` block in `foo` that called `bar` in the first place will evaluate to `20`.

OK, now this exception-handling apparatus does exemplify the second execution pattern we want to focus on. But it may bring it into clearer focus if we simplify the pattern even more. Imagine we could write code like this instead:

        # let foo x =
            try
                (if x = 1 then 10
                else abort 20) + 1
            end
            ;;

then if we called `foo 1`, we'd get the result `11`. If we called `foo 2`, on the other hand, we'd get `20` (note, not `21`). This exemplifies the same interesting "jump out of this part of the code" behavior that the `try ... raise ... with ...` code does, but without the details of matching which exception was raised, and handling the exception to produce a new result.

Many programming languages have this simplified exceution pattern, either instead of or alongside a `try ... with ...`-like pattern. In Lua and many other languages, `abort` is instead called `return`. The preceding example would be written:

        > function foo(x)
            local value
            if (x == 1) then
                value = 10
            else
                return 20
            end
            return value + 1
        end
        
        > return foo(1)
        11
        
        > return foo(2)
        20

Okay, so that's our second execution pattern.

##What do these have in common?##

In both of these patterns, we need to have some way to take a snapshot of where we are in the evaluation of a complex piece of code, so that we might later resume execution at that point. In the coroutine example, the two threads need to have a snapshot of where they were in the enumeration of their tree's leaves. In the abort example, we need to have a snapshot of where to pick up again if some embedded piece of code aborts. Sometimes we might distill that snapshot into a datastructure like a zipper. But we might not always know how to do so; and learning how to think about these snapshots without the help of zippers will help us see patterns and similarities we might otherwise miss.

A more general way to think about these snapshots is to think of the code we're taking a snapshot of as a *function.* For example, in this code:

        let foo x =
            try
                (if x = 1 then 10
                else abort 20) + 1
            end
        in (foo 2) + 1;;

we can imagine a box:

        let foo x =
        +---------------------------+
        |   try                     |
        |       (if x = 1 then 10   |
        |       else abort 20) + 1  |
        |   end                     |
        +---------------------------+
        in (foo 2) + 1;;

and as we're about to enter the box, we want to take a snapshot of the code *outside* the box. If we decide to abort, we'd be aborting to that snapshotted code.

<!--
# #require "delimcc";;
# open Delimcc;;
# let reset body = let p = new_prompt () in push_prompt p (body p);;
val reset : ('a Delimcc.prompt -> unit -> 'a) -> 'a = <fun>
# let foo x = reset(fun p () -> (shift p (fun k -> if x = 1 then k 10 else 20)) + 1) in (foo 1) + 100;;
- : int = 111
# let foo x = reset(fun p () -> (shift p (fun k -> if x = 1 then k 10 else 20)) + 1) in (foo 2) + 100;;
- : int = 120
-->




--------------------------------------

In coming weeks, we'll learn about a different way to create threads, that relies on **continuations** rather than on those two tools. All of these tools are inter-related. As Oleg says, "Zipper can be viewed as a delimited continuation reified as a data structure." These different tools are also inter-related with monads. Many of these tools can be used to define the others. We'll explore some of the connections between them in the remaining weeks, but we encourage you to explore more.


##Introducing Continuations##

A continuation is "the rest of the program." Or better: an **delimited continuation** is "the rest of the program, up to a certain boundary." An **undelimited continuation** is "the rest of the program, period."

Even if you haven't read specifically about this notion (for example, even if you haven't read Chris and Ken's work on using continuations in natural language semantics), you'll have brushed shoulders with it already several times in this course.

A naive semantics for atomic sentences will say the subject term is of type `e`, and the predicate of type `e -> t`, and that the subject provides an argument to the function expressed by the predicate.

Monatague proposed we instead take subject terms to be of type `(e -> t) -> t`, and that now it'd be the predicate (still of type `e -> t`) that provides an argument to the function expressed by the subject.

If all the subject did then was supply an `e` to the `e -> t` it receives as an argument, we wouldn't have gained anything we weren't already able to do. But of course, there are other things the subject can do with the `e -> t` it receives as an argument. For instance, it can check whether anything in the domain satisfies that `e -> t`; or whether most things do; and so on.

This inversion of who is the argument and who is the function receiving the argument is paradigmatic of working with continuations. We did the same thing ourselves back in the early days of the seminar, for example in our implementation of pairs. In the untyped lambda calculus, we identified the pair `(x, y)` with a function:

        \handler. handler x y

A pair-handling function would accept the two elements of a pair as arguments, and then do something with one or both of them. The important point here is that the handler was supplied as an argument to the pair. Eventually, the handler would itself be supplied with arguments. But only after it was supplied as an argument to the pair. This inverts the order you'd expect about what is the data or argument, and what is the function that operates on it.

Consider a complex computation, such as:

        1 + 2 * (1 - g (3 + 4))

Part of this computation---`3 + 4`---leads up to supplying `g` with an argument. The rest of the computation---`1 + 2 * (1 - ___)`---waits for the result of applying `g` to that argument and will go on to do something with it (inserting the result into the `___` slot). That "rest of the computation" can be regarded as a function:

        \result. 1 + 2 * (1 - result)

This function will be applied to whatever is the result of `g (3 + 4)`. So this function can be called the *continuation* of that application of `g`. For some purposes, it's useful to be able to invert the function/argument order here, and rather than supplying the result of applying `g` to the continuation, we instead supply the continuation to `g`. Well, not to `g` itself, since `g` only wants a single `int` argument. But we might build some `g`-like function which accepts not just an `int` argument like `g` does, but also a continuation argument.

Go back and read the material on "Aborting a Search Through a List" in [[Week4]] for an example of doing this.

In very general terms, the strategy is to work with functions like this:

        let g' k (i : int) =
                ... do stuff ...
                ... if you want to abort early, supply an argument to k ...
                ... do more stuff ...
                ... normal result
        in let gcon = fun result -> 1 + 2 * (1 - result)
        in gcon (g' gcon (3 + 4))

It's a convention to use variables like `k` for continuation arguments. If the function `g'` never supplies an argument to its contination argument `k`, but instead just finishes evaluating to a normal result, that normal result will be delivered to `g'`'s continuation `gcon`, just as happens when we don't pass around any explicit continuation variables.

The above snippet of OCaml code doesn't really capture what happens when we pass explicit continuation variables. For suppose that inside `g'`, we do supply an argument to `k`. That would go into the `result` parameter in `gcon`. But then what happens once we've finished evaluating the application of `gcon` to that `result`? In the OCaml snippet above, the final value would then bubble up through the context in the body of `g'` where `k` was applied, and eventually out to the final line of the snippet, where it once again supplied an argument to `gcon`. That's not what happens with a real continuation. A real continuation works more like this:

        let g' k (i : int) =
                ... do stuff ...
                ... if you want to abort early, supply an argument to k ...
                ... do more stuff ...
                ... normal result
        in let gcon = fun result ->
                let final_value = 1 + 2 * (1 - result)
                in end_program_with final_value
        in gcon (g' gcon (3 + 4))

So once we've finished evaluating the application of `gcon` to a `result`, the program is finished. (This is how undelimited continuations behave. We'll discuss delimited continuations later.)

So now, guess what would be the result of doing the following:

        let g' k (i : int) =
                1 + k i
        in let gcon = fun result ->
                let final_value = (1, result)
                in end_program_with final_value
        in gcon (g' gcon (3 + 4))

<!-- (1, 7) ... explain why not (1, 8) -->


Refunctionalizing zippers: from lists to continuations
------------------------------------------------------

If zippers are continuations reified (defuntionalized), then one route
to continuations is to re-functionalize a zipper.  Then the
concreteness and understandability of the zipper provides a way of
understanding and equivalent treatment using continuations.

Let's work with lists of chars for a change.  To maximize readability, we'll
indulge in an abbreviatory convention that "abSd" abbreviates the
list `['a'; 'b'; 'S'; 'd']`.

We will set out to compute a deceptively simple-seeming **task: given a
string, replace each occurrence of 'S' in that string with a copy of
the string up to that point.**

We'll define a function `t` (for "task") that maps strings to their
updated version.

Expected behavior:

<pre>
t "abSd" ~~> "ababd"
</pre>   


In linguistic terms, this is a kind of anaphora
resolution, where `'S'` is functioning like an anaphoric element, and
the preceding string portion is the antecedent.

This deceptively simple task gives rise to some mind-bending complexity.
Note that it matters which 'S' you target first (the position of the *
indicates the targeted 'S'):

<pre>
    t "aSbS" 
        *
~~> t "aabS" 
          *
~~> "aabaab"
</pre>

versus

<pre>
    t "aSbS"
          *
~~> t "aSbaSb" 
        *
~~> t "aabaSb"
           *
~~> "aabaaabab"
</pre>   

versus

<pre>
    t "aSbS"
          *
~~> t "aSbaSb"
           *
~~> t "aSbaaSbab"
            *
~~> t "aSbaaaSbaabab"
             *
~~> ...
</pre>

Aparently, this task, as simple as it is, is a form of computation,
and the order in which the `'S'`s get evaluated can lead to divergent
behavior.

For now, we'll agree to always evaluate the leftmost `'S'`, which
guarantees termination, and a final string without any `'S'` in it.

This is a task well-suited to using a zipper.  We'll define a function
`tz` (for task with zippers), which accomplishes the task by mapping a
char list zipper to a char list.  We'll call the two parts of the
zipper `unzipped` and `zipped`; we start with a fully zipped list, and
move elements to the zipped part by pulling the zipped down until the
entire list has been unzipped (and so the zipped half of the zipper is empty).

<pre>
type 'a list_zipper = ('a list) * ('a list);;

let rec tz (z:char list_zipper) = 
    match z with (unzipped, []) -> List.rev(unzipped) (* Done! *)
               | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped) 
               | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)

# tz ([], ['a'; 'b'; 'S'; 'd']);;
- : char list = ['a'; 'b'; 'a'; 'b'; 'd']

# tz ([], ['a'; 'S'; 'b'; 'S']);;
- : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
</pre>

Note that this implementation enforces the evaluate-leftmost rule.
Task completed.

One way to see exactly what is going on is to watch the zipper in
action by tracing the execution of `tz`.  By using the `#trace`
directive in the Ocaml interpreter, the system will print out the
arguments to `tz` each time it is (recurcively) called.  Note that the
lines with left-facing arrows (`<--`) show (recursive) calls to `tz`,
giving the value of its argument (a zipper), and the lines with
right-facing arrows (`-->`) show the output of each recursive call, a
simple list.  

<pre>
# #trace tz;;
t1 is now traced.
# tz ([], ['a'; 'b'; 'S'; 'd']);;
tz <-- ([], ['a'; 'b'; 'S'; 'd'])
tz <-- (['a'], ['b'; 'S'; 'd'])         (* Pull zipper *)
tz <-- (['b'; 'a'], ['S'; 'd'])         (* Pull zipper *)
tz <-- (['b'; 'a'; 'b'; 'a'], ['d'])    (* Special step *)
tz <-- (['d'; 'b'; 'a'; 'b'; 'a'], [])  (* Pull zipper *)
tz --> ['a'; 'b'; 'a'; 'b'; 'd']        (* Output reversed *)
tz --> ['a'; 'b'; 'a'; 'b'; 'd']
tz --> ['a'; 'b'; 'a'; 'b'; 'd']
tz --> ['a'; 'b'; 'a'; 'b'; 'd']
tz --> ['a'; 'b'; 'a'; 'b'; 'd']
- : char list = ['a'; 'b'; 'a'; 'b'; 'd'] 
</pre>

The nice thing about computations involving lists is that it's so easy
to visualize them as a data structure.  Eventually, we want to get to
a place where we can talk about more abstract computations.  In order
to get there, we'll first do the exact same thing we just did with
concrete zipper using procedures.  

Think of a list as a procedural recipe: `['a'; 'b'; 'S'; 'd']` 
is the result of the computation `a::(b::(S::(d::[])))` (or, in our old
style, `makelist a (makelist b (makelist S (makelist c empty)))`).
The recipe for constructing the list goes like this:

<pre>
(0)  Start with the empty list []
(1)  make a new list whose first element is 'd' and whose tail is the list constructed in step (0)
(2)  make a new list whose first element is 'S' and whose tail is the list constructed in step (1)
-----------------------------------------
(3)  make a new list whose first element is 'b' and whose tail is the list constructed in step (2)
(4)  make a new list whose first element is 'a' and whose tail is the list constructed in step (3)
</pre>

What is the type of each of these steps?  Well, it will be a function
from the result of the previous step (a list) to a new list: it will
be a function of type `char list -> char list`.  We'll call each step
(or group of steps) a **continuation** of the recipe.  So in this
context, a continuation is a function of type `char list -> char
list`.  For instance, the continuation corresponding to the portion of
the recipe below the horizontal line is the function `fun (tail:char
list) -> a::(b::tail)`.

This means that we can now represent the unzipped part of our
zipper--the part we've already unzipped--as a continuation: a function
describing how to finish building the list.  We'll write a new
function, `tc` (for task with continuations), that will take an input
list (not a zipper!) and a continuation and return a processed list.
The structure and the behavior will follow that of `tz` above, with
some small but interesting differences.  We've included the orginal
`tz` to facilitate detailed comparison:

<pre>
let rec tz (z:char list_zipper) = 
    match z with (unzipped, []) -> List.rev(unzipped) (* Done! *)
               | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped) 
               | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)

let rec tc (l: char list) (c: (char list) -> (char list)) =
  match l with [] -> List.rev (c [])
             | 'S'::zipped -> tc zipped (fun x -> c (c x))
             | target::zipped -> tc zipped (fun x -> target::(c x));;

# tc ['a'; 'b'; 'S'; 'd'] (fun x -> x);;
- : char list = ['a'; 'b'; 'a'; 'b']

# tc ['a'; 'S'; 'b'; 'S'] (fun x -> x);;
- : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
</pre>

To emphasize the parallel, I've re-used the names `zipped` and
`target`.  The trace of the procedure will show that these variables
take on the same values in the same series of steps as they did during
the execution of `tz` above.  There will once again be one initial and
four recursive calls to `tc`, and `zipped` will take on the values
`"bSd"`, `"Sd"`, `"d"`, and `""` (and, once again, on the final call,
the first `match` clause will fire, so the the variable `zipper` will
not be instantiated).

I have not called the functional argument `unzipped`, although that is
what the parallel would suggest.  The reason is that `unzipped` is a
list, but `c` is a function.  That's the most crucial difference, the
point of the excercise, and it should be emphasized.  For instance,
you can see this difference in the fact that in `tz`, we have to glue
together the two instances of `unzipped` with an explicit (and
relatively inefficient) `List.append`.
In the `tc` version of the task, we simply compose `c` with itself: 
`c o c = fun x -> c (c x)`.

Why use the identity function as the initial continuation?  Well, if
you have already constructed the initial list `"abSd"`, what's the next
step in the recipe to produce the desired result, i.e, the very same
list, `"abSd"`?  Clearly, the identity continuation.

A good way to test your understanding is to figure out what the
continuation function `c` must be at the point in the computation when
`tc` is called with the first argument `"Sd"`.  Two choices: is it
`fun x -> a::b::x`, or it is `fun x -> b::a::x`?  The way to see if
you're right is to execute the following command and see what happens:

    tc ['S'; 'd'] (fun x -> 'a'::'b'::x);;

There are a number of interesting directions we can go with this task.
The reason this task was chosen is because it can be viewed as a
simplified picture of a computation using continuations, where `'S'`
plays the role of a control operator with some similarities to what is
often called `shift`.  In the analogy, the input list portrays a
sequence of functional applications, where `[f1; f2; f3; x]` represents
`f1(f2(f3 x))`.  The limitation of the analogy is that it is only
possible to represent computations in which the applications are
always right-branching, i.e., the computation `((f1 f2) f3) x` cannot
be directly represented.

One possibile development is that we could add a special symbol `'#'`,
and then the task would be to copy from the target `'S'` only back to
the closest `'#'`.  This would allow the task to simulate delimited
continuations with embedded prompts.

The reason the task is well-suited to the list zipper is in part
because the list monad has an intimate connection with continuations.
The following section explores this connection.  We'll return to the
list task after talking about generalized quantifiers below.


Rethinking the list monad
-------------------------

To construct a monad, the key element is to settle on a type
constructor, and the monad more or less naturally follows from that.
We'll remind you of some examples of how monads follow from the type
constructor in a moment.  This will involve some review of familair
material, but it's worth doing for two reasons: it will set up a
pattern for the new discussion further below, and it will tie together
some previously unconnected elements of the course (more specifically,
version 3 lists and monads).

For instance, take the **Reader Monad**.  Once we decide that the type
constructor is

    type 'a reader = env -> 'a

then the choice of unit and bind is natural:

    let r_unit (a : 'a) : 'a reader = fun (e : env) -> a

The reason this is a fairly natural choice is that because the type of
an `'a reader` is `env -> 'a` (by definition), the type of the
`r_unit` function is `'a -> env -> 'a`, which is an instance of the
type of the *K* combinator.  So it makes sense that *K* is the unit
for the reader monad.

Since the type of the `bind` operator is required to be

    r_bind : ('a reader) -> ('a -> 'b reader) -> ('b reader)

We can reason our way to the traditional reader `bind` function as
follows. We start by declaring the types determined by the definition
of a bind operation:

    let r_bind (u : 'a reader) (f : 'a -> 'b reader) : ('b reader) = ...

Now we have to open up the `u` box and get out the `'a` object in order to
feed it to `f`.  Since `u` is a function from environments to
objects of type `'a`, the way we open a box in this monad is
by applying it to an environment:

<pre>
        ... f (u e) ...
</pre>

This subexpression types to `'b reader`, which is good.  The only
problem is that we made use of an environment `e` that we didn't already have,
so we must abstract over that variable to balance the books:

        fun e -> f (u e) ...

[To preview the discussion of the Curry-Howard correspondence, what
we're doing here is constructing an intuitionistic proof of the type,
and using the Curry-Howard labeling of the proof as our bind term.]

This types to `env -> 'b reader`, but we want to end up with `env ->
'b`.  Once again, the easiest way to turn a `'b reader` into a `'b` is to apply it to an environment.  So we end up as follows:

<pre>
r_bind (u : 'a reader) (f : 'a -> 'b reader) : ('b reader) = f (u e) e         
</pre>

And we're done. This gives us a bind function of the right type. We can then check whether, in combination with the unit function we chose, it satisfies the monad laws, and behaves in the way we intend. And it does.

[The bind we cite here is a condensed version of the careful `let a = u e in ...`
constructions we provided in earlier lectures.  We use the condensed
version here in order to emphasize similarities of structure across
monads.]

The **State Monad** is similar.  Once we've decided to use the following type constructor:

    type 'a state = store -> ('a, store)

Then our unit is naturally:

    let s_unit (a : 'a) : ('a state) = fun (s : store) -> (a, s)

And we can reason our way to the bind function in a way similar to the reasoning given above. First, we need to apply `f` to the contents of the `u` box:

    let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state = 
                ... f (...) ...

But unlocking the `u` box is a little more complicated.  As before, we
need to posit a state `s` that we can apply `u` to.  Once we do so,
however, we won't have an `'a`, we'll have a pair whose first element
is an `'a`.  So we have to unpack the pair:

        ... let (a, s') = u s in ... (f a) ...

Abstracting over the `s` and adjusting the types gives the result:

        let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state = 
                fun (s : store) -> let (a, s') = u s in f a s'

The **Option/Maybe Monad** doesn't follow the same pattern so closely, so we
won't pause to explore it here, though conceptually its unit and bind
follow just as naturally from its type constructor.

Our other familiar monad is the **List Monad**, which we were told
looks like this:

    type 'a list = ['a];;
    l_unit (a : 'a) = [a];;
    l_bind u f = List.concat (List.map f u);;

Thinking through the list monad will take a little time, but doing so
will provide a connection with continuations.

Recall that `List.map` takes a function and a list and returns the
result to applying the function to the elements of the list:

    List.map (fun i -> [i;i+1]) [1;2] ~~> [[1; 2]; [2; 3]]

and List.concat takes a list of lists and erases the embdded list
boundaries:

    List.concat [[1; 2]; [2; 3]] ~~> [1; 2; 2; 3]

And sure enough, 

    l_bind [1;2] (fun i -> [i, i+1]) ~~> [1; 2; 2; 3]

Now, why this unit, and why this bind?  Well, ideally a unit should
not throw away information, so we can rule out `fun x -> []` as an
ideal unit.  And units should not add more information than required,
so there's no obvious reason to prefer `fun x -> [x,x]`.  In other
words, `fun x -> [x]` is a reasonable choice for a unit.

As for bind, an `'a list` monadic object contains a lot of objects of
type `'a`, and we want to make use of each of them (rather than
arbitrarily throwing some of them away).  The only
thing we know for sure we can do with an object of type `'a` is apply
the function of type `'a -> 'a list` to them.  Once we've done so, we
have a collection of lists, one for each of the `'a`'s.  One
possibility is that we could gather them all up in a list, so that
`bind' [1;2] (fun i -> [i;i]) ~~> [[1;1];[2;2]]`.  But that restricts
the object returned by the second argument of `bind` to always be of
type `'b list list`.  We can elimiate that restriction by flattening
the list of lists into a single list: this is
just List.concat applied to the output of List.map.  So there is some logic to the
choice of unit and bind for the list monad.  

Yet we can still desire to go deeper, and see if the appropriate bind
behavior emerges from the types, as it did for the previously
considered monads.  But we can't do that if we leave the list type as
a primitive Ocaml type.  However, we know several ways of implementing
lists using just functions.  In what follows, we're going to use type
3 lists, the right fold implementation (though it's important and
intriguing to wonder how things would change if we used some other
strategy for implementating lists).  These were the lists that made
lists look like Church numerals with extra bits embdded in them:

    empty list:                fun f z -> z
    list with one element:     fun f z -> f 1 z
    list with two elements:    fun f z -> f 2 (f 1 z)
    list with three elements:  fun f z -> f 3 (f 2 (f 1 z))

and so on.  To save time, we'll let the OCaml interpreter infer the
principle types of these functions (rather than inferring what the
types should be ourselves):

        # fun f z -> z;;
        - : 'a -> 'b -> 'b = <fun>
        # fun f z -> f 1 z;;
        - : (int -> 'a -> 'b) -> 'a -> 'b = <fun>
        # fun f z -> f 2 (f 1 z);;
        - : (int -> 'a -> 'a) -> 'a -> 'a = <fun>
        # fun f z -> f 3 (f 2 (f 1 z))
        - : (int -> 'a -> 'a) -> 'a -> 'a = <fun>

We can see what the consistent, general principle types are at the end, so we
can stop. These types should remind you of the simply-typed lambda calculus
types for Church numerals (`(o -> o) -> o -> o`) with one extra type
thrown in, the type of the element a the head of the list
(in this case, an int).

So here's our type constructor for our hand-rolled lists:

    type 'b list' = (int -> 'b -> 'b) -> 'b -> 'b

Generalizing to lists that contain any kind of element (not just
ints), we have

    type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b

So an `('a, 'b) list'` is a list containing elements of type `'a`,
where `'b` is the type of some part of the plumbing.  This is more
general than an ordinary OCaml list, but we'll see how to map them
into OCaml lists soon.  We don't need to fully grasp the role of the `'b`'s
in order to proceed to build a monad:

    l'_unit (a : 'a) : ('a, 'b) list = fun a -> fun f z -> f a z

No problem.  Arriving at bind is a little more complicated, but
exactly the same principles apply, you just have to be careful and
systematic about it.

    l'_bind (u : ('a,'b) list') (f : 'a -> ('c, 'd) list') : ('c, 'd) list'  = ...

Unpacking the types gives:

    l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
            (f : 'a -> ('c -> 'd -> 'd) -> 'd -> 'd)
            : ('c -> 'd -> 'd) -> 'd -> 'd = ...

Perhaps a bit intimiating.
But it's a rookie mistake to quail before complicated types. You should
be no more intimiated by complex types than by a linguistic tree with
deeply embedded branches: complex structure created by repeated
application of simple rules.

[This would be a good time to try to build your own term for the types
just given.  Doing so (or attempting to do so) will make the next
paragraph much easier to follow.]

As usual, we need to unpack the `u` box.  Examine the type of `u`.
This time, `u` will only deliver up its contents if we give `u` an
argument that is a function expecting an `'a` and a `'b`. `u` will 
fold that function over its type `'a` members, and that's how we'll get the `'a`s we need. Thus:

        ... u (fun (a : 'a) (b : 'b) -> ... f a ... ) ...

In order for `u` to have the kind of argument it needs, the `... (f a) ...` has to evaluate to a result of type `'b`. The easiest way to do this is to collapse (or "unify") the types `'b` and `'d`, with the result that `f a` will have type `('c -> 'b -> 'b) -> 'b -> 'b`. Let's postulate an argument `k` of type `('c -> 'b -> 'b)` and supply it to `(f a)`:

        ... u (fun (a : 'a) (b : 'b) -> ... f a k ... ) ...

Now we have an argument `b` of type `'b`, so we can supply that to `(f a) k`, getting a result of type `'b`, as we need:

        ... u (fun (a : 'a) (b : 'b) -> f a k b) ...

Now, we've used a `k` that we pulled out of nowhere, so we need to abstract over it:

        fun (k : 'c -> 'b -> 'b) -> u (fun (a : 'a) (b : 'b) -> f a k b)

This whole expression has type `('c -> 'b -> 'b) -> 'b -> 'b`, which is exactly the type of a `('c, 'b) list'`. So we can hypothesize that our bind is:

    l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
            (f : 'a -> ('c -> 'b -> 'b) -> 'b -> 'b)
            : ('c -> 'b -> 'b) -> 'b -> 'b = 
      fun k -> u (fun a b -> f a k b)

That is a function of the right type for our bind, but to check whether it works, we have to verify it (with the unit we chose) against the monad laws, and reason whether it will have the right behavior.

Here's a way to persuade yourself that it will have the right behavior. First, it will be handy to eta-expand our `fun k -> u (fun a b -> f a k b)` to:

      fun k z -> u (fun a b -> f a k b) z

Now let's think about what this does. It's a wrapper around `u`. In order to behave as the list which is the result of mapping `f` over each element of `u`, and then joining (`concat`ing) the results, this wrapper would have to accept arguments `k` and `z` and fold them in just the same way that the list which is the result of mapping `f` and then joining the results would fold them. Will it?

Suppose we have a list' whose contents are `[1; 2; 4; 8]`---that is, our list' will be `fun f z -> f 1 (f 2 (f 4 (f 8 z)))`. We call that list' `u`. Suppose we also have a function `f` that for each `int` we give it, gives back a list of the divisors of that `int` that are greater than 1. Intuitively, then, binding `u` to `f` should give us:

        concat (map f u) =
        concat [[]; [2]; [2; 4]; [2; 4; 8]] =
        [2; 2; 4; 2; 4; 8]

Or rather, it should give us a list' version of that, which takes a function `k` and value `z` as arguments, and returns the right fold of `k` and `z` over those elements. What does our formula

      fun k z -> u (fun a b -> f a k b) z
        
do? Well, for each element `a` in `u`, it applies `f` to that `a`, getting one of the lists:

        []
        [2]
        [2; 4]
        [2; 4; 8]

(or rather, their list' versions). Then it takes the accumulated result `b` of previous steps in the fold, and it folds `k` and `b` over the list generated by `f a`. The result of doing so is passed on to the next step as the accumulated result so far.

So if, for example, we let `k` be `+` and `z` be `0`, then the computation would proceed:

        0 ==>
        right-fold + and 0 over [2; 4; 8] = 2+4+8+0 ==>
        right-fold + and 2+4+8+0 over [2; 4] = 2+4+2+4+8+0 ==>
        right-fold + and 2+4+2+4+8+0 over [2] = 2+2+4+2+4+8+0 ==>
        right-fold + and 2+2+4+2+4+8+0 over [] = 2+2+4+2+4+8+0

which indeed is the result of right-folding + and 0 over `[2; 2; 4; 2; 4; 8]`. If you trace through how this works, you should be able to persuade yourself that our formula:

      fun k z -> u (fun a b -> f a k b) z

will deliver just the same folds, for arbitrary choices of `k` and `z` (with the right types), and arbitrary list's `u` and appropriately-typed `f`s, as

        fun k z -> List.fold_right k (concat (map f u)) z

would.

For future reference, we might make two eta-reductions to our formula, so that we have instead:

      let l'_bind = fun k -> u (fun a -> f a k);;

Let's make some more tests:


    l_bind [1;2] (fun i -> [i, i+1]) ~~> [1; 2; 2; 3]

    l'_bind (fun f z -> f 1 (f 2 z)) 
            (fun i -> fun f z -> f i (f (i+1) z)) ~~> <fun>

Sigh.  OCaml won't show us our own list.  So we have to choose an `f`
and a `z` that will turn our hand-crafted lists into standard OCaml
lists, so that they will print out.

        # let cons h t = h :: t;;  (* OCaml is stupid about :: *)
        # l'_bind (fun f z -> f 1 (f 2 z)) 
                          (fun i -> fun f z -> f i (f (i+1) z)) cons [];;
        - : int list = [1; 2; 2; 3]

Ta da!


Montague's PTQ treatment of DPs as generalized quantifiers
----------------------------------------------------------

We've hinted that Montague's treatment of DPs as generalized
quantifiers embodies the spirit of continuations (see de Groote 2001,
Barker 2002 for lengthy discussion).  Let's see why.  

First, we'll need a type constructor.  As you probably know, 
Montague replaced individual-denoting determiner phrases (with type `e`)
with generalized quantifiers (with [extensional] type `(e -> t) -> t`.
In particular, the denotation of a proper name like *John*, which
might originally denote a object `j` of type `e`, came to denote a
generalized quantifier `fun pred -> pred j` of type `(e -> t) -> t`.
Let's write a general function that will map individuals into their
corresponding generalized quantifier:

   gqize (a : e) = fun (p : e -> t) -> p a

This function is what Partee 1987 calls LIFT, and it would be
reasonable to use it here, but we will avoid that name, given that we
use that word to refer to other functions.

This function wraps up an individual in a box.  That is to say,
we are in the presence of a monad.  The type constructor, the unit and
the bind follow naturally.  We've done this enough times that we won't
belabor the construction of the bind function, the derivation is
highly similar to the List monad just given:

        type 'a continuation = ('a -> 'b) -> 'b
        c_unit (a : 'a) = fun (p : 'a -> 'b) -> p a
        c_bind (u : ('a -> 'b) -> 'b) (f : 'a -> ('c -> 'd) -> 'd) : ('c -> 'd) -> 'd =
          fun (k : 'a -> 'b) -> u (fun (a : 'a) -> f a k)

Note that `c_unit` is exactly the `gqize` function that Montague used
to lift individuals into the continuation monad.

That last bit in `c_bind` looks familiar---we just saw something like
it in the List monad.  How similar is it to the List monad?  Let's
examine the type constructor and the terms from the list monad derived
above:

    type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b
    l'_unit a = fun f -> f a                 
    l'_bind u f = fun k -> u (fun a -> f a k)

(We performed a sneaky but valid eta reduction in the unit term.)

The unit and the bind for the Montague continuation monad and the
homemade List monad are the same terms!  In other words, the behavior
of the List monad and the behavior of the continuations monad are
parallel in a deep sense.

Have we really discovered that lists are secretly continuations?  Or
have we merely found a way of simulating lists using list
continuations?  Well, strictly speaking, what we have done is shown
that one particular implementation of lists---the right fold
implementation---gives rise to a continuation monad fairly naturally,
and that this monad can reproduce the behavior of the standard list
monad.  But what about other list implementations?  Do they give rise
to monads that can be understood in terms of continuations?

Manipulating trees with monads
------------------------------

This topic develops an idea based on a detailed suggestion of Ken
Shan's.  We'll build a series of functions that operate on trees,
doing various things, including replacing leaves, counting nodes, and
converting a tree to a list of leaves.  The end result will be an
application for continuations.

From an engineering standpoint, we'll build a tree transformer that
deals in monads.  We can modify the behavior of the system by swapping
one monad for another.  We've already seen how adding a monad can add
a layer of funtionality without disturbing the underlying system, for
instance, in the way that the reader monad allowed us to add a layer
of intensionality to an extensional grammar, but we have not yet seen
the utility of replacing one monad with other.

First, we'll be needing a lot of trees during the remainder of the
course.  Here's a type constructor for binary trees:

    type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)

These are trees in which the internal nodes do not have labels.  [How
would you adjust the type constructor to allow for labels on the
internal nodes?]

We'll be using trees where the nodes are integers, e.g.,


<pre>
let t1 = Node ((Node ((Leaf 2), (Leaf 3))),
               (Node ((Leaf 5),(Node ((Leaf 7),
                                      (Leaf 11))))))

    .
 ___|___
 |     |
 .     .
_|__  _|__
|  |  |  |
2  3  5  .
        _|__
        |  |
        7  11
</pre>

Our first task will be to replace each leaf with its double:

<pre>
let rec treemap (newleaf:'a -> 'b) (t:'a tree):('b tree) =
  match t with Leaf x -> Leaf (newleaf x)
             | Node (l, r) -> Node ((treemap newleaf l),
                                    (treemap newleaf r));;
</pre>
`treemap` takes a function that transforms old leaves into new leaves, 
and maps that function over all the leaves in the tree, leaving the
structure of the tree unchanged.  For instance:

<pre>
let double i = i + i;;
treemap double t1;;
- : int tree =
Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))

    .
 ___|____
 |      |
 .      .
_|__  __|__
|  |  |   |
4  6  10  .
        __|___
        |    |
        14   22
</pre>

We could have built the doubling operation right into the `treemap`
code.  However, because what to do to each leaf is a parameter, we can
decide to do something else to the leaves without needing to rewrite
`treemap`.  For instance, we can easily square each leaf instead by
supplying the appropriate `int -> int` operation in place of `double`:

<pre>
let square x = x * x;;
treemap square t1;;
- : int tree =ppp
Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
</pre>

Note that what `treemap` does is take some global, contextual
information---what to do to each leaf---and supplies that information
to each subpart of the computation.  In other words, `treemap` has the
behavior of a reader monad.  Let's make that explicit.  

In general, we're on a journey of making our treemap function more and
more flexible.  So the next step---combining the tree transducer with
a reader monad---is to have the treemap function return a (monadized)
tree that is ready to accept any `int->int` function and produce the
updated tree.

\tree (. (. (f2) (f3))(. (f5) (.(f7)(f11))))
<pre>
\f    .
  ____|____
  |       |
  .       .
__|__   __|__
|   |   |   |
f2  f3  f5  .
          __|___
          |    |
          f7  f11
</pre>

That is, we want to transform the ordinary tree `t1` (of type `int
tree`) into a reader object of type `(int->int)-> int tree`: something 
that, when you apply it to an `int->int` function returns an `int
tree` in which each leaf `x` has been replaced with `(f x)`.

With previous readers, we always knew which kind of environment to
expect: either an assignment function (the original calculator
simulation), a world (the intensionality monad), an integer (the
Jacobson-inspired link monad), etc.  In this situation, it will be
enough for now to expect that our reader will expect a function of
type `int->int`.

<pre>
type 'a reader = (int->int) -> 'a;;  (* mnemonic: e for environment *)
let reader_unit (x:'a): 'a reader = fun _ -> x;;
let reader_bind (u: 'a reader) (f:'a -> 'c reader):'c reader = fun e -> f (u e) e;;
</pre>

It's easy to figure out how to turn an `int` into an `int reader`:

<pre>
let int2int_reader (x:'a): 'b reader = fun (op:'a -> 'b) -> op x;;
int2int_reader 2 (fun i -> i + i);;
- : int = 4
</pre>

But what do we do when the integers are scattered over the leaves of a
tree?  A binary tree is not the kind of thing that we can apply a
function of type `int->int` to.

<pre>
let rec treemonadizer (f:'a -> 'b reader) (t:'a tree):('b tree) reader =
  match t with Leaf x -> reader_bind (f x) (fun x' -> reader_unit (Leaf x'))
             | Node (l, r) -> reader_bind (treemonadizer f l) (fun x ->
                                reader_bind (treemonadizer f r) (fun y ->
                                  reader_unit (Node (x, y))));;
</pre>

This function says: give me a function `f` that knows how to turn
something of type `'a` into an `'b reader`, and I'll show you how to 
turn an `'a tree` into an `'a tree reader`.  In more fanciful terms, 
the `treemonadizer` function builds plumbing that connects all of the
leaves of a tree into one connected monadic network; it threads the
monad through the leaves.

<pre>
# treemonadizer int2int_reader t1 (fun i -> i + i);;
- : int tree =
Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
</pre>

Here, our environment is the doubling function (`fun i -> i + i`).  If
we apply the very same `int tree reader` (namely, `treemonadizer
int2int_reader t1`) to a different `int->int` function---say, the
squaring function, `fun i -> i * i`---we get an entirely different
result:

<pre>
# treemonadizer int2int_reader t1 (fun i -> i * i);;
- : int tree =
Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))
</pre>

Now that we have a tree transducer that accepts a monad as a
parameter, we can see what it would take to swap in a different monad.
For instance, we can use a state monad to count the number of nodes in
the tree.

<pre>
type 'a state = int -> 'a * int;;
let state_unit x i = (x, i+.5);;
let state_bind u f i = let (a, i') = u i in f a (i'+.5);;
</pre>

Gratifyingly, we can use the `treemonadizer` function without any
modification whatsoever, except for replacing the (parametric) type
`reader` with `state`:

<pre>
let rec treemonadizer (f:'a -> 'b state) (t:'a tree):('b tree) state =
  match t with Leaf x -> state_bind (f x) (fun x' -> state_unit (Leaf x'))
             | Node (l, r) -> state_bind (treemonadizer f l) (fun x ->
                                state_bind (treemonadizer f r) (fun y ->
                                  state_unit (Node (x, y))));;
</pre>

Then we can count the number of nodes in the tree:

<pre>
# treemonadizer state_unit t1 0;;
- : int tree * int =
(Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11))), 13)

    .
 ___|___
 |     |
 .     .
_|__  _|__
|  |  |  |
2  3  5  .
        _|__
        |  |
        7  11
</pre>

Notice that we've counted each internal node twice---it's a good
exercise to adjust the code to count each node once.

One more revealing example before getting down to business: replacing
`state` everywhere in `treemonadizer` with `list` gives us

<pre>
# treemonadizer (fun x -> [ [x; square x] ]) t1;;
- : int list tree list =
[Node
  (Node (Leaf [2; 4], Leaf [3; 9]),
   Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))]
</pre>

Unlike the previous cases, instead of turning a tree into a function
from some input to a result, this transformer replaces each `int` with
a list of `int`'s.

Now for the main point.  What if we wanted to convert a tree to a list
of leaves?  

<pre>
type ('a, 'r) continuation = ('a -> 'r) -> 'r;;
let continuation_unit x c = c x;;
let continuation_bind u f c = u (fun a -> f a c);;

let rec treemonadizer (f:'a -> ('b, 'r) continuation) (t:'a tree):(('b tree), 'r) continuation =
  match t with Leaf x -> continuation_bind (f x) (fun x' -> continuation_unit (Leaf x'))
             | Node (l, r) -> continuation_bind (treemonadizer f l) (fun x ->
                                continuation_bind (treemonadizer f r) (fun y ->
                                  continuation_unit (Node (x, y))));;
</pre>

We use the continuation monad described above, and insert the
`continuation` type in the appropriate place in the `treemonadizer` code.
We then compute:

<pre>
# treemonadizer (fun a c -> a :: (c a)) t1 (fun t -> []);;
- : int list = [2; 3; 5; 7; 11]
</pre>

We have found a way of collapsing a tree into a list of its leaves.

The continuation monad is amazingly flexible; we can use it to
simulate some of the computations performed above.  To see how, first
note that an interestingly uninteresting thing happens if we use the
continuation unit as our first argument to `treemonadizer`, and then
apply the result to the identity function:

<pre>
# treemonadizer continuation_unit t1 (fun x -> x);;
- : int tree =
Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))
</pre>

That is, nothing happens.  But we can begin to substitute more
interesting functions for the first argument of `treemonadizer`:

<pre>
(* Simulating the tree reader: distributing a operation over the leaves *)
# treemonadizer (fun a c -> c (square a)) t1 (fun x -> x);;
- : int tree =
Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))

(* Simulating the int list tree list *)
# treemonadizer (fun a c -> c [a; square a]) t1 (fun x -> x);;
- : int list tree =
Node
 (Node (Leaf [2; 4], Leaf [3; 9]),
  Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))

(* Counting leaves *)
# treemonadizer (fun a c -> 1 + c a) t1 (fun x -> 0);;
- : int = 5
</pre>

We could simulate the tree state example too, but it would require
generalizing the type of the continuation monad to 

    type ('a -> 'b -> 'c) continuation = ('a -> 'b) -> 'c;;

The binary tree monad
---------------------

Of course, by now you may have realized that we have discovered a new
monad, the binary tree monad:

<pre>
type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
let tree_unit (x:'a) = Leaf x;;
let rec tree_bind (u:'a tree) (f:'a -> 'b tree):'b tree = 
  match u with Leaf x -> f x 
             | Node (l, r) -> Node ((tree_bind l f), (tree_bind r f));;
</pre>

For once, let's check the Monad laws.  The left identity law is easy:

    Left identity: bind (unit a) f = bind (Leaf a) f = fa

To check the other two laws, we need to make the following
observation: it is easy to prove based on `tree_bind` by a simple
induction on the structure of the first argument that the tree
resulting from `bind u f` is a tree with the same strucure as `u`,
except that each leaf `a` has been replaced with `fa`:

\tree (. (fa1) (. (. (. (fa2)(fa3)) (fa4)) (fa5)))
<pre>
                .                         .       
              __|__                     __|__   
              |   |                     |   |   
              a1  .                    fa1  .   
                 _|__                     __|__ 
                 |  |                     |   | 
                 .  a5                    .  fa5
   bind         _|__       f   =        __|__   
                |  |                    |   |   
                .  a4                   .  fa4  
              __|__                   __|___   
              |   |                   |    |   
              a2  a3                 fa2  fa3         
</pre>   

Given this equivalence, the right identity law

    Right identity: bind u unit = u

falls out once we realize that

    bind (Leaf a) unit = unit a = Leaf a

As for the associative law,

    Associativity: bind (bind u f) g = bind u (\a. bind (fa) g)

we'll give an example that will show how an inductive proof would
proceed.  Let `f a = Node (Leaf a, Leaf a)`.  Then

\tree (. (. (. (. (a1)(a2)))))
\tree (. (. (. (. (a1) (a1)) (. (a1) (a1)))  ))
<pre>
                                           .
                                       ____|____
          .               .            |       |
bind    __|__   f  =    __|_    =      .       .
        |   |           |   |        __|__   __|__
        a1  a2         fa1 fa2       |   |   |   |
                                     a1  a1  a1  a1  
</pre>

Now when we bind this tree to `g`, we get

<pre>
           .
       ____|____
       |       |
       .       .
     __|__   __|__
     |   |   |   |
    ga1 ga1 ga1 ga1  
</pre>

At this point, it should be easy to convince yourself that
using the recipe on the right hand side of the associative law will
built the exact same final tree.

So binary trees are a monad.

Haskell combines this monad with the Option monad to provide a monad
called a
[SearchTree](http://hackage.haskell.org/packages/archive/tree-monad/0.2.1/doc/html/src/Control-Monad-SearchTree.html#SearchTree)
that is intended to 
represent non-deterministic computations as a tree.

##[[List Monad as Continuation Monad]]##

##[[Manipulating Trees with Monads]]##