translating tweaks

[lambda.git] / translating_between_OCaml_Scheme_and_Haskell.mdwn

##Translating between OCaml, SML, and Haskell##

The functional programming literature tends to use one of four languages: Scheme, OCaml, Standard ML (SML), or Haskell. With experience, you'll grow comfortable switching between these. At the beginning, though, it can be confusing.

The easiest translations are between OCaml and SML. These languages are both derived from a common ancestor, ML. For the most part, the differences between them are only superficial. [Here's a translatio nmanual](http://www.mpi-sws.org/~rossberg/sml-vs-ocaml.html).

In some respects these languages are closer to Scheme than to Haskell: Scheme, OCaml and SML all default to call-by-value evaluation order, and all three have native syntax for mutation and other imperative idioms (though that's not central to their design). Haskell is different in both respects: the default evaluation order is call-by-name (strictly speaking, it's "call-by-need", which is a more efficient cousin), and the only way to have mutation or the like is through the use of monads.

On both sides, however, the non-default evaluation order can also be had by using special syntax. And in other respects, OCaml and SML are more like Haskell than they are like Scheme. For example, OCaml and SML and Haskell all permit you to declare types and those types are *statically checked*: that is, your program won't even start to be interpreted unless all the types are consistent. In Scheme, on the other hand, type-checking only happens when your program is running, and the language is generally much laxer about what it accepts as well typed. (There's no problem having a list of mixed numbers and booleans, for example... and you don't need to wrap them in any sum type to do so.)

Additionally, the syntax of OCaml and SML is superficially much closer to Haskell's than to Scheme's.

##Comments, Whitespace, and Brackets##

                -- this is a single line comment in Haskell

                {- this
                   is a multiline
                   comment in Haskell -}

                (* this is a single or multiline
                   comment in OCaml *)

                ; this is a single line comment in Scheme

                #| this is a
                   multiline comment
                   in Scheme |#

                #;(this is
                    (another way to
                      (comment out (a block) (of Scheme code))))

*       Haskell is sensitive to linespace and indentation: it matters how your code is lined up. OCaml and Scheme don't care about this, though they recommend following some conventions for readability.

*       In Haskell, a block of code can be bracketed with `{` and `}`, with different expressions separated by `;`. But usually one would use line-breaks and proper indentation instead. In OCaml, separating expressions with `;` has a different meaning, having to do with how side-effects are sequenced. Instead, one can bracket a block of code with `(` and `)` or with `begin` and `end`. In Scheme, of course, every parentheses is significant.


##Scheme and OCaml##

