[lambda.git] / manipulating_trees_with_monads.mdwn

[[!toc]]

Manipulating trees with monads
------------------------------

This topic develops an idea based on a detailed suggestion of Ken
Shan's.  We'll build a series of functions that operate on trees,
doing various things, including replacing leaves, counting nodes, and
converting a tree to a list of leaves.  The end result will be an
application for continuations.

From an engineering standpoint, we'll build a tree transformer that
deals in monads.  We can modify the behavior of the system by swapping
one monad for another.  We've already seen how adding a monad can add
a layer of funtionality without disturbing the underlying system, for
instance, in the way that the reader monad allowed us to add a layer
of intensionality to an extensional grammar, but we have not yet seen
the utility of replacing one monad with other.

First, we'll be needing a lot of trees for the remainder of the
course.  Here again is a type constructor for leaf-labeled, binary trees:

    type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)

[How would you adjust the type constructor to allow for labels on the
internal nodes?]

We'll be using trees where the nodes are integers, e.g.,


        let t1 = Node (Node (Leaf 2, Leaf 3),
                       Node (Leaf 5, Node (Leaf 7,
                                              Leaf 11)))
            .
         ___|___
         |     |
         .     .
        _|_   _|__
        |  |  |  |
        2  3  5  .
                _|__
                |  |
                7  11

Our first task will be to replace each leaf with its double:

        let rec tree_map (leaf_modifier : 'a -> 'b) (t : 'a tree) : 'b tree =
          match t with
            | Leaf i -> Leaf (leaf_modifier i)
            | Node (l, r) -> Node (tree_map leaf_modifier l,
                                   tree_map leaf_modifier r);;

`tree_map` takes a function that transforms old leaves into new leaves,
and maps that function over all the leaves in the tree, leaving the
structure of the tree unchanged.  For instance:

        let double i = i + i;;
        tree_map double t1;;
        - : int tree =
        Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))
        
            .
         ___|____
         |      |
         .      .
        _|__  __|__
        |  |  |   |
        4  6  10  .
                __|___
                |    |
                14   22

We could have built the doubling operation right into the `tree_map`
code.  However, because we've left what to do to each leaf as a parameter, we can
decide to do something else to the leaves without needing to rewrite
`tree_map`.  For instance, we can easily square each leaf instead by
supplying the appropriate `int -> int` operation in place of `double`:

        let square i = i * i;;
        tree_map square t1;;
        - : int tree =ppp
        Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))

Note that what `tree_map` does is take some global, contextual
information---what to do to each leaf---and supplies that information
to each subpart of the computation.  In other words, `tree_map` has the
behavior of a reader monad.  Let's make that explicit.

In general, we're on a journey of making our `tree_map` function more and
more flexible.  So the next step---combining the tree transformer with
a reader monad---is to have the `tree_map` function return a (monadized)
tree that is ready to accept any `int -> int` function and produce the
updated tree.

\tree (. (. (f 2) (f 3)) (. (f 5) (. (f 7) (f 11))))

        \f      .
           _____|____
           |        |
           .        .
         __|___   __|___
         |    |   |    |
        f 2  f 3  f 5  .
                     __|___
                     |    |
                    f 7  f 11

That is, we want to transform the ordinary tree `t1` (of type `int
tree`) into a reader object of type `(int -> int) -> int tree`: something
that, when you apply it to an `int -> int` function `f` returns an `int
tree` in which each leaf `i` has been replaced with `f i`.

