[lambda.git] / exercises / _assignment12.mdwn

## Same-fringe using zippers ##

Recall back in [[Assignment 4|assignment4#fringe]], we asked you to enumerate the "fringe" of a leaf-labeled tree. Both of these trees (here I *am* drawing the labels in the diagram):

            .                .
           / \              / \
          .   3            1   .
         / \                  / \
        1   2                2   3

have the same fringe: `[1; 2; 3]`. We also asked you to write a function that determined when two trees have the same fringe. The way you approached that back then was to enumerate each tree's fringe, and then compare the two lists for equality. Today, and then again in a later class, we'll encounter new ways to approach the problem of determining when two trees have the same fringe.


Supposing you did work out an implementation of the tree zipper, then one way to determine whether two trees have the same fringe would be: go downwards (and leftwards) in each tree as far as possible. Compare the focused leaves. If they're different, stop because the trees have different fringes. If they're the same, then for each tree, move rightward if possible; if it's not (because you're at the rightmost leaf in a subtree), move upwards then try again to move rightwards. Repeat until you are able to move rightwards. Once you do move rightwards, go downwards (and leftwards) as far as possible. Then you'll be focused on the next leaf in the tree's fringe. The operations it takes to get to "the next leaf" may be different for the two trees. For example, in these trees:

            .                .
           / \              / \
          .   3            1   .
         / \                  / \
        1   2                2   3

you won't move upwards at the same steps. Keep comparing "the next leaves" until they are different, or you exhaust the leaves of only one of the trees (then again the trees have different fringes), or you exhaust the leaves of both trees at the same time, without having found leaves with different labels. In this last case, the trees have the same fringe.

If your trees are very big---say, millions of leaves---you can imagine how this would be quicker and more memory-efficient than traversing each tree to construct a list of its fringe, and then comparing the two lists so built to see if they're equal. For one thing, the zipper method can abort early if the fringes diverge early, without needing to traverse or build a list containing the rest of each tree's fringe.

Let's sketch the implementation of this. We won't provide all the details for an implementation of the tree zipper (you'll need to fill those in), but we will sketch an interface for it.

In these exercises, we'll help ourselves to OCaml's **record types**. These are nothing more than tuples with a pretty interface. Instead of saying:

    # type blah = Blah of (int * int * (char -> bool));;

and then having to remember which element in the triple was which:

    # let b1 = Blah (1, (fun c -> c = 'M'), 2);;
    Error: This expression has type int * (char -> bool) * int
    but an expression was expected of type int * int * (char -> bool)
    # (* damnit *)
    # let b1 = Blah (1, 2, (fun c -> c = 'M'));;
    val b1 : blah = Blah (1, 2, <fun>)

records let you attach descriptive labels to the components of the tuple:

    # type blah_record = { height : int; weight : int; char_tester : char -> bool };;
    # let b2 = { height = 1; weight = 2; char_tester = (fun c -> c = 'M') };;
    val b2 : blah_record = {height = 1; weight = 2; char_tester = <fun>}
    # let b3 = { height = 1; char_tester = (fun c -> c = 'K'); weight = 3 };; (* also works *)
    val b3 : blah_record = {height = 1; weight = 3; char_tester = <fun>}

These were the strategies to extract the components of an unlabeled tuple:

    let h = fst some_pair;; (* accessor functions fst and snd are only predefined for pairs *)

    let (h, w, test) = b1;; (* works for arbitrary tuples *)

    match b1 with
    | (h, w, test) -> ...;; (* same as preceding *)

Here is how you can extract the components of a labeled record:

    let h = b2.height;; (* handy! *)

    let {height = h; weight = w; char_tester = test} = b2 in
    (* go on to use h, w, and test ... *)

    match test with
    | {height = h; weight = w; char_tester = test} ->
    (* same as preceding *)

Anyway, using record types, we might define the tree zipper interface like so. First, we define a type for leaf-labeled, binary trees:

    type 'a tree = Leaf of 'a | Node of ('a tree * 'a tree)

Next, the types for our tree zippers:

    type 'a zipper = { in_focus: 'a tree; context : 'a context }
    and 'a context = Root | Nonroot of 'a nonroot_context
    and 'a nonroot_context = { up : 'a context; left: 'a tree option; right: 'a tree option }

Unlike in seminar, here we represent the siblings as `'a tree option`s rather than `'a tree list`s. Since we're dealing with binary trees, each context will have exactly one sibling, either to the right or to the left.

The following function takes an `'a tree` and returns an `'a zipper` focused on its root:

    let new_zipper (t : 'a tree) : 'a zipper =
      {in_focus = t; context = Root}

Here are the beginnings of functions to move from one focused tree to another:

    let rec move_botleft (z : 'a zipper) : 'a zipper =
      (* returns z if the focused node in z has no children *)
      (* else returns move_botleft (zipper which results from moving down from z's focused node to its leftmost child) *)
      _____ (* YOU SUPPLY THE DEFINITION *)

<!--
    match z.in_focus with
    | Leaf _ -> z
    | Node(left, right) ->
        move_botleft {in_focus = left; context = Nonroot {up = z.context; left = None; right = Some right}}
-->


    let rec move_right_or_up (z : 'a zipper) : 'a zipper option =
      (* if it's possible to move right in z, returns Some (the result of doing so) *)
      (* else if it's not possible to move any further up in z, returns None *)
      (* else returns move_right_or_up (result of moving up in z) *)
      _____ (* YOU SUPPLY THE DEFINITION *)

<!--
    match z.context with
    | Nonroot {up; left= None; right = Some right} ->
        Some {in_focus = right; context = Nonroot {up; left = Some z.in_focus; right = None}}
    | Root -> None
    | Nonroot {up; left = Some left; right = None} ->
        move_right_or_up {in_focus = Node(left, z.in_focus); context = up}
-->


1.  Your first assignment is to complete the definitions of `move_botleft` and `move_right_or_up`.

    Having completed that, we can use define a function that enumerates a tree's fringe, step by step, until it's exhausted:

        let make_fringe_enumerator (t: 'a tree) : 'b * 'a zipper option =
          (* create a zipper focusing the botleft of t *)
          let zbotleft = move_botleft (new_zipper t) in
          (* create initial state, pointing to zbotleft *)
          let initial_state = Some zbotleft in
          (* construct the next_leaf function *)
          let next_leaf : 'a zipper option -> ('a * 'a zipper option) option = function
            | Some z -> (
              (* extract label of currently-focused leaf *)
              let Leaf current = z.in_focus in
              (* create next_state pointing to next leaf, if there is one *)
              let next_state : 'a zipper option = match move_right_or_up z with
                | None -> None
                | Some z' -> Some (move_botleft z') in
              (* return saved label and next_state *)
              Some (current, next_state)
              )
            | None -> (* we've finished enumerating the fringe *)
              None in
          (* return the next_leaf function and initial state *)
          next_leaf, initial_state

    Here's an example of `make_fringe_enumerator` in action:

        # let tree1 = Leaf 1;;
        val tree1 : int tree = Leaf 1
        # let next1, state1 = make_fringe_enumerator tree1;;
        val next1 : unit -> int option = <fun>
        # let res1, state1' = next1 state1;;
        - : int option = Some 1
        # next1 state1';;
        - : int option = None
        # let tree2 = Node (Node (Leaf 1, Leaf 2), Leaf 3);;
        val tree2 : int tree = Node (Node (Leaf 1, Leaf 2), Leaf 3)
        # let next2, state2 = make_fringe_enumerator tree2;;
        val next2 : unit -> int option = <fun>
        # let res2, state2' = next2 state2;;
        - : int option = Some 1
        # let res2, state2'' = next2 state2';;
        - : int option = Some 2
        # let res2, state2''' = next2 state2'';;
        - : int option = Some 3
        # let res2, state2'''' = next2 state2''';;
        - : int option = None

    You might think of it like this: `make_fringe_enumerator` returns a little subprogram that will keep returning the next leaf in a tree's fringe, in the form `Some ...`, until it gets to the end of the fringe. After that, it will return `None`. The subprogram's memory of where it is and what steps to perform next are stored in the `state` variables that are part of its input and output.

    Using these fringe enumerators, we can write our `same_fringe` function like this:

        let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
          let next1, initial_state1 = make_fringe_enumerator t1 in
          let next2, initial_state2 = make_fringe_enumerator t2 in
          let rec loop state1 state2 : bool =
            match next1 state1, next2 state2 with
            | Some (a, state1'), Some (b, state2') when a = b -> loop state1' state2'
            | None, None -> true
            | _ -> false in
          loop initial_state1 initial_state2

    The auxiliary `loop` function will keep calling itself recursively until a difference in the fringes has manifested itself---either because one fringe is exhausted before the other, or because the next leaves in the two fringes have different labels. If we get to the end of both fringes at the same time (`next1 (), next2 ()` matches the pattern `None, None`) then we've established that the trees do have the same fringe.

2.  Test your implementations of `move_botleft` and `move_right_or_up` against some example trees to see if the resulting `make_fringe_enumerator` and `same_fringe` functions work as expected. Show us some of your tests.

3.  Now we'll talk about another way to implement the `make_fringe_enumerator` function above (and so too the `same_fringe` function which uses it). Notice that the pattern given above is that the `make_fringe_enumerator` creates a `next_leaf` function and an initial state, and each time you want to advance the `next_leaf` by one step, you do so by calling it with the current state. It will return a result plus a modified state, which you can use when you want to call it again and take another step. All of the `next_leaf` function's memory about where it is in the enumeration is contained in the state. If you saved an old state, took three steps, and then called the `next_leaf` function again with the saved old state, it would be back where it was three steps ago. But in fact, the way we use the process and state above, there is no back-tracking. Neither do we "fork" any of the states and pursue different forward paths. Their progress is deterministic, and fixed independently of anything that `same_fringe` might do. All that's up to `same_fringe` is to take the decision of when (and whether) to take another step forward.

    Given that usage pattern, it would be appropriate and convenient to make the `next_leaf` function remember its state itself, in a mutable variable. The client function `same_fringe` doesn't need to do anything with, or even be given access to, this variable. Here's how we might write `make_fringe_enumerator` according to this plan:

        let make_fringe_enumerator (t: 'a tree) =
          (* create a zipper focusing the botleft of t *)
          let zbotleft = move_botleft (new_zipper t) in
          (* create refcell, initially pointing to zbotleft *)
          let zcell = ref (Some zbotleft) in
          (* construct the next_leaf function *)
          let next_leaf () : 'a option =
            match !zcell with
            | Some z -> (
              (* extract label of currently-focused leaf *)
              let Leaf current = z.in_focus in
              (* update zcell to point to next leaf, if there is one *)
              let () = zcell := match move_right_or_up z with
                | None -> None
                | Some z' -> _____ in
              (* return saved label *)
              _____
              )
            | None -> (* we've finished enumerating the fringe *)
              None in
          (* return the next_leaf function *)
          next_leaf

        let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
          let next1 = make_fringe_enumerator t1 in
          let next2 = make_fringe_enumerator t2 in
          let rec loop () : bool =
            match _____, _____ with
            | Some a, Some b when a = b -> loop ()
            | None, None -> true
            | _ -> false in
          loop ()

    You should fill in the blanks.

    <!--
        let make_fringe_enumerator (t: 'a tree) =
          (* create a zipper focusing the botleft of t *)
          let zbotleft = move_botleft (new_zipper t) in
          (* create refcell, initially pointing to zbotleft *)
          let zcell = ref (Some zbotleft) in
          (* construct the next_leaf function *)
          let next_leaf () : 'a option =
            match !zcell with
            | Some z -> (
              (* extract label of currently-focused leaf *)
              let Leaf current = z.in_focus in
              (* update zcell to point to next leaf, if there is one *)
              let () = zcell := match move_right_or_up z with
                | None -> None
                | Some z' -> Some (move_botleft z') in
              (* return saved label *)
              Some current
              )
            | None -> (* we've finished enumerating the fringe *)
              None in
          (* return the next_leaf function *)
          next_leaf

        let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
          let next1 = make_fringe_enumerator t1 in
          let next2 = make_fringe_enumerator t2 in
          let rec loop () : bool =
            match next1 (), next2 () with
            | Some a, Some b when a = b -> loop ()
            | None, None -> true
            | _ -> false in
          loop ()
    -->


---


Finally, we can use a mutable reference cell to define a function that enumerates a tree's fringe until it's exhausted:

        let make_fringe_enumerator (t: 'a tree) =
            (* create a zipper focusing the botleft of t *)
            let zbotleft = move_botleft (new_zipper t)
            (* create a refcell initially pointing to zbotleft *)
            in let zcell = ref (Some zbotleft)
            (* construct the next_leaf function *)
            in let next_leaf () : 'a option =
                match !zcell with
                | Some z -> (
                    (* extract label of currently-focused leaf *)
                    let Leaf current = z.in_focus
                    (* update zcell to point to next leaf, if there is one *)
                    in let () = zcell := match move_right_or_up z with
                        | None -> None
                        | Some z' -> Some (move_botleft z')
                    (* return saved label *)
                    in Some current
                | None -> (* we've finished enumerating the fringe *)
                    None
                )
            (* return the next_leaf function *)
            in next_leaf
            ;;


Using these fringe enumerators, we can write our `same_fringe` function like this:

        let same_fringe (t1 : 'a tree) (t2 : 'a tree) : bool =
            let next1 = make_fringe_enumerator t1
            in let next2 = make_fringe_enumerator t2
            in let rec loop () : bool =
                match next1 (), next2 () with
                | Some a, Some b when a = b -> loop ()
                | None, None -> true
                | _ -> false
            in loop ()
            ;;

The auxiliary `loop` function will keep calling itself recursively until a difference in the fringes has manifested itself---either because one fringe is exhausted before the other, or because the next leaves in the two fringes have different labels. If we get to the end of both fringes at the same time (`next1 (), next2 ()` matches the pattern `None, None`) then we've established that the trees do have the same fringe.



---

4.  Here's another implementation of the same-fringe function, in Scheme. It's taken from <http://c2.com/cgi/wiki?SameFringeProblem>. It uses thunks to delay the evaluation of code that computes the tail of a list of a tree's fringe. It also involves passing "the rest of the enumeration of the fringe" as a thunk argument (`tail-thunk` below). Your assignment is to fill in the blanks in the code, **and also to supply comments to the code,** to explain what every significant piece is doing. Don't forget to supply the comments, this is an important part of the assignment.

    This code uses Scheme's `cond` construct. That works like this;

        (cond
            ((test1 argument argument) result1)
            ((test2 argument argument) result2)
            ((test3 argument argument) result3)
            (else result4))

    is equivalent to:

        (if (test1 argument argument)
           ; then
             result1
           ; else
             (if (test2 argument argument)
                ; then
                  result2
                ; else
                  (if (test3 argument argument)
                     ; then
                       result3
                     ; else
                       result4)))

    Some other Scheme details or reminders:

    *   `#t` is true and `#f` is false
    *   `(lambda () ...)` constructs a thunk
    *   there is no difference in meaning between `[...]` and `(...)`; we just sometimes use the square brackets for clarity
    *   `'(1 . 2)` and `(cons 1 2)` are pairs (the same pair)
    *   `(list)` and `'()` both evaluate to the empty list
    *   `(null? lst)` tests whether `lst` is the empty list
    *   non-empty lists are implemented as pairs whose second member is a list
    *   `'()` `'(1)` `'(1 2)` `'(1 2 3)` are all lists
    *   `(list)` `(list 1)` `(list 1 2)` `(list 1 2 3)` are the same lists as the preceding
    *   `'(1 2 3)` and `(cons 1 '(2 3))` are both pairs and lists (the same list)
    *   `(pair? lst)` tests whether `lst` is a pair; if `lst` is a non-empty list, it will also pass this test; if `lst` fails this test, it may be because `lst` is the empty list, or because it's not a list or pair at all
    *   `(car lst)` extracts the first member of a pair / head of a list
    *   `(cdr lst)` extracts the second member of a pair / tail of a list

    Here is the implementation:

        (define (lazy-flatten tree)
          (letrec ([helper (lambda (tree tail-thunk)
                             (cond
                               [(pair? tree)
                                 (helper (car tree) (lambda () (helper _____ tail-thunk)))]
                               [else (cons tree tail-thunk)]))])
                  (helper tree (lambda () _____))))

        (define (stream-equal? stream1 stream2)
          (cond
            [(and (null? stream1) (null? stream2)) _____]
            [(and (pair? stream1) (pair? stream2))
              (and (equal? (car stream1) (car stream2))
                _____)]
            [else #f]))

        (define (same-fringe? tree1 tree2)
          (stream-equal? (lazy-flatten tree1) (lazy-flatten tree2)))

        (define tree1 '(((1 . 2) . (3 . 4)) . (5 . 6)))
        (define tree2 '(1 . (((2 . 3) . (4 . 5)) . 6)))

        (same-fringe? tree1 tree2)

The previous problem implemented a "stream" in Scheme. A stream is like a list in that it wraps a series of elements of a single type. It differs from a list in that the tail of the series is left uncomputed until needed. We will turn the stream on and off by thunking it. Here is one way to implement streams in OCaml:

    type 'a stream = End | Next of 'a * (unit -> 'a stream);;

There is a special stream called End that represents a stream that contains no (more) elements, analogous to the empty list []. Streams that are not empty contain a first object, paired with a thunked stream representing the rest of the series. In order to get access to the next element in the stream, we must force the thunk by applying it to the unit. Watch the behavior of this stream in detail. This stream delivers the natural numbers, in order: 1, 2, 3, ...

    # let rec make_int_stream i = Next (i, fun () -> make_int_stream (i + 1));;
    val make_int_stream : int -> int stream = [fun]

    # let int_stream = make_int_stream 1;;
    val int_stream : int stream = Next (1, [fun])         (* First element: 1 *)

    # let tail = match int_stream with Next (i, rest) -> rest;;      
    val tail : unit -> int stream = [fun]                 (* Tail: a thunk *)

    (* Force the thunk to compute the second element *)
    # tail ();;
    - : int stream = Next (2, [fun])                      (* Second element: 2 *)

    # match tail () with Next (_, rest) -> rest ();;
    - : int stream = Next (3, [fun])                      (* Third element: 3 *)

You can think of `int_stream` as a functional object that provides access to an infinite sequence of integers, one at a time. It's as if we had written `[1;2;...]` where `...` meant "continue for as long as some other process needs new integers".