arithmetic.mdwn

   1 Here are a bunch of pre-tested operations for the untyped lambda calculus. In some cases multiple versions are offered.
   2
   3         ; booleans
   4         let true = \y n. y  in ; aka K
   5         let false = \y n. n  in ; aka K I
   6         let and = \p q. p q false  in ; or
   7         let and = \p q. p q p  in ; aka S C I
   8         let or = \p q. p true q  in ; or
   9         let or = \p q. p p q  in ; aka M
  10         let not = \p. p false true  in ; or
  11         let not = \p y n. p n y  in ; aka C
  12         let xor = \p q. p (not q) q  in
  13         let iff = \p q. not (xor p q)  in ; or
  14         let iff = \p q. p q (not q)  in
  15
  16         ; pairs
  17         let make_pair = \x y f. f x y  in
  18         let get_1st = \x y. x  in ; aka true
  19         let get_2nd = \x y. y  in ; aka false
  20
  21         ; triples
  22         let make_triple = \x y z f. f x y z  in
  23
  24
  25         ; Church numerals: basic operations
  26
  27         let zero = \s z. z  in ; aka false
  28         let one = \s z. s z  in ; aka I
  29         let succ = \n s z. s (n s z)  in
  30         ; for any Church numeral n > zero : n (K y) z ~~> y
  31         let iszero = \n. n (\x. false) true  in
  32
  33
  34         ; version 3 lists
  35
  36         let empty = \f z. z  in
  37         let make_list = \h t f z. f h (t f z)  in
  38         let isempty = \lst. lst (\h sofar. false) true  in
  39         let head = \lst. lst (\h sofar. h) junk  in
  40         let tail_empty = empty  in
  41         let tail = \lst. (\shift. lst shift (make_pair empty tail_empty) get_2nd)
  42                                 ; where shift is
  43                                 (\h p. p (\t y. make_pair (make_list h t) t))  in
  44         let length = \lst. lst (\h sofar. succ sofar) 0  in
  45         let map = \f lst. lst (\h sofar. make_list (f h) sofar) empty  in
  46         let filter = \f lst. lst (\h sofar. f h (make_list h sofar) sofar) empty  in ; or
  47         let filter = \f lst. lst (\h. f h (make_list h) I) empty  in
  48
  49         ; append list2 to list1 with: list1 make_list list2
  50         let singleton = \x f z. f x z  in
  51         let reverse = \lst. lst (\h sofar. sofar make_list (singleton h)) empty  in
  52         ; zip [a;b;c] [x; y; z] ~~> [(a,x);(b,y);(c,z)]
  53         let zip = \left right. (\base build. reverse left build base (\x y. reverse x))
  54                        ; where base is
  55                        (make_pair empty (map (\h u. u h) right))
  56                        ; and build is
  57                        (\h sofar. sofar (\x y. isempty y
  58                                                sofar
  59                                                (make_pair (make_list (\u. head y (u h)) x)  (tail y))
  60                        ))  in
  61
  62         let all = \f lst. lst (\h sofar. and sofar (f h)) true  in
  63         let any = \f lst. lst (\h sofar. or sofar (f h)) false  in
  64
  65
  66         ; version 1 lists
  67
  68         let empty = make_pair true junk  in
  69         let make_list = \h t. make_pair false (make_pair h t)  in
  70         let isempty = \lst. lst get_1st  in
  71         let head = \lst. isempty lst err (lst get_2nd get_1st)  in
  72         let tail_empty = empty  in
  73         let tail = \lst. isempty lst tail_empty (lst get_2nd get_2nd)  in
  74
  75
  76         ; more math with Church numerals
  77
  78         let add = \m n. m succ n  in ; or
  79         let add = \m n s z. m s (n s z)  in
  80         let mul = \m n. m (\z. add n z) zero  in ; or
  81         let mul = \m n s. m (n s)  in
  82         let pow = \b exp. exp (mul b) one  in ; or
  83         ; b succ : adds b
  84         ; b (b succ) ; adds b b times, ie adds b^2
  85         ; b (b (b succ)) ; adds b^2 b times, ie adds b^3
  86         ; exp b succ ; adds b^exp
  87         let pow = \b exp s z. exp b s z  in
  88
  89
  90         ; three strategies for predecessor
  91         let pred_zero = zero  in
  92         let pred = (\shift n. n shift (make_pair zero pred_zero) get_2nd)
  93                 ; where shift is
  94                 (\p. p (\x y. make_pair (succ x) x))  in ; or
  95         ; from Oleg; observe that for any Church numeral n: n I ~~> I
  96         let pred = \n. iszero n zero
  97                                         ; else
  98                                         (n (\x. x I ; when x is the base term, this will be K zero
  99                                                           ; when x is a Church numeral, it will be I
 100                                                 (succ x))
 101                                           ; base term
 102                                           (K (K zero))
 103                                         )  in
 104         ; from Bunder/Urbanek
 105         let pred = \n s z. n (\u v. v (u s)) (K z) I  in ; or
 106
 107
 108         ; inefficient but simple comparisons
 109         let leq = \m n. iszero (n pred m)  in
 110         let lt = \m n. not (leq n m)  in
 111         let eq = \m n. and (leq m n) (leq n m)  in ; or
 112
 113
 114         ; more efficient comparisons, Oleg's gt provided some simplifications
 115         let leq = (\base build consume. \m n. n consume (m build base) get_1st)
 116                         ; where base is
 117                         (make_pair true junk)
 118                         ; and build is
 119                         (\p. make_pair false p)
 120                         ; and consume is
 121                         (\p. p get_1st p (p get_2nd))  in
 122         let lt = \m n. not (leq n m)  in
 123         let eq = (\base build consume. \m n. n consume (m build base) get_1st)
 124                         ; 2nd element of a pair will now be of the form (K sthg) or I
 125                         ; we supply the pair being consumed itself as an argument
 126                         ; getting back either sthg or the pair we just consumed
 127                         ; base is
 128                         (make_pair true (K (make_pair false I)))
 129                         ; and build is
 130                         (\p. make_pair false (K p))
 131                         ; and consume is
 132                         (\p. p get_2nd p)  in
 133
 134
 135         ; -n is a fixedpoint of \x. add (add n x) x
 136         ; but unfortunately Y that_function doesn't normalize
 137         ; instead:
 138         let sub = \m n. n pred m  in ; or
 139         ; how many times we can succ n until m <= result
 140         let sub = \m n. (\base build. m build base (\cur fin sofar. sofar))
 141                                 ; where base is
 142                                 (make_triple n false zero)
 143                                 ; and build is
 144                                 (\t. t (\cur fin sofar. or fin (leq m cur)
 145                                                 (make_triple cur true sofar) ; enough
 146                                                 (make_triple (succ cur) false (succ sofar)) ; continue
 147                                 ))  in
 148         ; or
 149         let sub = (\base build consume. \m n. n consume (m build base) get_1st)
 150                         ; where base is
 151                         (make_pair zero I) ; see second defn of eq for explanation of 2nd element
 152                         ; and build is
 153                         (\p. p (\x y. make_pair (succ x) (K p)))
 154                         ; and consume is
 155                         (\p. p get_2nd p)  in
 156
 157
 158         let min = \m n. sub m (sub m n) in
 159         let max = \m n. add n (sub m n) in
 160
 161
 162         ; (m/n) is a fixedpoint of \x. add (sub (mul n x) m) x
 163         ; but unfortunately Y that_function doesn't normalize
 164         ; instead:
 165         ; how many times we can sub n from m while n <= result
 166         let div = \m n. (\base build. m build base (\cur go sofar. sofar))
 167                                 ; where base is
 168                                 (make_triple m true zero)
 169                                 ; and build is
 170                                 (\t. t (\cur go sofar. and go (leq n cur)
 171                                                 (make_triple (sub cur n) true (succ sofar)) ; continue
 172                                                 (make_triple cur false sofar) ; enough
 173                                 ))  in
 174     ; what's left after sub n from m while n <= result
 175     let mod = \m n. (\base build. m build base (\cur go. cur))
 176                 ; where base is
 177                 (make_pair m true)
 178                 ; and build is
 179                 (\p. p (\cur go. and go (leq n cur)
 180                         (make_pair (sub cur n) true) ; continue
 181                         (make_pair cur false) ; enough
 182                 ))  in
 183
 184         ; or
 185         let divmod = (\base build mtail. \m n.
 186                                         (\dhead. m (mtail dhead) (\sel. dhead (sel 0 0)))
 187                                                         (n build base (\x y z. z junk))
 188                                                         (\t u x y z. make_pair t u) )
 189                                 ; where base is
 190                                 (make_triple succ (K 0) I) ; see second defn of eq for explanation of 3rd element
 191                                 ; and build is
 192                         (\t. make_triple I succ (K t))
 193                                 ; and mtail is
 194                                 (\dhead d. d (\dz mz df mf drest sel. drest dhead (sel (df dz) (mf mz))))
 195         in
 196         let div = \n d. divmod n d get_1st  in
 197         let mod = \n d. divmod n d get_2nd  in
 198
 199
 200         ; sqrt n is a fixedpoint of \x. div (div (add n (mul x x)) 2) x
 201         ; but unfortunately Y that_function doesn't normalize
 202
 203
 204         ; (log base b of m) is a fixedpoint of \x. add (sub (pow b x) m) x
 205         ; but unfortunately Y that_function doesn't normalize
 206         ; instead:
 207         ; how many times we can mul b by b while result <= m
 208         let log = \m b. (\base build. m build base (\cur go sofar. sofar))
 209                 ; where base is
 210                 (make_triple b true 0)
 211                 ; and build is
 212                 (\t. t (\cur go sofar. and go (leq cur m)
 213                            (make_triple (mul cur b) true (succ sofar)) ; continue
 214                            (make_triple cur false sofar) ; enough
 215                 ))  in
 216
 217
 218         ; Rosenbloom's fixed point combinator
 219         let Y = \f. (\h. f (h h)) (\h. f (h h)) in
 220         ; Turing's fixed point combinator
 221         let Theta = (\u f. f (u u f)) (\u f. f (u u f))  in
 222
 223
 224         ; length for version 1 lists
 225         let length = Y (\self lst. isempty lst 0 (succ (self (tail lst))))  in
 226
 227
 228         ; numhelper 0 f z ~~> z
 229         ; when n > 0: numhelper n f z ~~> f (pred n)
 230         ; compare Bunder/Urbanek pred
 231         let numhelper = \n. n (\u v. v (u succ)) (K 0) (\p f z. f p)  in
 232
 233         ; accepts fixed point combinator as a parameter, so you can use different ones
 234         let fact = \y. y (\self n. numhelper n (\p. mul n (self p)) 1)  in
 235
 236
 237
 238         fact Theta 3  ; returns 6
 239
 240
 241 <!--
 242         ; my original efficient comparisons
 243         let leq = (\base build consume. \m n. n consume (m build base) get_1st (\x. false) true)
 244                         ; where base is
 245                         (make_pair zero I) ; supplying this pair as an arg to its 2nd term returns the pair
 246                         ; and build is
 247                         (\p. p (\x y. make_pair (succ x) (K p))) ; supplying the made pair as an arg to its 2nd term returns p (the previous pair)
 248                         ; and consume is
 249                         (\p. p get_2nd p)  in
 250         let lt = \m n. not (leq n m) in
 251         let eq = (\base build consume. \m n. n consume (m build base) true (\x. false) true)
 252                         ; where base is
 253                         (make_pair zero (K (make_pair one I)))
 254                         ; and build is
 255                         (\p. p (\x y. make_pair (succ x) (K p)))
 256                         ; and consume is
 257                         (\p. p get_2nd p)  in ; or
 258 -->
 259
 260 <!--
 261         gcd
 262         pow_mod
 263
 264
 265         show Oleg's definition of integers:
 266                 church_to_int = \n sign. n
 267                 church_to_negint = \n sign s z. sign (n s z)
 268
 269                 ; int_to_church
 270                 abs = \int. int I
 271
 272                 sign_case = \int ifpos ifzero ifneg. int (K ifneg) (K ifpos) ifzero
 273
 274                 negate_int = \int. sign_case int (church_to_negint (abs int)) zero (church_to_int (abs int))
 275
 276         for more, see http://okmij.org/ftp/Computation/lambda-arithm-neg.scm
 277
 278 -->