1 [[!toc]]
3 We're going to come at continuations from three different directions, and each
4 time we're going to end up at the same place: a particular monad, which we'll
5 call the Continuation monad.
7 Rethinking the List monad
8 -------------------------
10 To construct a monad, the key element is to settle on how to implement its type, and
11 the monad more or less naturally follows from that.
12 We'll remind you of some examples of how monads follow from their types
13 in a moment.  This will involve some review of familiar
14 material, but it's worth doing for two reasons: it will set up a
15 pattern for the new discussion further below, and it will tie together
16 some previously unconnected elements of the course (more specifically,
17 version 3 lists and monads).
19 For instance, take the **Reader monad**.  Once we decide to define its type as:
21         type 'a reader = env -> 'a
23 then the choice of unit and bind is natural:
25         let r_unit (a : 'a) : 'a reader = fun (e : env) -> a
27 The reason this is a fairly natural choice is that because the type of
28 an `'a reader` is `env -> 'a` (by definition), the type of the
29 `r_unit` function is `'a -> env -> 'a`, which is an instance of the
30 type of the **K** combinator.  So it makes sense that **K** is the unit
33 Since the type of the `bind` operator is required to be
35         r_bind : 'a reader -> ('a -> 'b reader) -> 'b reader
37 We can reason our way to the traditional reader `bind` function as
38 follows. We start by declaring the types determined by the definition
39 of a bind operation:
41         let r_bind (u : 'a reader) (f : 'a -> 'b reader) : 'b reader = ...
43 Now we have to open up the `u` box and get out the `'a` object in order to
44 feed it to `f`.  Since `u` is a function from environments to
45 objects of type `'a`, the way we open a box in this monad is
46 by applying it to an environment:
48         ... f (u e) ...
50 This subexpression types to `'b reader`, which is good.  The only
51 problem is that we made use of an environment `e` that we didn't already have,
52 so we must abstract over that variable to balance the books:
54         fun e -> f (u e) ...
56 [To preview the discussion of the Curry-Howard correspondence, what
57 we're doing here is constructing an intuitionistic proof of the type,
58 and using the Curry-Howard labeling of the proof as our bind term.]
60 This types to `env -> 'b reader`, but we want to end up with `env ->
61 'b`.  Once again, the easiest way to turn a `'b reader` into a `'b` is to apply it to an environment.  So we end up as follows:
63         r_bind (u : 'a reader) (f : 'a -> 'b reader) : 'b reader =
64             fun e -> f (u e) e
66 And we're done. This gives us a bind function of the right type. We can then check whether, in combination with the unit function we chose, it satisfies the monad laws, and behaves in the way we intend. And it does.
68 [The bind we cite here is a condensed version of the careful `let a = u e in ...`
69 constructions we provided in earlier lectures.  We use the condensed
70 version here in order to emphasize similarities of structure across
73 The **State monad** is similar.  Once we've decided to use the following type constructor:
75         type 'a state = store -> ('a, store)
77 Then our unit is naturally:
79         let s_unit (a : 'a) : 'a state = fun (s : store) -> (a, s)
81 And we can reason our way to the bind function in a way similar to the reasoning given above. First, we need to apply `f` to the contents of the `u` box:
83         let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
84             ... f (...) ...
86 But unlocking the `u` box is a little more complicated.  As before, we
87 need to posit a store `s` that we can apply `u` to.  Once we do so,
88 however, we won't have an `'a`; we'll have a pair whose first element
89 is an `'a`.  So we have to unpack the pair:
91         ... let (a, s') = u s in ... f a ...
93 Abstracting over the `s` and adjusting the types gives the result:
95         let s_bind (u : 'a state) (f : 'a -> 'b state) : 'b state =
96             fun (s : store) -> let (a, s') = u s in f a s'
98 The **Option/Maybe monad** doesn't follow the same pattern so closely, so we
99 won't pause to explore it here, though conceptually its unit and bind
100 follow just as naturally from its type constructor.
102 Our other familiar monad is the **List monad**, which we were told
103 looks like this:
105         (* type 'a list = ['a];; *)
106         l_unit (a : 'a) = [a];;
107         l_bind u f = List.concat (List.map f u);;
109 Thinking through the List monad will take a little time, but doing so
110 will provide a connection with continuations.
112 Recall that `List.map` takes a function and a list and returns the
113 result of applying the function to the elements of the list:
115         List.map (fun i -> [i; i+1]) [1; 2] ~~> [[1; 2]; [2; 3]]
117 and `List.concat` takes a list of lists and erases one level of embedded list
118 boundaries:
120         List.concat [[1; 2]; [2; 3]] ~~> [1; 2; 2; 3]
122 And sure enough,
124         l_bind [1; 2] (fun i -> [i; i+1]) ~~> [1; 2; 2; 3]
126 Now, why this unit, and why this bind?  Well, ideally a unit should
127 not throw away information, so we can rule out `fun x -> []` as an
128 ideal unit.  And units should not add more information than required,
129 so there's no obvious reason to prefer `fun x -> [x; x]`.  In other
130 words, `fun x -> [x]` is a reasonable choice for a unit.
132 As for bind, an `'a list` monadic object contains a lot of objects of
133 type `'a`, and we want to make use of each of them (rather than
134 arbitrarily throwing some of them away).  The only
135 thing we know for sure we can do with an object of type `'a` is apply
136 the function of type `'a -> 'b list` to them.  Once we've done so, we
137 have a collection of lists, one for each of the `'a`'s.  One
138 possibility is that we could gather them all up in a list, so that
139 `bind' [1; 2] (fun i -> [i; i]) ~~> [[1; 1]; [2; 2]]`.  But that restricts
140 the object returned by the second argument of `bind` to always be of
141 type `('something list) list`.  We can eliminate that restriction by flattening
142 the list of lists into a single list: this is
143 just `List.concat` applied to the output of `List.map`.  So there is some logic to the
144 choice of unit and bind for the List monad.
146 Yet we can still desire to go deeper, and see if the appropriate bind
147 behavior emerges from the types, as it did for the previously
148 considered monads.  But we can't do that if we leave the list type as
149 a primitive OCaml type.  However, we know several ways of implementing
150 lists using just functions.  In what follows, we're going to use version
151 3 lists, the right fold implementation (though it's important and
152 intriguing to wonder how things would change if we used some other
153 strategy for implementing lists).  These were the lists that made
154 lists look like Church numerals with extra bits embedded in them:
156         empty list:                fun f z -> z
157         list with one element:     fun f z -> f 1 z
158         list with two elements:    fun f z -> f 2 (f 1 z)
159         list with three elements:  fun f z -> f 3 (f 2 (f 1 z))
161 and so on.  To save time, we'll let the OCaml interpreter infer the
162 principle types of these functions (rather than inferring what the
163 types should be ourselves):
165         # fun f z -> z;;
166         - : 'a -> 'b -> 'b = <fun>
167         # fun f z -> f 1 z;;
168         - : (int -> 'a -> 'b) -> 'a -> 'b = <fun>
169         # fun f z -> f 2 (f 1 z);;
170         - : (int -> 'a -> 'a) -> 'a -> 'a = <fun>
171         # fun f z -> f 3 (f 2 (f 1 z))
172         - : (int -> 'a -> 'a) -> 'a -> 'a = <fun>
174 We can see what the consistent, general principle types are at the end, so we
175 can stop. These types should remind you of the simply-typed lambda calculus
176 types for Church numerals (`(o -> o) -> o -> o`) with one extra type
177 thrown in, the type of the element at the head of the list
178 (in this case, an `int`).
180 So here's our type constructor for our hand-rolled lists:
182         type 'b list' = (int -> 'b -> 'b) -> 'b -> 'b
184 Generalizing to lists that contain any kind of element (not just
185 `int`s), we have
187         type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b
189 So an `('a, 'b) list'` is a list containing elements of type `'a`,
190 where `'b` is the type of some part of the plumbing.  This is more
191 general than an ordinary OCaml list, but we'll see how to map them
192 into OCaml lists soon.  We don't need to fully grasp the role of the `'b`s
193 in order to proceed to build a monad:
195         l'_unit (a : 'a) : ('a, 'b) list = fun a -> fun k z -> k a z
197 Take an `'a` and return its v3-style singleton. No problem.  Arriving at bind
198 is a little more complicated, but exactly the same principles apply, you just
199 have to be careful and systematic about it.
201         l'_bind (u : ('a, 'b) list') (f : 'a -> ('c, 'd) list') : ('c, 'd) list'  = ...
203 Unpacking the types gives:
205         l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
206                 (f : 'a -> ('c -> 'd -> 'd) -> 'd -> 'd)
207                    : ('c -> 'd -> 'd) -> 'd -> 'd = ...
209 Perhaps a bit intimidating.
210 But it's a rookie mistake to quail before complicated types. You should
211 be no more intimidated by complex types than by a linguistic tree with
212 deeply embedded branches: complex structure created by repeated
213 application of simple rules.
215 [This would be a good time to try to reason your way to your own term having the type just specified.  Doing so (or attempting to do so) will make the next
216 paragraph much easier to follow.]
218 As usual, we need to unpack the `u` box.  Examine the type of `u`.
219 This time, `u` will only deliver up its contents if we give `u` an
220 argument that is a function expecting an `'a` and a `'b`. `u` will
221 fold that function over its type `'a` members, and that's where we can get at the `'a`s we need. Thus:
223         ... u (fun (a : 'a) (b : 'b) -> ... f a ... ) ...
225 In order for `u` to have the kind of argument it needs, the `fun a b -> ... f a ...` has to have type `'a -> 'b -> 'b`; so the `... f a ...` has to evaluate to a result of type `'b`. The easiest way to do this is to collapse (or "unify") the types `'b` and `'d`, with the result that `f a` will have type `('c -> 'b -> 'b) -> 'b -> 'b`. Let's postulate an argument `k` of type `('c -> 'b -> 'b)` and supply it to `f a`:
227         ... u (fun (a : 'a) (b : 'b) -> ... f a k ... ) ...
229 Now the function we're supplying to `u` also receives an argument `b` of type `'b`, so we can supply that to `f a k`, getting a result of type `'b`, as we need:
231         ... u (fun (a : 'a) (b : 'b) -> f a k b) ...
233 Now, we've used a `k` that we pulled out of nowhere, so we need to abstract over it:
235         fun (k : 'c -> 'b -> 'b) -> u (fun (a : 'a) (b : 'b) -> f a k b)
237 This whole expression has type `('c -> 'b -> 'b) -> 'b -> 'b`, which is exactly the type of a `('c, 'b) list'`. So we can hypothesize that our bind is:
239         l'_bind (u : ('a -> 'b -> 'b) -> 'b -> 'b)
240                 (f : 'a -> ('c -> 'b -> 'b) -> 'b -> 'b)
241                    : ('c -> 'b -> 'b) -> 'b -> 'b =
242             fun k -> u (fun a b -> f a k b)
244 That is a function of the right type for our bind, but to check whether it works, we have to verify it (with the unit we chose) against the monad laws, and reason whether it will have the right behavior.
246 Here's a way to persuade yourself that it will have the right behavior. First, it will be handy to eta-expand our `fun k -> u (fun a b -> f a k b)` to:
248         fun k z -> u (fun a b -> f a k b) z
250 Now let's think about what this does. It's a wrapper around `u`. In order to behave as the list `v` which is the result of mapping `f` over each element of `u`, and then joining (`concat`ing) the results, this wrapper would have to accept arguments `k` and `z` and fold them in just the same way that `v` would.
251 Will it?
253 Suppose we have a list' whose contents are `[1; 2; 4; 8]`---that is, our list' `u` will be `fun f z -> f 1 (f 2 (f 4 (f 8 z)))`. Suppose we also have a function `f` that for each `int` we give it, gives back a list of the divisors of that `int` that are greater than 1. Intuitively, then, binding `u` to `f` should give us:
255         v =
256         List.concat (List.map f u) =
257         List.concat [[]; ; [2; 4]; [2; 4; 8]] =
258         [2; 2; 4; 2; 4; 8]
260 Or rather, it should give us a list' version of that, which takes a function `k` and value `z` as arguments, and returns the right fold of `k` and `z` over those elements. Does our formula
262         fun k z -> u (fun a b -> f a k b) z
264 do that? Well, for each element `a` in `u`, it applies `f` to that `a`, getting one of the lists:
266         []        ; result of applying f to leftmost a
267         
268         [2; 4]
269         [2; 4; 8] ; result of applying f to rightmost a
271 (or rather, their list' versions). Then it takes the accumulated result `b` of previous steps in the `k`,`z`-fold, and it folds `k` and `b` over the list generated by `f a`. The result of doing so is passed on to the next step of the `k`,`z`-fold as the new accumulated result `b`.
273 So if, for example, we let `k` be `+` and `z` be `0`, then the computation would proceed:
275         0 ==>
276         right-fold + and 0 over [2; 4; 8] = 2+4+8+(0) ==>
277         right-fold + and 2+4+8+0 over [2; 4] = 2+4+(2+4+8+(0)) ==>
278         right-fold + and 2+4+2+4+8+0 over  = 2+(2+4+(2+4+8+(0))) ==>
279         right-fold + and 2+2+4+2+4+8+0 over [] = 2+(2+4+(2+4+8+(0)))
281 which indeed is the result of right-folding `+` and `0` over `[2; 2; 4; 2; 4; 8]`. If you trace through how this works, you should be able to persuade yourself that our formula:
283         fun k z -> u (fun a b -> f a k b) z
285 will deliver just the same folds, for arbitrary choices of `k` and `z` (with the right types), and arbitrary `list'`s `u` and appropriately-typed `f`s, as
287         fun k z -> List.fold_right k v z =
288         fun k z -> List.fold_right k (List.concat (List.map f u)) z
290 would.
292 For future reference, we might make two eta-reductions to our formula, so that we have instead:
294         let l'_bind = fun k -> u (fun a -> f a k);;
296 Let's make some more tests:
298         # l_bind [1; 2] (fun i -> [i; i+1]);;
299         - : int list = [1; 2; 2; 3]
301         # l'_bind (fun f z -> f 1 (f 2 z)) (fun i -> fun f z -> f i (f (i+1) z));;
302         - : (int -> '_a -> '_a) -> '_a -> '_a = <fun>
304 Sigh.  OCaml won't show us our own list.  So we have to choose an `f`
305 and a `z` that will turn our hand-crafted lists into standard OCaml
306 lists, so that they will print out.
308         # let cons h t = h :: t;;  (* OCaml is stupid about :: *)
309         # l'_bind (fun f z -> f 1 (f 2 z)) (fun i -> fun f z -> f i (f (i+1) z)) cons [];;
310         - : int list = [1; 2; 2; 3]
312 Ta da!
315 Montague's PTQ treatment of DPs as generalized quantifiers
316 ----------------------------------------------------------
318 We've hinted that Montague's treatment of DPs as generalized
319 quantifiers embodies the spirit of continuations (see de Groote 2001,
320 Barker 2002 for lengthy discussion).  Let's see why.
322 First, we'll need a type constructor.  As we've said,
323 Montague replaced individual-denoting determiner phrases (with type `e`)
324 with generalized quantifiers (with [extensional] type `(e -> t) -> t`.
325 In particular, the denotation of a proper name like *John*, which
326 might originally denote a object `j` of type `e`, came to denote a
327 generalized quantifier `fun pred -> pred j` of type `(e -> t) -> t`.
328 Let's write a general function that will map individuals into their
329 corresponding generalized quantifier:
331         gqize (a : e) = fun (p : e -> t) -> p a
333 This function is what Partee 1987 calls LIFT, which is not an unreasonable name. But we will avoid her term here, since that word has been used to refer to other functions in our discussion.
335 This function wraps up an individual in a box.  That is to say,
336 we are in the presence of a monad.  The type constructor, the unit and
337 the bind follow naturally.  We've done this enough times that we won't
338 belabor the construction of the bind function. The derivation is
339 highly similar to the List monad just given:
341         type 'a continuation = ('a -> 'b) -> 'b
342         let c_unit (a : 'a) = fun (p : 'a -> 'b) -> p a
343         let c_bind (u : ('a -> 'b) -> 'b) (f : 'a -> ('c -> 'd) -> 'd) : ('c -> 'd) -> 'd =
344             fun (k : 'a -> 'b) -> u (fun (a : 'a) -> f a k)
346 Note that `c_unit` is exactly the `gqize` function that Montague used
347 to lift individuals into generalized quantifiers.
349 That last bit in `c_bind` looks familiar---we just saw something like
350 it in the List monad.  How similar is it to the List monad?  Let's
351 examine the type constructor and the terms from the list monad derived
352 above:
354         type ('a, 'b) list' = ('a -> 'b -> 'b) -> 'b -> 'b;;
355                 (* that is of the form ('a -> 'r) -> 'r, where 'r = 'b -> 'b *)
356         let l'_unit a = fun k z -> k a z;;
358 This can be eta-reduced to:
360         let l'_unit a = fun k -> k a
362 and:
364         let l'_bind u f =
365             (* we mentioned three versions of this, the eta-expanded: *)
366             fun k z -> u (fun a b -> f a k b) z
367                 (* an intermediate version, and the fully eta-reduced: *)
368             fun k -> u (fun a -> f a k)
370 Consider the most eta-reduced versions of `l'_unit` and `l'_bind`. They're the same as the unit and bind for the Montague Continuation monad! In other words, the behavior of our v3-List monad and the behavior of the continuations monad are
371 parallel in a deep sense.
373 Have we really discovered that lists are secretly continuations?  Or
374 have we merely found a way of simulating lists using list
375 continuations?  Well, strictly speaking, what we have done is shown
376 that one particular implementation of lists---the right fold
377 implementation---gives rise to a Continuation monad fairly naturally,
378 and that this monad can reproduce the behavior of the standard list
379 monad.  But what about other list implementations?  Do they give rise
380 to monads that can be understood in terms of continuations?