*       You can [try Scheme in your web browser](http://tryscheme.sourceforge.net/). This is useful if you don't have Racket or another Scheme implementation installed---but don't expect it to have all the bells and whistles of a mature implementation!

*       **Type Variants and Pattern Matching** If you want to reproduce this kind of OCaml code:

                type lambda_expression = Var of char | Lam of char * lambda_expression | App of lambda_expression * lambda_expression;;

                let rec free_vars (expr : lambda_expression) : char list =
                  match expr with
                    | Var label -> [label]
                    | Lam (label, body) -> remove label (free_vars body)
                    | App (left, right) -> merge (free_vars left) (free_vars right);;

        in Scheme, you have two choices. First, the quick hack:

                ; we use the symbols 'var and 'lam as tags, and assume
                ; that an expression will always be a pair of one of these forms:
                ;       (cons 'var symbol)
                ;       (cons (cons 'lam symbol) expression)
                ;       (cons expression expression)

                (define (free-vars expr)
                  (cond
                    [(eq? (car expr) 'var) (list (cdr expr))]
                    [(and? (pair? (car expr)) (eq? (car (car expr)) 'lam))
                      (remove (cdr (car expr)) (free-vars (cdr expr)))]
                    [else (merge (free-vars (car expr)) (free-vars (cdr expr)))]))

        Second, you can create real datatypes and pattern-match on them. There are several tools for doing this. I'll describe the `define-datatype` and `cases` forms developed for the book *Essentials of Programming Languages* (EoPL) by Friedman and Wand.

        (Alternatives include the `struct` form in Racket, see <http://docs.racket-lang.org/guide/define-struct.html>. Also `define-record-type` from srfi-9 and srfi-57; see also <http://docs.racket-lang.org/r6rs-lib-std/r6rs-lib-Z-H-7.html>.)

        Here is how the tools from EoPL work. You must begin your file either with `#lang eopl` or with the first two lines below:

                #lang racket
                (require eopl/eopl)

                (define-datatype lambda-expression lambda-expression?
                  (var (label symbol?))
                  (lam (label symbol?) (body lambda-expression?))
                  (app (left lambda-expression?) (right lambda-expression?)))

                (define (free-vars expr)
                  (cases lambda-expression expr
                    (var (label) (list label))
                    (lam (label body) (remove label (free-vars body)))
                    (app (left right) (remove-duplicates (append (free-vars left) (free-vars right))))))


*       Scheme has excellent support for working with implicit or "first-class" **continuations**, using either `call/cc` or any of various delimited continuation operators. See <http://docs.racket-lang.org/reference/cont.html?q=shift&q=do#%28part._.Classical_.Control_.Operators%29>.

        In Scheme you can use these forms by default (they're equivalent):

                (call/cc (lambda (k) ...))
                (let/cc k ...)

        If your program declares `(require racket/control)`, you can also use:

                (begin ... (reset ... (shift k ...) ...) ...)

                (begin ... (prompt ... (control k ...) ...) ...)

                (begin ... (prompt ... (abort value) ...) ...)

        These last three forms are also available in OCaml, but to use them you'll need to compile and install Oleg Kiselyov's "delimcc" or "caml-shift" library (these names refer to the same library), which you can find [here](http://okmij.org/ftp/continuations/implementations.html#caml-shift). You'll already need to have OCaml installed. It also helps if you already have the findlib package installed, too, [as we discuss here](http://lambda.jimpryor.net/how_to_get_the_programming_languages_running_on_your_computer/). If you're not familiar with how to compile software on your computer, this might be beyond your reach for the time being.

        But assuming you do manage to compile and install Oleg's library, here's how you'd use it in an OCaml session:

                #require "delimcc";; (* loading Oleg's library this way requires the findlib package *)
                open Delimcc;; (* this lets you say e.g. new_prompt instead of Delimcc.new_prompt *)
                let p = new_prompt ();;
                let prompt thunk = push_prompt p thunk;;
                let foo =
                  ...
                  prompt (fun () ->
                    ...
                    shift p (fun k -> ...)
                    ...
                    (* or *)
                    control p (fun k -> ...)
                    ...
                    (* or *)
                    abort p value
                    ...
                  )
                  ...

        There is also a library for using *undelimited* continuations in OCaml, but it's shakier than Oleg's delimited continuation library.

We won't say any more about translating to and from Scheme.


##Haskell and OCaml##

We will however try to give some general advice about how to translate between OCaml and Haskell.

*       Again, it may sometimes be useful to [try Haskell in your web browser](http://tryhaskell.org/)
*       There are many Haskell tutorials and textbooks available. This is probably the most actively developed: [Haskell Wikibook](http://en.wikibooks.org/wiki/Haskell)
*       [Yet Another Haskell Tutorial](http://www.cs.utah.edu/~hal/docs/daume02yaht.pdf) (much of this excellent book has supposedly been integrated into the Haskell Wikibook)
*       All About Monads has supposedly also been integrated into the Haskell Wikibook
*       (A not-so-)[Gentle Introduction to Haskell](http://web.archive.org/web/http://www.haskell.org/tutorial/) (archived)
*       [Learn You a Haskell for Great Good](http://learnyouahaskell.com/)


#Type expressions#

*       In Haskell, you say a value has a certain type with: `value :: type`. You express the operation of prepending a new `int` to a list of `int`s with `1 : other_numbers`. In OCaml it's the reverse: you say `value : type` and `1 :: other_numbers`.

*       In Haskell, type names and constructors both begin with capital letters, and type variables always appear after their constructors, in Curried form. And the primary term for declaring a new type is `data` (short for "abstract datatype").
So we have:

                data Either a b = Left a | Right b;
                data FooType a b = Foo_constructor1 a b | Foo_constructor2 a b;

        In printed media, Haskell type variables are often written using Greek letters, like this:

        <pre><code>type Either &alpha; &beta; = Left &alpha; | Right &beta;
        </code></pre>

        Some terminology: in this type declaration, `Either` is known as a *type-constructor*, since it takes some types <code>&alpha;</code> and <code>&beta;</code> as arguments and yields a new type. We call <code>Left &alpha;</code> one of the *variants* for the type <code>Either &alpha; &beta;</code>. `Left` and `Right` are known as *value constructors* or *data constructors* or just *constructors*. You can use `Left` in any context where you need a function, for example:

                map Left [1, 2]

        In OCaml, value constructors are still capitalized, but type names are lowercase. Type variables take the form `'a` instead of `a`, and if there are multiple type variables, they're not Curried but instead have to be grouped in a tuple. The syntax for whether they appear first or second is also somewhat different. So we have instead:

                type ('a,'b) either = Left of 'a | Right of 'b;;
                type ('a,'b) foo_type = Foo_constructor1 of 'a * 'b | Foo_constructor2 of 'a * 'b;;

        In OCaml, constructors aren't full-fledged functions, so you need to do this instead:

                List.map (fun x -> Left x) [1; 2]

        Apart from these differences, there are many similarities between Haskell's and OCaml's use of constructors. For example, in both languages you can do:

                let Left x = Left 1 in x + 1

*       In addition to the `data` keyword, Haskell also sometimes uses `type` and `newtype` to declare types. `type` is used just to introduce synonyms. If you say:

                type Weight = Integer
                type Person = (Name, Address)    -- supposing types Name and Address to be declared elsewhere

        then you can use a value of type `Integer` wherever a `Weight` is expected, and vice versa. `newtype` and `data` on the other hand, create genuinely new types. `newtype` is basically just an efficient version of `data` that you can use in special circumstances. `newtype` must always take one type argument and have one value constructor. For example:

                newtype PersonalData a = PD a

        You could also say:

                data PersonalData a = PD a

        And `data` also allows multiple type arguments, and multiple variants and value constructors.

        OCaml just uses the one keyword `type` for all of these purposes:

                type weight = int;;
                type person = name * address;;
                type 'a personal_data = PD of 'a;;

*       The type constructors discussed above took simple types as arguments. In Haskell, types are also allowed to take *type constructors* as arguments:

                data BarType t = Bint (t Integer) | Bstring (t string)

        One does this for example when defining monad transformers---the type constructor `ReaderT` takes some base monad's type constructor as an argument.

        The way to do this this in OCaml is less straightforward. [See here](/code/tree_monadize.ml) for an example.

*       Haskell has a notion of *type-classes*. They look like this:

                class Eq a where
                  (==)    :: a -> a -> Bool

        This declares the type-class `Eq`; in order to belong to this class, a type `a` will have to supply its own implementation of the function ==, with the type a -> a -> Bool. Here is how the `Integer` class signs up to join the type-class:

                instance Eq Integer where
                  x == y  =  ...

        Type expressions can be conditional on some of their parameters belonging to certain type-classes. For example:

                elem      :: (Eq a) => a -> [a] -> Bool

        says that the function `elem` is only defined over types `a` that belong to the type-class `Eq`. For such types `a`, `elem` has the type `a -> [a] -> Bool`.

        Similarly:

                instance (Eq a) => Eq (Tree a) where
                  Leaf a         == Leaf b          =  a == b
                  (Branch l1 r1) == (Branch l2 r2)  =  (l1==l2) && (r1==r2)
                  _              == _               =  False

        says that if `a` belongs to the typeclass `Eq`, then so too does `Tree a`, and in such cases here is the implementation of `==` for `Tree a`...

*       OCaml doesn't have type-classes. You can do soemthing similar with OCaml modules that take are parameterized on other modules. Again, [see here](/code/tree_monadize.ml) for an example.


*       Some specific differences in how certain types are expressed. This block in Haskell:

                Prelude> type Maybe a = Nothing | Just a
                Prelude> let x = [] :: [Int]
                Prelude> :t x
                x :: [Int]
                Prelude> let x = () :: ()
                Prelude> let x = (1, True) :: (Int, Bool)

corresponds to this block in OCaml:

                # type 'a option = None | Some of 'a;;
                type 'a option = None | Some of 'a
                # let (x : int list) = [];;
                val x : int list = []
                # let (x : unit) = ();;
                val x : unit = ()
                # let (x : int * bool) = (1, true);;
                val x : int * bool = (1, true)

*       Haskell has a plethora of numerical types, including the two types `Int` (integers limited to a machine-dependent range) and `Integer` (unbounded integers). The same arithmetic operators (`+` and so on) work for all of these. OCaml also has several different numerical types (though not as many). In OCaml, by default, one has to use a different numerical operator for each type:

                # 1 + 2;;
                - : int = 3
                # 1.0 + 2.0;;
                Error: This expression has type float but an expression was expected of type int
                # 1.0 +. 2.0;;
                - : float = 3.

        However the comparison operators are polymorphic. You can equally say:

                # 1 = 2;;
                - : bool = false
                # 1.0 = 2.0;;
                - : bool = false
                # 2 > 1;;
                - : bool = true
                # 2.0 > 1.0;;
                - : bool = true

        But you must still apply these operators to expressions of the same type:

                # 2.0 > 1;;
                Error: This expression has type int but an expression was expected of type float

* We'll discuss differences between Haskell's and OCaml's record types below.


#Lists, Tuples, Unit, Booleans#

*       As noted above, Haskell describes the type of a list of `Int`s as `[Int]`. OCaml describes it as `int list`. Haskell describes the type of a pair of `Int`s as `(Int, Int)`. OCaml describes it as `int * int`. Finally, Haskell uses `()` to express both the unit type and a value of that type. In OCaml, one uses `()` for the value and `unit` for the type.

*       Haskell describes the boolean type as `Bool` and its variants are `True` and `False`. OCaml describes the type as `bool` and its variants are `true` and `false`. This is an inconsistency in OCaml: other value constructors must always be capitalized.

*       As noted above, in Haskell one builds up a list by saying `1 : [2, 3]`. In OCaml one says `1 :: [2; 3]`. In Haskell, one can test whether a list is empty with either:

                lst == []
                null lst

        In OCaml, there is no predefined `null` or `isempty` function. One can still test whether a list is empty using the comparison `lst = []`.

*       In Haskell, the expression [1..5] is the same as [1,2,3,4,5], and the expression [0..] is a infinite lazily-evaluated stream of the natural numbers. In OCaml, there is no [1..5] shortcut, lists must be finite, and they are eagerly evaluated. It is possible to create lazy streams in OCaml, even infinite ones, but you have to use other techniques than the native list type.

*       Haskell has *list comprehensions*:

                [ x * x | x <- [1..10], odd x]

        In OCaml, one has to write this out longhand:

                List.map (fun x -> x * x) (List.filter odd [1..10]);;

*       In Haskell, the expressions "abc" and ['a','b','c'] are equivalent. (Strings are just lists of chars. In OCaml, these expressions have two different types.

        Haskell uses the operator `++` for appending both strings and lists (since Haskell strings are just one kind of list). OCaml uses different operators:

                "string1" ^ "string2"
                ['s';'t'] @ ['r';'i';'n';'g']
                (* or equivalently *)
                List.append ['s';'t'] ['r';'i';'n';'g']


#Let and Where#

*       Haskell permits both:

                foo x =
                  let result1 = x * x
                      result2 = x + 1
                  in result1 + result2

        and:

                foo x = result1 + result2
                  where result1 = x * x
                        result2 = x + 1

        OCaml permits only:

                let foo x =
                  let result1 = x * x
                  in let result2 = x + 1
                  in result1 + result2;;

#Patterns#

*       In OCaml:

                # let (x, y) as both = (1, 2)
                  in (both, x, y);;
                - : (int * int) * int * int = ((1, 2), 1, 2)


        The same in Haskell:

                let both@(x,y) = (1, 2)
                  in (both, x, y)

*       In OCaml:

                match list_expression with
                  | y::_ when odd y -> result1
                  | y::_ when y > 5 -> result2
                  | y::_ as whole -> (whole, y)
                  | [] -> result4

        The same in Haskell:

                case list_expression of
                  (y:_) | odd y -> result1
                        | y > 5 -> result2
                  whole@(y:_) -> (whole, y)
                  [] -> result4


#Records#

Haskell and OCaml both have `records`, which are essentially just tuples with a pretty interface. The syntax for declaring and using these is a little bit different in the two languages.

*       In Haskell one says:

                -- declare a record type
                data Color = C { red, green, blue :: Int }
                -- create a value of that type
                let c = C { red = 0, green = 127, blue = 255 }

        In OCaml one says instead:

                type color = { red : int; green : int; blue : int};;
                let c = { red = 0; green = 127; blue = 255 }

        Notice that OCaml doesn't use any value constructor `C`. The record syntax `{ red = ...; green = ...; blue = ... }` is by itself the constructor. The record labels `red`, `green`, and `blue` cannot be re-used for any other record type.

*       In Haskell, one may have multiple constructors for a single record type, and one may re-use record labels within that type, so long as the labels go with fields of the same type:

                data FooType = Constructor1 {f :: Int, g :: Float} | Constructor2 {f :: Int, h :: Bool}

*       In Haskell, one can extract the field of a record like this:

                let c = C { red = 0, green = 127, blue = 255 }
                in red c    -- evaluates to 0

        In OCaml:

                let c = { red = 0; green = 127; blue = 255 }
                in c.red    (* evaluates to 0 *)

*       In both languages, there is a special syntax for creating a copy of an existing record, with some specified fields altered. In Haskell:

                let c2 = c { green = 50, blue = 50 }
                -- evaluates to C { red = red c, green = 50, blue = 50 }

        In OCaml:

                let c2 = { c with green = 50; blue = 50 }
                (* evaluates to { red = c.red; green = 50; blue = 50 }

*       One pattern matches on records in similar ways. In Haskell:

                let C { red = r, green = g } = c
                in r

        In OCaml:

                let { red = r; green = g } = c
                in r

        In Haskell:

                makegray c@(C { red = r} ) = c { green = r, blue = r }

        is equivalent to:

                makegray c = let C { red = r } = c
                             in { red = r, green = r, blue = r }

        In OCaml it's:

                # let makegray ({red = r} as c) = { c with green=r; blue=r };;
                val makegray : color -> color = <fun>
                # makegray { red = 0; green = 127; blue = 255 };;
                - : color = {red = 0; green = 0; blue = 0}


#Functions#

*       In Haskell functions are assumed to be recursive, and their types and applications to values matching different patterns are each declared on different lines. So we have:

                factorial    :: int -> int
                factorial 0  =  1
                factorial n  =  n * factorial (n-1)

        In OCaml you must explicitly say when a function is recursive; and this would be written instead as:

                let rec factorial (n : int) : int =
                  match n with
                    | 0 -> 1
                    | x -> x * factorial (x-1)

        or:

                let rec factorial : int -> int =
                  fun n -> match n with
                    | 0 -> 1
                    | x -> x * factorial (x-1)

        or (though we recommend not using this last form):

                let rec factorial : int -> int =
                  function
                    | 0 -> 1
                    | x -> x * factorial (x-1)

*       Another example, in Haskell:

                length         :: [a] -> Integer
                length []      =  0
                length (x:xs)  =  1 + length xs

        In OCaml:

                let rec length : 'a list -> int =
                  fun lst -> match lst with
                    | [] -> 0
                    | x::xs -> 1 + length xs

*       Another example, in Haskell:

                sign x | x >  0      = 1
                       | x == 0      = 0
                       | otherwise   = -1

        In OCaml:

                let sign x = match x with
                  | x' when x' > 0 -> 1
                  | x' when x' = 0 -> 0
                  | _ -> -1

*       In Haskell the equality comparison operator is `==`, and the non-equality operator is `/=`. In OCaml, `==` expresses "physical identity", which has no analogue in Haskell because Haskell has no mutable types. See our discussion of "Four grades of mutable involvement" in the [[Week9]] notes. In OCaml the operator corresponding to Haskell's `==` is just `=`, and the corresponding non-equality operator is `<>`.

*       In both Haskell and OCaml, one can use many infix operators as prefix functions by parenthesizing them. So for instance:

                (+) 1 2

        will work in both languages. One notable exception is that in OCaml you can't do this with the list constructor `::`:

        # (::) 1 [1;2];;
        Error: Syntax error
        # (fun x xs -> x :: xs) 1 [1; 2];;
        - : int list = [1; 1; 2]

*       Haskell also permits two further shortcuts here that OCaml has no analogue for. In Haskell, in addition to writing:

                (>) 2 1

        you can also write either of:

                (1 >) 2
                (> 2) 1

        In OCaml one has to write these out longhand:

                (fun y -> 1 > y) 2;;
                (fun x -> x > 2) 1;;

        Also, in Haskell, there's a special syntax for using what are ordinarily prefix functions into infix operators:

                Prelude> elem 1 [1, 2]
                True
                Prelude> 1 `elem` [1, 2]
                True

        In OCaml one can't do that. There's only:

                # List.mem 1 [1; 2];;
                - : bool = true

*       In Haskell one writes anonymous functions like this:

                \x -> x + 1

        In OCaml it's:

                fun x -> x + 1

*       Haskell uses the period `.` as a composition operator:

                g . f
                -- same as
                \x -> g (f x)

        In OCaml one has to write it out longhand:

                fun x -> g (f x)

*       In Haskell, expressions like this:

                g $ f x y

        are equivalent to:

                g (f x y)

        (Think of the period in our notation for the untyped lambda calculus.)

*       The names of standard functions, and the order in which they take their arguments, may differ. In Haskell:

                Prelude> :t foldr
                foldr :: (a -> b -> b) -> b -> [a] -> b

        In OCaml:

                # List.fold_right;;
                - : ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b = <fun>

*       Some functions are predefined in Haskell but not in OCaml. Here are OCaml definitions for some common ones:

        let id x = x;;
        let const x _ = x;;
        let flip f x y = f y x;;
        let curry (f : ('a, 'b) -> 'c) = fun x y -> f (x, y);;
        let uncurry (f : 'a -> 'b -> 'c) = fun (x, y) -> f x y;;
        let null lst = lst = [];;

        `fst` and `snd` (defined only on pairs) are provided in both languages. Haskell has `head` and `tail` for lists; these will raise an exception if applied to []. In OCaml the corresponding functions are `List.hd` and `List.tl`. Many other Haskell list functions like `length` are available in OCaml as `List.length`, but OCaml's standard libraries are leaner that Haskell's.

*       The `until` function in Haskell is used like this:

                until (\l -> length l == 4) (1 : ) []
                -- evaluates to [1,1,1,1]

                until (\x -> x == 10) succ 0
                -- evaluates to 10

        This can be defined in OCaml as:

    let rec until test f z =
        if test z then z else until test f (f z)


#Lazy or Eager#

*       As we've mentioned several times, Haskell's evaluation is by default *lazy* or "call-by-need" (that's an efficient version of "call-by-name" that avoids computing the same results again and again). In some places Haskell will force evaluation to be *eager* or "strict". This is done in several different ways; the symbols `!` and `seq` are signs that it's being used.

*       Like Scheme and most other languages, OCaml is by default eager. Laziness can be achieved either by using thunks:

                # let eval_later1 () = 2 / 2;;
                val eval_later1 : unit -> int = <fun>
                # let eval_later2 () = 2 / 0;;
                val eval_later2 : unit -> int = <fun>
                # eval_later1 ();;
                - : int = 1
                # eval_later2 ();;
                Exception: Division_by_zero.

        or by using the special forms `lazy` and `Lazy.force`:

                # let eval_later3 = lazy (2 / 2);;
                val eval_later3 : int lazy_t = <lazy>
                # Lazy.force eval_later3;;
                - : int = 1
                # eval_later3;;
                - : int lazy_t = lazy 1

        Notice in the last line the value is reported as being `lazy 1` instead of `<lazy>`. Since the value has once been forced, it won't ever need to be recomputed. The thunks are less efficient in this respect. Even though OCaml will now remember that `eval_later3` should be forced to, `eval_later3` is still type distinct from a plain `int`.


#Monads#

Haskell has more built-in support for monads, but one can define the monads one needs in OCaml.

*       In our seminar, we've been calling one monadic operation `unit`, in Haskell the same operation is called `return`. We've been calling another monadic operation `bind`, used in prefix form, like this:

                bind u f

        In Haskell, one uses the infix operator `>>=` to express bind instead:

                u >>= f

        If you like this Haskell convention, you can define (>>=) in OCaml like this:

                let (>>=) = bind;;

*       Haskell also uses the operator `>>`, where `u >> v` means the same as `u >>= \_ -> v`.

*       In Haskell, one can generally just use plain `return` and `>>=` and the compiler will infer what monad you must be talking about from the surrounding type constraints. In OCaml, you generally need to be specific about which monad you're using. So in these notes, when mutiple monads are on the table, we've defined operations as `reader_unit` and `reader_bind`.

*       Haskell has a special syntax for working conveniently with monads. It looks like this. Assume `u` `v` and `w` are values of some monadic type `M a`. Then `x` `y` and `z` will be variables of type `a`:

                do
                  x <- u
                  y <- v
                  w
                  let z = foo x y
                  return z

        This is equivalent in meaning to the following:

                u >>= \ x ->
                v >>= \ y ->
                w >>= \ _ ->
                let z = foo x y
                in unit z

        which can be translated straightforwardly into OCaml.

*       If you like the Haskell do-notation, there's [a library](http://www.cas.mcmaster.ca/~carette/pa_monad/) you can compile and install to let you use something similar in OCaml.

*       In order to do any printing, Haskell has to use a special `IO` monad. So programs will look like this:

                main :: IO ()
                main = do
                  let s = "hello world"
                  putStrLn s
        
                main :: IO String
                main = do
                  let s = "hello world"
                  putStrLn s
                  return s
        
                main :: IO String
                main = let s = "hello world"
                       in putStrLn s >> return s

        OCaml permits you to mix side-effects with regular code, so you can just print, without needing to bring in any monad:

                let main =
                  let s = "hello world"
                  in let () = print_endline s
                  in s;;

        or:

                let main =
                  let s = "hello world"
                  in print_endline s ; s;;