transformers tweak

[lambda.git] / monad_transformers.mdwn

[[!toc]]

Multi-layered monadic boxes
===========================

So far, we've defined monads as single-layered boxes. Though in the Groenendijk, Stokhof, and Veltman homework, we had to figure out how to combine Reader, State, and Set monads in an ad-hoc way. In practice, one often wants to combine the abilities of several monads. Corresponding to each monad like Reader, there's a corresponding ReaderT **monad transformer**. That takes an existing monad M and wraps Readerish monad packaging around it. The way these are defined parallels the way the single-layer versions are defined. For example, here's the Reader monad:

        (* monadic operations for the Reader monad *)

        type 'a reader =
                env -> 'a;;
        let unit (a : 'a) : 'a reader =
                fun e -> a;;
        let bind (u: 'a reader) (f : 'a -> 'b reader) : 'b reader =
                fun e -> (fun a -> f a e) (u e);;

We've just beta-expanded the familiar `f (u e) e` into `(fun a -> f a
e) (u e)`. We did that so as to factor out the parts where any Reader monad is
being supplied as an argument to another function. That will help make some patterns that are coming up more salient.

That was the plain Reader monad. Now if we want instead to wrap some other monad M inside Readerish packaging. How could we do it?

Well, one way to proceed would be to just let values of the other monad M be the `'a` in your `'a reader`. Then you could apply `reader_bind` to get at the wrapped `'a M`, and then apply `M.bind` to get at *its* wrapped `'a`. This sometimes works. It's what we did in the hints to GSV assignment, where as we said, we "combined State and Set in an ad hoc way."

But there are two problems: (1) It's cumbersome having to work with *both* `reader_bind` and `M.bind`. It'd be nice to figure out some systematic way to connect the plumbing of the different monadic layers, so that we could have a *single* `bind` that took our `'a M_inside_Reader`, and sequenced it with a single `'a -> 'b M_inside_Reader` function. Similarly for `unit`. This is what the ReaderT monad transformer will let us do.

(2) For some combinations of monads, the best way to implement a Tish monadic wrapper around an inner M monad won't be equivalent to either an `('a m) t` or an `('a t) m`. It will be a tighter intermingling of the two. So some natural activities will remain out of reach until we equip ourselves to go beyond `('a m) t`s and so on.

What we want in general are monadic transformers. For example, a ReaderT transformer will be parameterized not just on the type of its innermost contents `'a`, but also on the monadic box `M` that wraps `'a`. It will make use of monad `M`'s existing operations `M.unit` and `M.bind`, together with the Reader patterns for unit and bind, to define a new monad ReaderT(M) that fuses the behavior of Reader and M.

To be clear: ReaderT isn't itself a monad. It's a kind of Readerish packaging (wrapping paper) that converts one monadic box M into another monadic box ReaderT(M).

Here's how it's implemented:

        (* monadic operations for the ReaderT monadic transformer *)

        (* We're not giving valid OCaml code, but rather something
         * that's conceptually easier to digest.
         * How you really need to write this in OCaml is more circuitous...
         * see http://lambda.jimpryor.net/code/tree_monadize.ml
         * and http://lambda.jimpryor.net/code/monads.ml
         * for some details. *)

        type 'a readerT(M) =
                env -> 'a M;;
        (* this _happens_ also to be the type of an ('a M) reader
         * but as we noted, you can't rely on that pattern always to hold *)

        let unit (a : 'a) : 'a readerT(M) =
                fun e -> M.unit a;;

        let bind (u : 'a readerT(M)) (f : 'a -> 'b readerT(M)) : 'b readerT(M) =
                fun e -> M.bind (u e) (fun a -> f a e);;

Notice the key differences: where before `unit` was implemented by a function that just returned `a`, now we
instead return `M.unit a`. Where before `bind` just supplied value `u e`
of type `'a reader` as an argument to a function, now we instead
`M.bind` the corresponding value to the function. Notice also the differences
in the types.

