1 Refunctionalizing zippers: from lists to continuations
2 ------------------------------------------------------
4 If zippers are continuations reified (defuntionalized), then one route
5 to continuations is to re-functionalize a zipper.  Then the
6 concreteness and understandability of the zipper provides a way of
7 understanding and equivalent treatment using continuations.
9 Let's work with lists of `char`s for a change.  To maximize readability, we'll
10 indulge in an abbreviatory convention that "abSd" abbreviates the
11 list `['a'; 'b'; 'S'; 'd']`.
13 We will set out to compute a deceptively simple-seeming **task: given a
14 string, replace each occurrence of 'S' in that string with a copy of
15 the string up to that point.**
17 We'll define a function `t` (for "task") that maps strings to their
18 updated version.
20 Expected behavior:
22         t "abSd" ~~> "ababd"
25 In linguistic terms, this is a kind of anaphora
26 resolution, where `'S'` is functioning like an anaphoric element, and
27 the preceding string portion is the antecedent.
29 This deceptively simple task gives rise to some mind-bending complexity.
30 Note that it matters which 'S' you target first (the position of the *
31 indicates the targeted 'S'):
33             t "aSbS"
34                 *
35         ~~> t "aabS"
36                   *
37         ~~> "aabaab"
39 versus
41             t "aSbS"
42                   *
43         ~~> t "aSbaSb"
44                 *
45         ~~> t "aabaSb"
46                    *
47         ~~> "aabaaabab"
49 versus
51             t "aSbS"
52                   *
53         ~~> t "aSbaSb"
54                    *
55         ~~> t "aSbaaSbab"
56                     *
57         ~~> t "aSbaaaSbaabab"
58                      *
59         ~~> ...
61 Aparently, this task, as simple as it is, is a form of computation,
62 and the order in which the `'S'`s get evaluated can lead to divergent
63 behavior.
65 For now, we'll agree to always evaluate the leftmost `'S'`, which
66 guarantees termination, and a final string without any `'S'` in it.
68 This is a task well-suited to using a zipper.  We'll define a function
69 `tz` (for task with zippers), which accomplishes the task by mapping a
70 `char list zipper` to a `char list`.  We'll call the two parts of the
71 zipper `unzipped` and `zipped`; we start with a fully zipped list, and
72 move elements to the zipped part by pulling the zipper down until the
73 entire list has been unzipped (and so the zipped half of the zipper is empty).
75         type 'a list_zipper = ('a list) * ('a list);;
77         let rec tz (z:char list_zipper) =
78             match z with (unzipped, []) -> List.rev(unzipped) (* Done! *)
79                        | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped)
80                        | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)
82         # tz ([], ['a'; 'b'; 'S'; 'd']);;
83         - : char list = ['a'; 'b'; 'a'; 'b'; 'd']
85         # tz ([], ['a'; 'S'; 'b'; 'S']);;
86         - : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
88 Note that this implementation enforces the evaluate-leftmost rule.
91 One way to see exactly what is going on is to watch the zipper in
92 action by tracing the execution of `tz`.  By using the `#trace`
93 directive in the Ocaml interpreter, the system will print out the
94 arguments to `tz` each time it is (recurcively) called.  Note that the
95 lines with left-facing arrows (`<--`) show (recursive) calls to `tz`,
96 giving the value of its argument (a zipper), and the lines with
97 right-facing arrows (`-->`) show the output of each recursive call, a
98 simple list.
100 <pre>
101 # #trace tz;;
102 t1 is now traced.
103 # tz ([], ['a'; 'b'; 'S'; 'd']);;
104 tz <-- ([], ['a'; 'b'; 'S'; 'd'])
105 tz <-- (['a'], ['b'; 'S'; 'd'])         (* Pull zipper *)
106 tz <-- (['b'; 'a'], ['S'; 'd'])         (* Pull zipper *)
107 tz <-- (['b'; 'a'; 'b'; 'a'], ['d'])    (* Special step *)
108 tz <-- (['d'; 'b'; 'a'; 'b'; 'a'], [])  (* Pull zipper *)
109 tz --> ['a'; 'b'; 'a'; 'b'; 'd']        (* Output reversed *)
110 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
111 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
112 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
113 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
114 - : char list = ['a'; 'b'; 'a'; 'b'; 'd']
115 </pre>
117 The nice thing about computations involving lists is that it's so easy
118 to visualize them as a data structure.  Eventually, we want to get to
119 a place where we can talk about more abstract computations.  In order
120 to get there, we'll first do the exact same thing we just did with
121 concrete zipper using procedures.
123 Think of a list as a procedural recipe: `['a'; 'b'; 'S'; 'd']`
124 is the result of the computation `'a'::('b'::('S'::('d'::[])))` (or, in our old
125 style, `make_list 'a' (make_list 'b' (make_list 'S' (make_list 'd' empty)))`).
126 The recipe for constructing the list goes like this:
128 <pre>
129 (0)  Start with the empty list []
130 (1)  make a new list whose first element is 'd' and whose tail is the list constructed in step (0)
131 (2)  make a new list whose first element is 'S' and whose tail is the list constructed in step (1)
132 -----------------------------------------
133 (3)  make a new list whose first element is 'b' and whose tail is the list constructed in step (2)
134 (4)  make a new list whose first element is 'a' and whose tail is the list constructed in step (3)
135 </pre>
137 What is the type of each of these steps?  Well, it will be a function
138 from the result of the previous step (a list) to a new list: it will
139 be a function of type `char list -> char list`.  We'll call each step
140 (or group of steps) a **continuation** of the recipe.  So in this
141 context, a continuation is a function of type `char list -> char
142 list`.  For instance, the continuation corresponding to the portion of
143 the recipe below the horizontal line is the function `fun (tail:char
144 list) -> 'a'::('b'::tail)`.
146 This means that we can now represent the unzipped part of our
147 zipper---the part we've already unzipped---as a continuation: a function
148 describing how to finish building the list.  We'll write a new
149 function, `tc` (for task with continuations), that will take an input
150 list (not a zipper!) and a continuation and return a processed list.
151 The structure and the behavior will follow that of `tz` above, with
152 some small but interesting differences.  We've included the orginal
153 `tz` to facilitate detailed comparison:
155 <pre>
156 let rec tz (z:char list_zipper) =
157     match z with (unzipped, []) -> List.rev(unzipped) (* Done! *)
158                | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped)
159                | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)
161 let rec tc (l: char list) (c: (char list) -> (char list)) =
162   match l with [] -> List.rev (c [])
163              | 'S'::zipped -> tc zipped (fun x -> c (c x))
164              | target::zipped -> tc zipped (fun x -> target::(c x));;
166 # tc ['a'; 'b'; 'S'; 'd'] (fun x -> x);;
167 - : char list = ['a'; 'b'; 'a'; 'b']
169 # tc ['a'; 'S'; 'b'; 'S'] (fun x -> x);;
170 - : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
171 </pre>
173 To emphasize the parallel, I've re-used the names `zipped` and
174 `target`.  The trace of the procedure will show that these variables
175 take on the same values in the same series of steps as they did during
176 the execution of `tz` above.  There will once again be one initial and
177 four recursive calls to `tc`, and `zipped` will take on the values
178 `"bSd"`, `"Sd"`, `"d"`, and `""` (and, once again, on the final call,
179 the first `match` clause will fire, so the the variable `zipper` will
180 not be instantiated).
182 I have not called the functional argument `unzipped`, although that is
183 what the parallel would suggest.  The reason is that `unzipped` is a
184 list, but `c` is a function.  That's the most crucial difference, the
185 point of the excercise, and it should be emphasized.  For instance,
186 you can see this difference in the fact that in `tz`, we have to glue
187 together the two instances of `unzipped` with an explicit (and
188 relatively inefficient) `List.append`.
189 In the `tc` version of the task, we simply compose `c` with itself:
190 `c o c = fun x -> c (c x)`.
192 Why use the identity function as the initial continuation?  Well, if
193 you have already constructed the initial list `"abSd"`, what's the next
194 step in the recipe to produce the desired result, i.e, the very same
195 list, `"abSd"`?  Clearly, the identity continuation.
197 A good way to test your understanding is to figure out what the
198 continuation function `c` must be at the point in the computation when
199 `tc` is called with the first argument `"Sd"`.  Two choices: is it
200 `fun x -> a::b::x`, or it is `fun x -> b::a::x`?  The way to see if
201 you're right is to execute the following command and see what happens:
203     tc ['S'; 'd'] (fun x -> 'a'::'b'::x);;
205 There are a number of interesting directions we can go with this task.
206 The reason this task was chosen is because it can be viewed as a
207 simplified picture of a computation using continuations, where `'S'`
208 plays the role of a control operator with some similarities to what is
209 often called `shift`.  In the analogy, the input list portrays a
210 sequence of functional applications, where `[f1; f2; f3; x]` represents
211 `f1(f2(f3 x))`.  The limitation of the analogy is that it is only
212 possible to represent computations in which the applications are
213 always right-branching, i.e., the computation `((f1 f2) f3) x` cannot
214 be directly represented.
216 One possibile development is that we could add a special symbol `'#'`,
217 and then the task would be to copy from the target `'S'` only back to
218 the closest `'#'`.  This would allow the task to simulate delimited
219 continuations with embedded prompts.
221 The reason the task is well-suited to the list zipper is in part
222 because the list monad has an intimate connection with continuations.
223 The following section explores this connection.  We'll return to the
224 list task after talking about generalized quantifiers below.