With previous readers, we always knew which kind of environment to
expect: either an assignment function (the original calculator
simulation), a world (the intensionality monad), an integer (the
Jacobson-inspired link monad), etc.  In the present case, it will be
enough to expect that our "environment" will be some function of type
`int -> int`.

        type 'a reader = (int -> int) -> 'a;;  (* mnemonic: e for environment *)
        let reader_unit (a : 'a) : 'a reader = fun _ -> a;;
        let reader_bind (u: 'a reader) (f : 'a -> 'b reader) : 'b reader = fun e -> f (u e) e;;

It would be a simple matter to turn an *integer* into an `int reader`:

        let int_readerize : int -> int reader = fun (a : int) -> fun (modifier : int -> int) -> modifier a;;
        int_readerize 2 (fun i -> i + i);;
        - : int = 4

But how do we do the analagous transformation when our `int`s are scattered over the leaves of a tree? How do we turn an `int tree` into a reader?
A tree is not the kind of thing that we can apply a
function of type `int -> int` to.

But we can do this:

        let rec tree_monadize (f : 'a -> 'b reader) (t : 'a tree) : 'b tree reader =
            match t with
            | Leaf i -> reader_bind (f i) (fun i' -> reader_unit (Leaf i'))
            | Node (l, r) -> reader_bind (tree_monadize f l) (fun x ->
                               reader_bind (tree_monadize f r) (fun y ->
                                 reader_unit (Node (x, y))));;

This function says: give me a function `f` that knows how to turn
something of type `'a` into an `'b reader`, and I'll show you how to
turn an `'a tree` into an `'b tree reader`.  In more fanciful terms,
the `tree_monadize` function builds plumbing that connects all of the
leaves of a tree into one connected monadic network; it threads the
`'b reader` monad through the original tree's leaves.

        # tree_monadize int_readerize t1 double;;
        - : int tree =
        Node (Node (Leaf 4, Leaf 6), Node (Leaf 10, Node (Leaf 14, Leaf 22)))

Here, our environment is the doubling function (`fun i -> i + i`).  If
we apply the very same `int tree reader` (namely, `tree_monadize
int_readerize t1`) to a different `int -> int` function---say, the
squaring function, `fun i -> i * i`---we get an entirely different
result:

        # tree_monadize int_readerize t1 square;;
        - : int tree =
        Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))

Now that we have a tree transformer that accepts a reader monad as a
parameter, we can see what it would take to swap in a different monad.

<!-- FIXME -->

For instance, we can use a state monad to count the number of nodes in
the tree.

        type 'a state = int -> 'a * int;;
        let state_unit a = fun s -> (a, s);;
        let state_bind_and_count u f = fun s -> let (a, s') = u s in f a (s' + 1);;

Gratifyingly, we can use the `tree_monadize` function without any
modification whatsoever, except for replacing the (parametric) type
`'b reader` with `'b state`, and substituting in the appropriate unit and bind:

        let rec tree_monadize (f : 'a -> 'b state) (t : 'a tree) : 'b tree state =
            match t with
            | Leaf i -> state_bind_and_count (f i) (fun i' -> state_unit (Leaf i'))
            | Node (l, r) -> state_bind_and_count (tree_monadize f l) (fun x ->
                               state_bind_and_count (tree_monadize f r) (fun y ->
                                 state_unit (Node (x, y))));;

Then we can count the number of nodes in the tree:

        # tree_monadize state_unit t1 0;;
        - : int tree * int =
        (Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11))), 13)
        
            .
         ___|___
         |     |
         .     .
        _|__  _|__
        |  |  |  |
        2  3  5  .
                _|__
                |  |
                7  11

Notice that we've counted each internal node twice---it's a good
exercise to adjust the code to count each node once.

<!--
A tree with n leaves has 2n - 1 nodes.
This function will currently return n*1 + (n-1)*2 = 3n - 2.
To convert b = 3n - 2 into 2n - 1, we can use: let n = (b + 2)/3 in 2*n -1

But I assume Chris means here, adjust the code so that no corrections of this sort have to be applied.
-->


One more revealing example before getting down to business: replacing
`state` everywhere in `tree_monadize` with `list` gives us

        # tree_monadize (fun i -> [ [i; square i] ]) t1;;
        - : int list tree list =
        [Node
          (Node (Leaf [2; 4], Leaf [3; 9]),
           Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))]

Unlike the previous cases, instead of turning a tree into a function
from some input to a result, this transformer replaces each `int` with
a list of `int`'s.

<!--
We don't make it clear why the fun has to be int -> int list list, instead of int -> int list
-->


Now for the main point.  What if we wanted to convert a tree to a list
of leaves?

        type ('a, 'r) continuation = ('a -> 'r) -> 'r;;
        let continuation_unit a = fun k -> k a;;
        let continuation_bind u f = fun k -> u (fun a -> f a k);;
        
        let rec tree_monadize (f : 'a -> ('b, 'r) continuation) (t : 'a tree) : ('b tree, 'r) continuation =
            match t with
            | Leaf i -> continuation_bind (f i) (fun i' -> continuation_unit (Leaf i'))
            | Node (l, r) -> continuation_bind (tree_monadize f l) (fun x ->
                               continuation_bind (tree_monadize f r) (fun y ->
                                 continuation_unit (Node (x, y))));;

We use the continuation monad described above, and insert the
`continuation` type in the appropriate place in the `tree_monadize` code.
We then compute:

        # tree_monadize (fun a k -> a :: (k a)) t1 (fun t -> []);;
        - : int list = [2; 3; 5; 7; 11]