What is the relation between Reader and ReaderT? Well, suppose you started with the Identity monad:

        type 'a identity = 'a;;
        let unit (a : 'a) : 'a = a;;
        let bind (u : 'a) (f : 'a -> 'b) : 'b = f u;;

and you used the ReaderT transformer to wrap the Identity monad inside Readerish packaging. What do you suppose you would get?

The relations between the State monad and the StateT monadic transformer are parallel:

        (* monadic operations for the State monad *)

        type 'a state =
                store -> ('a * store);;

        let unit (a : 'a) : 'a state =
                fun s -> (a, s);;

        let bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
                fun s -> (fun (a, s') -> f a s') (u s);;

We've used `(fun (a, s') -> f a s') (u s)` instead of the more familiar `let (a, s') = u s in f a s'` in order to factor out the part where a value of type `'a state` is supplied as an argument to a function. Now StateT will be:

        (* monadic operations for the StateT monadic transformer *)

        type 'a stateT(M) =
                store -> ('a * store) M;;
        (* notice this is not an ('a M) state *)

        let unit (a : 'a) : 'a stateT(M) =
                fun s -> M.unit (a, s);;

        let bind (u : 'a stateT(M)) (f : 'a -> 'b stateT(M)) : 'b stateT(M) =
                fun s -> M.bind (u s) (fun (a, s') -> f a s');;


Do you see the pattern? Where before `unit` was implemented by a function that returned an `'a * store` value, now we instead use `M.unit` to return an `('a * store) M` value. Where before `bind` supplied an `'a state` value `(u s)` as an argument to a function, now we instead `M.bind` it to that function.

Once again, what do you think you'd get if you wrapped StateT monadic packaging around an Identity monad?


We spell out all the common monads, their common dedicated operations (such as `lookup`- and `shift`-like operations for the Reader monad), and monad transformer cousins of all of these, in an OCaml [[monad library]]. Read the linked page for details about how to use the library, and some design choices we made. Our [[State Monad Tutorial]] gives some more examples of using the library.

When a T monadic layer encloses an inner M monad, the T's interface is the most exposed one. To use operations defined in the inner M monad, you'll have to "elevate" them into the outer T packaging. Haskell calls this operation `lift`, but we call it `elevate` because the term "lift" is already now too overloaded. In our usage, `lift` (and `lift2`) are functions that bring non-monadic operations into a monad; `elevate` brings monadic operations from a wrapped monad out into the wrapping.

Here's an example. Suppose `S` is an instance of a State monad:

        # #use "path/to/monads.ml";;
        # module S = State_monad(struct type store = int end);;

and `MS` is a MaybeT wrapped around `S`:

        # module MS = Maybe_monad.T(S);;

Then if you want to use an `S`-specific monad like `puts succ` inside `MS`, you'll have to use `MS`'s `elevate` function, like this:

        # MS.(...elevate (S.puts succ) ...)


We said that when T encloses M, you can rely on T's interface to be most exposed. That is intuitive. What you cannot also assume is that the implementing type has a Tish structure surrounding an Mish structure. Often it will be reverse: a ListT(Maybe) is implemented by a `'a list option`, not by an `'a option list`. Until you've tried to write the code to a monadic transformer library yourself, this will probably remain counter-intuitive. But you don't need to concern yourself with it in practise. Think of what you have as a ListT(Maybe); don't worry about whether the underlying implementation is as an `'a list option` or an `'a option list` or as something more complicated.

Notice from the code for StateT, above, that an `'a stateT(M)` is not an `('a M) state`; neither is it an `('a state) M`. The pattern by which we transform the types from a Blah monad to a BlahT monad transformer is:

        't0                  --->  't0 M
        't1 -> 't0           --->  't1 -> 't0 M
        ('t1 -> 't0) -> 't0  --->  ('t1 -> 't0 M) -> 't0 M

Ken Shan's paper [Monads for natural language semantics](http://arxiv.org/abs/cs/0205026v1) (2001) discusses how to systematically move from some base monads to the corresponding monad transformers. But as he notes, his algorithm isn't the only one possible, and it only applies to monads whose type has a certain form. (Reader and State have that form; List for example doesn't.)

As best we know, figuring out how a monad transformer should be defined is still something of an art, not something that can be done mechanically. However, you can think that all of the art goes into deciding what StateT and so on should be; having figured that out, plain State would follow as the simple case where StateT is parameterized on the Identity monad.

Apart from whose interface is outermost, the behavior of a StateT(Maybe) and a MaybeT(State) will partly coincide. But in certain crucial respects they will diverge, and you need to think carefully about which behavior you want and what the appropriate layering is for your needs. Consider these examples:

        # module MS = Maybe_monad.T(S);;
        # module SM = S.T(Maybe_monad);;
        # MS.(run (elevate (S.puts succ) >> zero () >> elevate S.get >>= fun cur -> unit (cur+10) )) 0;;
        - : int option * S.store = (None, 1)
        # MS.(run (elevate (S.puts succ) >> zero () >> elevate (S.put 5) )) 0;;
        - : unit option * S.store = (None, 1)

Although we have a wrapped `None`, notice that the store (as it was at the point of failure) is still retrievable.

        # SM.(run (puts succ >> elevate (Maybe_monad.zero ()) >> get >>= fun cur -> unit (cur+10) )) 0;;
        - : ('a, int * S.store) Maybe_monad.result = None

When Maybe is on the inside, on the other hand, a failure means the whole computation has failed, and even the store is no longer available.

<!--
        # ES.(run( elevate (S.puts succ) >> throw "bye" >> elevate S.get >>= fun i -> unit(i+10) )) 0;;
        - : int Failure.error * S.store = (Failure.Error "bye", 1)
        # SE.(run( puts succ >> elevate (Failure.throw "bye") >> get >>= fun i -> unit(i+10) )) 0;;
        - : (int * S.store) Failure.result = Failure.Error "bye"
        # ES.(run_exn( elevate (S.puts succ) >> throw "bye" >> elevate S.get >>= fun i -> unit(i+10) )) 0;;
        Exception: Failure "bye".
        # SE.(run_exn( puts succ >> elevate (Failure.throw "bye") >> get >>= fun i -> unit(i+10) )) 0;;
        Exception: Failure "bye".
-->

Here's an example wrapping List around Maybe, and vice versa:

        # module LM = List_monad.T(Maybe_monad);;
        # module ML = Maybe_monad.T(List_monad);;
        # ML.(run (plus (zero ()) (unit 20) >>= fun i -> unit (i+10)));;
        - : ('_a, int) ML.result = [Some 30]

When List is on the inside, the failed results just get dropped and the computation proceeds without them.

        # LM.(run (plus (elevate (Maybe_monad.zero ())) (unit 20) >>= fun i -> unit (i+10)));;
        - : ('_a, int) LM.result = None

On the other hand, when Maybe is on the inside, failures abort the whole computation.

<!--
        # EL.(run( plus (throw "bye") (unit 20) >>= fun i -> unit(i+10)));;
        - : int EL.result = [Failure.Error "bye"; Failure.Success 30]
        # LE.(run( plus (elevate (Failure.throw "bye")) (unit 20) >>= fun i -> unit(i+10)));;
        - : int LE.result = Failure.Error "bye"
        # EL.(run_exn( plus (throw "bye") (unit 20) >>= fun i -> unit(i+10)));;
        Exception: Failure "bye".
        # LE.(run_exn( plus (elevate (Failure.throw "bye")) (unit 20) >>= fun i -> unit(i+10)));;
        Exception: Failure "bye".
-->

This is fun. Notice the difference it makes whether the second `plus` is native to the outer `List_monad`, or whether it's the inner `List_monad`'s `plus` elevated into the outer wrapper:

        # module LL = List_monad.T(List_monad);;

        # LL.(run(plus (unit 1) (unit 2) >>= fun i -> plus (unit i) (unit(10*i)) ));;
        - : ('_a, int) LL.result = \[[1; 10; 2; 20]]
        # LL.(run(plus (unit 1) (unit 2) >>= fun i -> elevate L.(plus (unit i) (unit(10*i)) )));;
        - : ('_a, int) LL.result = [[1; 2]; [1; 20]; [10; 2]; [10; 20]]



Further Reading
---------------

*       This is excellent, everyone should read: [Monad Transformers Step by Step](http://www.grabmueller.de/martin/www/pub/Transformers.pdf)

*       Read Part III of [All About Monads](http://web.archive.org/web/20071106232016/haskell.org/all_about_monads/html/introIII.html). This link is to an archived version, the main link to haskell.org seems to be broken. Some but not all of this site has been [absorbed into the Haskell wikibook](http://en.wikibooks.org/wiki/Haskell/Monad_transformers).


Tree Monads
===========

Our [[monad library]] includes a `Tree_monad`, for binary, leaf-labeled trees. There are other kinds of trees you might want to monadize, but we took the name `Tree_monad` for this one. Like the Haskell [SearchTree](http://hackage.haskell.org/packages/archive/tree-monad/0.2.1/doc/html/src/Control-Monad-SearchTree.html#SearchTree) monad, our `Tree_monad` also incorporates an Optionish layer. (See the comments in our library code about `plus` and `zero` for discussion of why.)

So how does our `Tree_monad` behave? Simplified, its implementation looks something like this:

        (* monadic operations for the Tree monad *)

        type 'a tree =
                Leaf of 'a | Node of ('a tree) * ('a tree);;

        let unit (a: 'a) : 'a tree =
                Leaf a;;

        let rec bind (u : 'a tree) (f : 'a -> 'b tree) : 'b tree =
            match u with
            | Leaf a -> f a;;
            | Node (l, r) ->
                        let l' = bind l f in
                        let r' = bind r f in
                        Node (l', r')

Recall how `bind` works for the List monad. If you have a list:

        let u = [1; 2; 4; 8];;

and a function `f` such that:

        f 1 ~~> []
        f 2 ~~> [2]
        f 4 ~~> [2; 4]
        f 8 ~~> [2; 4; 8]

then `list_bind u f` would be `concat [[]; [2]; [2; 4]; [2; 4; 8]]`, that is `[2; 2; 4; 2; 4; 8]`. It splices the lists returned by `f` into the corresponding positions in the original list structure. The `tree_bind` operation works the same way. If `f'` maps `2` to the tree `Leaf 2` and `8` to the tree `Node (Leaf 2, Node (Leaf 4, Leaf 8))`, then binding the tree `u` to `f'` will splice the trees returned by `f'` to the corresponding positions in the original structure:

         u
         .                    .
        _|__  >>=  f' ~~>    _|__
        |  |                 |  |
        2  8                 2  .
                               _|__
                               |  |
                               2  .
                                 _|__
                                 |  |
                                 4  8

Except, as we mentioned, our implementation of the Tree monad incorporates an Optionish layer too. So `f' 2` should be not `Leaf 2` but `Some (Leaf 2)`. What if `f'` also mapped `1` to `None` and `4` to `Some (Node (Leaf 2, Leaf 4))`. Then binding the tree `Node (Leaf 1, Node (Leaf 2, Leaf 4))` to `f'` would delete thr branch corresponding to the original `Leaf 1`, and would splice in the results for `f' 2` and `f' 4`, yielding:

         .                        
        _|__  >>=  f' ~~>         
        |  |                     
        1  .                    .
          _|__                 _|__
          |  |                 |  |
          2  4                 2  .
                                 _|__
                                 |  |
                                 2  4

As always, the functions you bind an `'a tree` to need not map `'a`s to `'a tree`s; they can map them to `'b tree`s instead. For instance, we could transform `Node (Leaf 1, Node (Leaf 2, Leaf 4))` instead into `Node (Leaf "two", Node (Leaf "two", Leaf "four"))`.

As we [mention in the notes](/monad_library), our monad library encapsulates the implementation of its monadic types. So to work with it you have to use the primitives it provides. You can't say:

        # Tree_monad.(orig_tree >>= fun a -> match a with
            | 4 -> Some (Node (Leaf 2, Leaf 4))
            | _ -> None);;
        Error: This expression has type int Tree_monad.tree option
                   but an expression was expected of type ('a, 'b) Tree_monad.m

You have to instead say something like this:

        # Tree_monad.(orig_tree >>= fun a -> match a with
            | 4 -> plus (unit 2) (unit 4)
            | _ -> zero () );;
        - : ('_a, int) Tree_monad.m = <abstr>



How is all this related to our tree\_monadize function?
-------------------------------------------------------

Recall our earlier definition of `tree_monadize`, specialized for the Reader monad:

        let rec tree_monadize (f : 'a -> 'b reader) (t : 'a tree) : 'b tree reader =
            match t with
            | Leaf a -> reader_bind (f a) (fun b -> reader_unit (Leaf b))
            | Node (l, r) -> reader_bind (tree_monadize f l) (fun l' ->
                               reader_bind (tree_monadize f r) (fun r' ->
                                 reader_unit (Node (l', r'))));;


(MORE...)