from_lists_to_continuations.mdwn

   1 Refunctionalizing zippers: from lists to continuations
   2 ------------------------------------------------------
   3
   4 If zippers are continuations reified (defuntionalized), then one route
   5 to continuations is to re-functionalize a zipper.  Then the
   6 concreteness and understandability of the zipper provides a way of
   7 understanding and equivalent treatment using continuations.
   8
   9 Let's work with lists of `char`s for a change.  To maximize readability, we'll
  10 indulge in an abbreviatory convention that "abSd" abbreviates the
  11 list `['a'; 'b'; 'S'; 'd']`.
  12
  13 We will set out to compute a deceptively simple-seeming **task: given a
  14 string, replace each occurrence of 'S' in that string with a copy of
  15 the string up to that point.**
  16
  17 We'll define a function `t` (for "task") that maps strings to their
  18 updated version.
  19
  20 Expected behavior:
  21
  22         t "abSd" ~~> "ababd"
  23
  24
  25 In linguistic terms, this is a kind of anaphora
  26 resolution, where `'S'` is functioning like an anaphoric element, and
  27 the preceding string portion is the antecedent.
  28
  29 This deceptively simple task gives rise to some mind-bending complexity.
  30 Note that it matters which 'S' you target first (the position of the *
  31 indicates the targeted 'S'):
  32
  33             t "aSbS"
  34                 *
  35         ~~> t "aabS"
  36                   *
  37         ~~> "aabaab"
  38
  39 versus
  40
  41             t "aSbS"
  42                   *
  43         ~~> t "aSbaSb"
  44                 *
  45         ~~> t "aabaSb"
  46                    *
  47         ~~> "aabaaabab"
  48
  49 versus
  50
  51             t "aSbS"
  52                   *
  53         ~~> t "aSbaSb"
  54                    *
  55         ~~> t "aSbaaSbab"
  56                     *
  57         ~~> t "aSbaaaSbaabab"
  58                      *
  59         ~~> ...
  60
  61 Aparently, this task, as simple as it is, is a form of computation,
  62 and the order in which the `'S'`s get evaluated can lead to divergent
  63 behavior.
  64
  65 For now, we'll agree to always evaluate the leftmost `'S'`, which
  66 guarantees termination, and a final string without any `'S'` in it.
  67
  68 This is a task well-suited to using a zipper.  We'll define a function
  69 `tz` (for task with zippers), which accomplishes the task by mapping a
  70 `char list zipper` to a `char list`.  We'll call the two parts of the
  71 zipper `unzipped` and `zipped`; we start with a fully zipped list, and
  72 move elements to the zipped part by pulling the zipper down until the
  73 entire list has been unzipped (and so the zipped half of the zipper is empty).
  74
  75         type 'a list_zipper = ('a list) * ('a list);;
  76
  77         let rec tz (z : char list_zipper) =
  78             match z with
  79             | (unzipped, []) -> List.rev(unzipped) (* Done! *)
  80             | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped)
  81             | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)
  82
  83         # tz ([], ['a'; 'b'; 'S'; 'd']);;
  84         - : char list = ['a'; 'b'; 'a'; 'b'; 'd']
  85
  86         # tz ([], ['a'; 'S'; 'b'; 'S']);;
  87         - : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
  88
  89 Note that this implementation enforces the evaluate-leftmost rule.
  90 Task completed.
  91
  92 One way to see exactly what is going on is to watch the zipper in
  93 action by tracing the execution of `tz`.  By using the `#trace`
  94 directive in the Ocaml interpreter, the system will print out the
  95 arguments to `tz` each time it is (recurcively) called.  Note that the
  96 lines with left-facing arrows (`<--`) show (recursive) calls to `tz`,
  97 giving the value of its argument (a zipper), and the lines with
  98 right-facing arrows (`-->`) show the output of each recursive call, a
  99 simple list.
 100
 101 <pre>
 102 # #trace tz;;
 103 t1 is now traced.
 104 # tz ([], ['a'; 'b'; 'S'; 'd']);;
 105 tz <-- ([], ['a'; 'b'; 'S'; 'd'])
 106 tz <-- (['a'], ['b'; 'S'; 'd'])         (* Pull zipper *)
 107 tz <-- (['b'; 'a'], ['S'; 'd'])         (* Pull zipper *)
 108 tz <-- (['b'; 'a'; 'b'; 'a'], ['d'])    (* Special step *)
 109 tz <-- (['d'; 'b'; 'a'; 'b'; 'a'], [])  (* Pull zipper *)
 110 tz --> ['a'; 'b'; 'a'; 'b'; 'd']        (* Output reversed *)
 111 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
 112 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
 113 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
 114 tz --> ['a'; 'b'; 'a'; 'b'; 'd']
 115 - : char list = ['a'; 'b'; 'a'; 'b'; 'd']
 116 </pre>
 117
 118 The nice thing about computations involving lists is that it's so easy
 119 to visualize them as a data structure.  Eventually, we want to get to
 120 a place where we can talk about more abstract computations.  In order
 121 to get there, we'll first do the exact same thing we just did with
 122 concrete zipper using procedures.
 123
 124 Think of a list as a procedural recipe: `['a'; 'b'; 'S'; 'd']`
 125 is the result of the computation `'a'::('b'::('S'::('d'::[])))` (or, in our old
 126 style, `make_list 'a' (make_list 'b' (make_list 'S' (make_list 'd' empty)))`).
 127 The recipe for constructing the list goes like this:
 128
 129 <pre>
 130 (0)  Start with the empty list []
 131 (1)  make a new list whose first element is 'd' and whose tail is the list constructed in step (0)
 132 (2)  make a new list whose first element is 'S' and whose tail is the list constructed in step (1)
 133 -----------------------------------------
 134 (3)  make a new list whose first element is 'b' and whose tail is the list constructed in step (2)
 135 (4)  make a new list whose first element is 'a' and whose tail is the list constructed in step (3)
 136 </pre>
 137
 138 What is the type of each of these steps?  Well, it will be a function
 139 from the result of the previous step (a list) to a new list: it will
 140 be a function of type `char list -> char list`.  We'll call each step
 141 (or group of steps) a **continuation** of the recipe.  So in this
 142 context, a continuation is a function of type `char list -> char
 143 list`.  For instance, the continuation corresponding to the portion of
 144 the recipe below the horizontal line is the function `fun (tail : char
 145 list) -> 'a'::('b'::tail)`.
 146
 147 This means that we can now represent the unzipped part of our
 148 zipper---the part we've already unzipped---as a continuation: a function
 149 describing how to finish building the list.  We'll write a new
 150 function, `tc` (for task with continuations), that will take an input
 151 list (not a zipper!) and a continuation and return a processed list.
 152 The structure and the behavior will follow that of `tz` above, with
 153 some small but interesting differences.  We've included the orginal
 154 `tz` to facilitate detailed comparison:
 155
 156         let rec tz (z : char list_zipper) =
 157             match z with
 158             | (unzipped, []) -> List.rev(unzipped) (* Done! *)
 159             | (unzipped, 'S'::zipped) -> tz ((List.append unzipped unzipped), zipped)
 160             | (unzipped, target::zipped) -> tz (target::unzipped, zipped);; (* Pull zipper *)
 161
 162         let rec tc (l: char list) (c: (char list) -> (char list)) =
 163             match l with
 164             | [] -> List.rev (c [])
 165             | 'S'::zipped -> tc zipped (fun x -> c (c x))
 166             | target::zipped -> tc zipped (fun x -> target::(c x));;
 167
 168         # tc ['a'; 'b'; 'S'; 'd'] (fun x -> x);;
 169         - : char list = ['a'; 'b'; 'a'; 'b']
 170
 171         # tc ['a'; 'S'; 'b'; 'S'] (fun x -> x);;
 172         - : char list = ['a'; 'a'; 'b'; 'a'; 'a'; 'b']
 173
 174 To emphasize the parallel, I've re-used the names `zipped` and
 175 `target`.  The trace of the procedure will show that these variables
 176 take on the same values in the same series of steps as they did during
 177 the execution of `tz` above.  There will once again be one initial and
 178 four recursive calls to `tc`, and `zipped` will take on the values
 179 `"bSd"`, `"Sd"`, `"d"`, and `""` (and, once again, on the final call,
 180 the first `match` clause will fire, so the the variable `zipper` will
 181 not be instantiated).
 182
 183 I have not called the functional argument `unzipped`, although that is
 184 what the parallel would suggest.  The reason is that `unzipped` is a
 185 list, but `c` is a function.  That's the most crucial difference, the
 186 point of the excercise, and it should be emphasized.  For instance,
 187 you can see this difference in the fact that in `tz`, we have to glue
 188 together the two instances of `unzipped` with an explicit (and
 189 relatively inefficient) `List.append`.
 190 In the `tc` version of the task, we simply compose `c` with itself:
 191 `c o c = fun x -> c (c x)`.
 192
 193 Why use the identity function as the initial continuation?  Well, if
 194 you have already constructed the initial list `"abSd"`, what's the next
 195 step in the recipe to produce the desired result, i.e, the very same
 196 list, `"abSd"`?  Clearly, the identity continuation.
 197
 198 A good way to test your understanding is to figure out what the
 199 continuation function `c` must be at the point in the computation when
 200 `tc` is called with the first argument `"Sd"`.  Two choices: is it
 201 `fun x -> a::b::x`, or it is `fun x -> b::a::x`?  The way to see if
 202 you're right is to execute the following command and see what happens:
 203
 204     tc ['S'; 'd'] (fun x -> 'a'::'b'::x);;
 205
 206 There are a number of interesting directions we can go with this task.
 207 The reason this task was chosen is because it can be viewed as a
 208 simplified picture of a computation using continuations, where `'S'`
 209 plays the role of a control operator with some similarities to what is
 210 often called `shift`.  In the analogy, the input list portrays a
 211 sequence of functional applications, where `[f1; f2; f3; x]` represents
 212 `f1(f2(f3 x))`.  The limitation of the analogy is that it is only
 213 possible to represent computations in which the applications are
 214 always right-branching, i.e., the computation `((f1 f2) f3) x` cannot
 215 be directly represented.
 216
 217 One possibile development is that we could add a special symbol `'#'`,
 218 and then the task would be to copy from the target `'S'` only back to
 219 the closest `'#'`.  This would allow the task to simulate delimited
 220 continuations with embedded prompts.
 221
 222 The reason the task is well-suited to the list zipper is in part
 223 because the list monad has an intimate connection with continuations.
 224 The following section explores this connection.  We'll return to the
 225 list task after talking about generalized quantifiers below.
 226
 227
 228