<!-- FIXME: what if we had fun t -> [-t]? why `t`? -->

We have found a way of collapsing a tree into a list of its leaves.

The continuation monad is amazingly flexible; we can use it to
simulate some of the computations performed above.  To see how, first
note that an interestingly uninteresting thing happens if we use
`continuation_unit` as our first argument to `tree_monadize`, and then
apply the result to the identity function:

        # tree_monadize continuation_unit t1 (fun i -> i);;
        - : int tree =
        Node (Node (Leaf 2, Leaf 3), Node (Leaf 5, Node (Leaf 7, Leaf 11)))

That is, nothing happens.  But we can begin to substitute more
interesting functions for the first argument of `tree_monadize`:

        (* Simulating the tree reader: distributing a operation over the leaves *)
        # tree_monadize (fun a k -> k (square a)) t1 (fun i -> i);;
        - : int tree =
        Node (Node (Leaf 4, Leaf 9), Node (Leaf 25, Node (Leaf 49, Leaf 121)))

        (* Simulating the int list tree list *)
        # tree_monadize (fun a k -> k [a; square a]) t1 (fun i -> i);;
        - : int list tree =
        Node
         (Node (Leaf [2; 4], Leaf [3; 9]),
          Node (Leaf [5; 25], Node (Leaf [7; 49], Leaf [11; 121])))

        (* Counting leaves *)
        # tree_monadize (fun a k -> 1 + k a) t1 (fun i -> 0);;
        - : int = 5

We could simulate the tree state example too, but it would require
generalizing the type of the continuation monad to

        type ('a, 'b, 'c) continuation = ('a -> 'b) -> 'c;;

The binary tree monad
---------------------

Of course, by now you may have realized that we have discovered a new
monad, the binary tree monad:

        type 'a tree = Leaf of 'a | Node of ('a tree) * ('a tree);;
        let tree_unit (a: 'a) = Leaf a;;
        let rec tree_bind (u : 'a tree) (f : 'a -> 'b tree) : 'b tree =
            match u with
            | Leaf a -> f a
            | Node (l, r) -> Node ((tree_bind l f), (tree_bind r f));;

For once, let's check the Monad laws.  The left identity law is easy:

    Left identity: bind (unit a) f = bind (Leaf a) f = f a

To check the other two laws, we need to make the following
observation: it is easy to prove based on `tree_bind` by a simple
induction on the structure of the first argument that the tree
resulting from `bind u f` is a tree with the same strucure as `u`,
except that each leaf `a` has been replaced with `f a`:

\tree (. (f a1) (. (. (. (f a2) (f a3)) (f a4)) (f a5)))

                        .                         .
                      __|__                     __|__
                      |   |                     |   |
                      a1  .                   f a1  .
                         _|__                     __|__
                         |  |                     |   |
                         .  a5                    .  f a5
           bind         _|__       f   =        __|__
                        |  |                    |   |
                        .  a4                   .  f a4
                      __|__                   __|___
                      |   |                   |    |
                      a2  a3                f a2  f a3

Given this equivalence, the right identity law

        Right identity: bind u unit = u

falls out once we realize that

        bind (Leaf a) unit = unit a = Leaf a

As for the associative law,

        Associativity: bind (bind u f) g = bind u (\a. bind (f a) g)

we'll give an example that will show how an inductive proof would
proceed.  Let `f a = Node (Leaf a, Leaf a)`.  Then

\tree (. (. (. (. (a1) (a2)))))
\tree (. (. (. (. (a1) (a1)) (. (a1) (a1)))))

                                                   .
                                               ____|____
                  .               .            |       |
        bind    __|__   f  =    __|_    =      .       .
                |   |           |   |        __|__   __|__
                a1  a2        f a1 f a2      |   |   |   |
                                             a1  a1  a1  a1

Now when we bind this tree to `g`, we get

                    .
               _____|______
               |          |
               .          .
             __|__      __|__
             |   |      |   |
           g a1 g a1  g a1 g a1

At this point, it should be easy to convince yourself that
using the recipe on the right hand side of the associative law will
built the exact same final tree.

So binary trees are a monad.

Haskell combines this monad with the Option monad to provide a monad
called a
[SearchTree](http://hackage.haskell.org/packages/archive/tree-monad/0.2.1/doc/html/src/Control-Monad-SearchTree.html#SearchTree)
that is intended to represent non-deterministic computations as a tree.