arithmetic.mdwn

   1 Here are a bunch of pre-tested operations for the untyped lambda calculus. In some cases multiple versions are offered.
   2
   3         ; booleans
   4         let true = \y n. y  in ; aka K
   5         let false = \y n. n  in ; aka K I
   6         let and = \p q. p q false  in ; or
   7         let and = \p q. p q p  in ; aka S C I
   8         let or = \p q. p true q  in ; or
   9         let or = \p q. p p q  in ; aka M
  10         let not = \p. p false true  in ; or
  11         let not = \p y n. p n y  in ; aka C
  12         let xor = \p q. p (not q) q  in
  13         let iff = \p q. not (xor p q)  in ; or
  14         let iff = \p q. p q (not q)  in
  15
  16         ; pairs
  17         let make_pair = \x y f. f x y  in
  18         let get_1st = \x y. x  in ; aka true
  19         let get_2nd = \x y. y  in ; aka false
  20
  21         ; triples
  22         let make_triple = \x y z f. f x y z  in
  23
  24
  25         ; Church numerals: basic operations
  26
  27         let zero = \s z. z  in ; aka false
  28         let one = \s z. s z  in ; aka I
  29         let succ = \n s z. s (n s z)  in
  30         ; for any Church numeral n > zero : n (K y) z ~~> y
  31         let iszero = \n. n (\x. false) true  in
  32
  33
  34         ; version 3 lists
  35
  36         let empty = \f z. z  in
  37         let make_list = \h t f z. f h (t f z)  in
  38         let isempty = \lst. lst (\h sofar. false) true  in
  39         let head = \lst. lst (\h sofar. h) junk  in
  40         let tail_empty = empty  in
  41         let tail = \lst. (\shift. lst shift (make_pair empty tail_empty) get_2nd)
  42                                 ; where shift is
  43                                 (\h p. p (\t y. make_pair (make_list h t) t))  in
  44         let length = \lst. lst (\h sofar. succ sofar) 0  in
  45         let map = \f lst. lst (\h sofar. make_list (f h) sofar) empty  in
  46         let filter = \f lst. lst (\h sofar. f h (make_list h sofar) sofar) empty  in ; or
  47         let filter = \f lst. lst (\h. f h (make_list h) I) empty  in
  48         let singleton = \x f z. f x z  in
  49         ; append list2 to list1 with: list1 make_list list2
  50         let reverse = \lst. lst (\h sofar. sofar make_list (singleton h)) empty  in
  51         ; zip [a;b;c] [x; y; z] ~~> [(a,x);(b,y);(c,z)]
  52         let zip = \left right. (\base build. reverse left build base (\x y. reverse x))
  53                        ; where base is
  54                        (make_pair empty (map (\h u. u h) right))
  55                        ; and build is
  56                        (\h sofar. sofar (\x y. isempty y
  57                                                sofar
  58                                                (make_pair (make_list (\u. head y (u h)) x)  (tail y))
  59                        ))  in
  60         let all = \f lst. lst (\h sofar. and sofar (f h)) true  in
  61         let any = \f lst. lst (\h sofar. or sofar (f h)) false  in
  62
  63
  64         ; version 1 lists
  65
  66         let empty = make_pair true junk  in
  67         let make_list = \h t. make_pair false (make_pair h t)  in
  68         let isempty = \lst. lst get_1st  in
  69         let head = \lst. isempty lst err (lst get_2nd get_1st)  in
  70         let tail_empty = empty  in
  71         let tail = \lst. isempty lst tail_empty (lst get_2nd get_2nd)  in
  72
  73
  74         ; more math with Church numerals
  75
  76         let add = \m n. m succ n  in ; or
  77         let add = \m n s z. m s (n s z)  in
  78         let mul = \m n. m (\z. add n z) zero  in ; or
  79         let mul = \m n s. m (n s)  in
  80         let pow = \b exp. exp (mul b) one  in ; or
  81         ; b succ : adds b
  82         ; b (b succ) ; adds b b times, ie adds b^2
  83         ; b (b (b succ)) ; adds b^2 b times, ie adds b^3
  84         ; exp b succ ; adds b^exp
  85         let pow = \b exp s z. exp b s z  in
  86
  87
  88         ; three strategies for predecessor
  89         let pred_zero = zero  in
  90         let pred = (\shift n. n shift (make_pair zero pred_zero) get_2nd)
  91                 ; where shift is
  92                 (\p. p (\x y. make_pair (succ x) x))  in ; or
  93         ; from Oleg; observe that for any Church numeral n: n I ~~> I
  94         let pred = \n. iszero n zero
  95                                         ; else
  96                                         (n (\x. x I ; when x is the base term, this will be K zero
  97                                                           ; when x is a Church numeral, it will be I
  98                                                 (succ x))
  99                                           ; base term
 100                                           (K (K zero))
 101                                         )  in
 102         ; from Bunder/Urbanek
 103         let pred = \n s z. n (\u v. v (u s)) (K z) I  in ; or
 104
 105
 106         ; inefficient but simple comparisons
 107         let leq = \m n. iszero (n pred m)  in
 108         let lt = \m n. not (leq n m)  in
 109         let eq = \m n. and (leq m n) (leq n m)  in ; or
 110
 111
 112         ; more efficient comparisons, Oleg's gt provided some simplifications
 113         let leq = (\base build consume. \m n. n consume (m build base) get_1st)
 114                         ; where base is
 115                         (make_pair true junk)
 116                         ; and build is
 117                         (\p. make_pair false p)
 118                         ; and consume is
 119                         (\p. p get_1st p (p get_2nd))  in
 120         let lt = \m n. not (leq n m)  in
 121         let eq = (\base build consume. \m n. n consume (m build base) get_1st)
 122                         ; 2nd element of a pair will now be of the form (K sthg) or I
 123                         ; we supply the pair being consumed itself as an argument
 124                         ; getting back either sthg or the pair we just consumed
 125                         ; base is
 126                         (make_pair true (K (make_pair false I)))
 127                         ; and build is
 128                         (\p. make_pair false (K p))
 129                         ; and consume is
 130                         (\p. p get_2nd p)  in
 131
 132
 133         ; -n is a fixedpoint of \x. add (add n x) x
 134         ; but unfortunately Y that_function doesn't normalize
 135         ; instead:
 136         let sub = \m n. n pred m  in ; or
 137         ; how many times we can succ n until m <= result
 138         let sub = \m n. (\base build. m build base (\cur fin sofar. sofar))
 139                                 ; where base is
 140                                 (make_triple n false zero)
 141                                 ; and build is
 142                                 (\t. t (\cur fin sofar. or fin (leq m cur)
 143                                                 (make_triple cur true sofar) ; enough
 144                                                 (make_triple (succ cur) false (succ sofar)) ; continue
 145                                 ))  in
 146         ; or
 147         let sub = (\base build consume. \m n. n consume (m build base) get_1st)
 148                         ; where base is
 149                         (make_pair zero I) ; see second defn of eq for explanation of 2nd element
 150                         ; and build is
 151                         (\p. p (\x y. make_pair (succ x) (K p)))
 152                         ; and consume is
 153                         (\p. p get_2nd p)  in
 154
 155
 156         let min = \m n. sub m (sub m n) in
 157         let max = \m n. add n (sub m n) in
 158
 159
 160         ; (m/n) is a fixedpoint of \x. add (sub (mul n x) m) x
 161         ; but unfortunately Y that_function doesn't normalize
 162         ; instead:
 163         ; how many times we can sub n from m while n <= result
 164         let div = \m n. (\base build. m build base (\cur go sofar. sofar))
 165                                 ; where base is
 166                                 (make_triple m true zero)
 167                                 ; and build is
 168                                 (\t. t (\cur go sofar. and go (leq n cur)
 169                                                 (make_triple (sub cur n) true (succ sofar)) ; continue
 170                                                 (make_triple cur false sofar) ; enough
 171                                 ))  in
 172     ; what's left after sub n from m while n <= result
 173     let mod = \m n. (\base build. m build base (\cur go. cur))
 174                 ; where base is
 175                 (make_pair m true)
 176                 ; and build is
 177                 (\p. p (\cur go. and go (leq n cur)
 178                         (make_pair (sub cur n) true) ; continue
 179                         (make_pair cur false) ; enough
 180                 ))  in
 181
 182         ; or
 183         let divmod = (\base build mtail. \m n.
 184                                         (\dhead. m (mtail dhead) (\sel. dhead (sel 0 0)))
 185                                                         (n build base (\x y z. z junk))
 186                                                         (\t u x y z. make_pair t u) )
 187                                 ; where base is
 188                                 (make_triple succ (K 0) I) ; see second defn of eq for explanation of 3rd element
 189                                 ; and build is
 190                         (\t. make_triple I succ (K t))
 191                                 ; and mtail is
 192                                 (\dhead d. d (\dz mz df mf drest sel. drest dhead (sel (df dz) (mf mz))))
 193         in
 194         let div = \n d. divmod n d get_1st  in
 195         let mod = \n d. divmod n d get_2nd  in
 196
 197
 198         ; sqrt n is a fixedpoint of \x. div (div (add n (mul x x)) 2) x
 199         ; but unfortunately Y that_function doesn't normalize
 200
 201
 202         ; (log base b of m) is a fixedpoint of \x. add (sub (pow b x) m) x
 203         ; but unfortunately Y that_function doesn't normalize
 204         ; instead:
 205         ; how many times we can mul b by b while result <= m
 206         let log = \m b. (\base build. m build base (\cur go sofar. sofar))
 207                 ; where base is
 208                 (make_triple b true 0)
 209                 ; and build is
 210                 (\t. t (\cur go sofar. and go (leq cur m)
 211                            (make_triple (mul cur b) true (succ sofar)) ; continue
 212                            (make_triple cur false sofar) ; enough
 213                 ))  in
 214
 215
 216         ; Rosenbloom's fixed point combinator
 217         let Y = \f. (\h. f (h h)) (\h. f (h h)) in
 218         ; Turing's fixed point combinator
 219         let Theta = (\u f. f (u u f)) (\u f. f (u u f))  in
 220
 221
 222         ; length for version 1 lists
 223         let length = Y (\self lst. isempty lst 0 (succ (self (tail lst))))  in
 224
 225
 226         ; numhelper 0 f z ~~> z
 227         ; when n > 0: numhelper n f z ~~> f (pred n)
 228         ; compare Bunder/Urbanek pred
 229         let numhelper = \n. n (\u v. v (u succ)) (K 0) (\p f z. f p)  in
 230
 231         ; accepts fixed point combinator as a parameter, so you can use different ones
 232         let fact = \y. y (\self n. numhelper n (\p. mul n (self p)) 1)  in
 233
 234
 235
 236         fact Theta 3  ; returns 6
 237
 238
 239 <!--
 240         ; my original efficient comparisons
 241         let leq = (\base build consume. \m n. n consume (m build base) get_1st (\x. false) true)
 242                         ; where base is
 243                         (make_pair zero I) ; supplying this pair as an arg to its 2nd term returns the pair
 244                         ; and build is
 245                         (\p. p (\x y. make_pair (succ x) (K p))) ; supplying the made pair as an arg to its 2nd term returns p (the previous pair)
 246                         ; and consume is
 247                         (\p. p get_2nd p)  in
 248         let lt = \m n. not (leq n m) in
 249         let eq = (\base build consume. \m n. n consume (m build base) true (\x. false) true)
 250                         ; where base is
 251                         (make_pair zero (K (make_pair one I)))
 252                         ; and build is
 253                         (\p. p (\x y. make_pair (succ x) (K p)))
 254                         ; and consume is
 255                         (\p. p get_2nd p)  in ; or
 256 -->
 257
 258 <!--
 259         gcd
 260         pow_mod
 261
 262
 263         show Oleg's definition of integers:
 264                 church_to_int = \n sign. n
 265                 church_to_negint = \n sign s z. sign (n s z)
 266
 267                 ; int_to_church
 268                 abs = \int. int I
 269
 270                 sign_case = \int ifpos ifzero ifneg. int (K ifneg) (K ifpos) ifzero
 271
 272                 negate_int = \int. sign_case int (church_to_negint (abs int)) zero (church_to_int (abs int))
 273
 274         for more, see http://okmij.org/ftp/Computation/lambda-arithm-neg.scm
 275
 276 -->